Multi thread app works with interpreter But not working with jpm build

[Geo-7]

The simple multi-threaded proxy works with janet proxy/init.janet, but it doesn't work after building the executable using jpm build and running ./build/proxy. It appears that in the executable, the thread is blocked on ev/take

proxy/init.janet:

(defn handler [conn no]
  (print "Handler started from consumer: " no)
  (with [upstream (net/connect "127.0.0.1" 9000)]
    (forever
      (->> (ev/read conn 1024)
           (:write upstream))
      (->> (ev/read upstream 1024)
           (:write conn)))))


(defn producer [no listener]
  (print "producer started num:" no)
  (forever
    (->> (net/accept listener)
         (ev/give conn-chan))
    (print "Added to chan by producer" no)))

(defn consumer [no]
  (print "Printing from consumer:" no)
  (def conn (ev/take conn-chan))
  (ev/call handler conn no)
  (consumer no))

(defn main [& args]
  (def listener (net/listen "127.0.0.1" 10000))
  (ev/spawn-thread (consumer 1))
  (ev/spawn-thread (consumer 2))
  (producer 1 listener))

Simple Client:

(defn make-array [a b] 
  [0 85 32 127 138 0 0 129 0 211 12 215 57 36 19 80 34 41
   64 50 53 115 33 170 153 3 18 1 135 17 23 55 135 40 10 5
   a b 223 100 224 125 116 238 118 22 12 23 38 98 35 48 81 6
   54 7 4 20 153 0 217 4 5 85 85 85 0 5 178 60 156 202 10 50
   49 48 61 49 49 46 48 55 59 175 52 202 125])


(defn send [number dummy-buffer]
  (def proxy (net/connect "127.0.0.1" 10000))
  (each x (range 0 number)
    (net/write proxy dummy-buffer)
    (ev/read proxy 1024))
  (:close proxy))

(defn main [& args]
  (print "Client started")
  (var dummy-buffer @"")
  #Make 100 clients TODO: Should be multi thread 
  (each x (range 0 100)
    (each b (make-array 0 x)
      (buffer/push-byte dummy-buffer b))
    #Each Client sends N number of packet
    (ev/call send 1000 dummy-buffer)
    ))

Server

(def listener (net/listen "127.0.0.1" 9000))

(defn handler [conn]
  (forever
    (->> (ev/read conn 2048)
         (net/write conn))
    (print "Got message")))

(defn start-server []
  (forever
    (->> (net/accept listener)
         (ev/call handler))))

(defn main [& args]
  (print "Server Started")
  (start-server))

[Geo-7]

I made a simpler example for testing:

(def conn-chan (ev/thread-chan 1000))

(defn producer [no]
  (forever
    (ev/sleep 5)
    (print "Adding data from producer num:" no)
    (ev/give conn-chan (math/random))))

(defn consumer [no]
  (forever
    (ev/sleep 0.5)
    (def num (ev/take conn-chan))
    (print num ": Printing from consumer:" no)))

(defn main [& args]
  (ev/spawn-thread (producer 1))
  (ev/spawn-thread (consumer 1))
  (ev/spawn-thread (consumer 2))
  (ev/sleep 20)
  (print "exiting"))

[Geo-7]

If I change conn-chan to ev/chan it will stop working with interpreter (Thats ok, because they do not allow communication between threads)
ev/thread-chan acts differently when building executable, It acts like ev/chan

[Geo-7]

Creating image has the same defect as jpm build
janet -c proxy/init.janet proxy.jimage Then running janet -i proxy.image

[bakpakin]

The issue is the top level threaded channel, which is not marshaled correctly.

Fixed in cd36f1e

The immediate solution is to create the channel in main and pass to the producer and consumer.

(defn producer [conn-chan no]
  (forever
    (ev/sleep 5)
    (print "Adding data from producer num:" no)
    (ev/give conn-chan (math/random))))

(defn consumer [conn-chan no]
  (forever
    (ev/sleep 0.5)
    (def num (ev/take conn-chan))
    (print num ": Printing from consumer:" no)))

(defn main [& args]
  (def conn-chan (ev/thread-chan 1000))
  (ev/spawn-thread (producer conn-chan 1))
  (ev/spawn-thread (consumer conn-chan 1))
  (ev/spawn-thread (consumer conn-chan 2))
  (ev/sleep 20)
  (print "exiting"))