A PEG that matches a number of at least two digits and ends with a specific digit?

[stutonk]

For the sake of example, let's say the number must end in 0. The problem is easily solved with a regex like [0-9]+0. Practically I ended up just using '(at-least 2 (range "09")) and string/has-suffix? if the string matched. But how would you do it with a pure PEG since you can't use a construct like (* (some (range "09")) "0")?

[ianthehenry]

You can run arbitrary code at match time using cmt ("capture at match time"), so you can do e.g.:

repl:1:> (peg/match ~(cmt '(at-least 2 :d) ,|(if (string/has-suffix? "0" $) $)) "1230")
@["1230"]
repl:2:> (peg/match ~(cmt '(at-least 2 :d) ,|(if (string/has-suffix? "0" $) $)) "0")
nil
repl:3:> (peg/match ~(cmt '(at-least 2 :d) ,|(if (string/has-suffix? "0" $) $)) "12")
nil
repl:4:> (peg/match ~(cmt '(at-least 2 :d) ,|(if (string/has-suffix? "0" $) $)) "00")
@["00"]

I think you could also do this with mutually recursive rules instead of explicit repetition? It might perform better, but cmt is clear and expresses the intent pretty well.

(cmt has the chance to change the capture too, so you could scan-number or whatever if you wanted in here without having to wrap this in the (number ...) peg special)

(Also probably not worth noting that [0-9]+0 will match 12340334 due to backtracking; I don't actually know how to express the exact equivalent of this PEG in a regex; but whatever we'll assume anchoring on the end or something)

[sogaiu]

Not sure if this counts, but what about something like this:

(peg/match ~(sequence :d+ (look -1 "0")) "0210")
# =>
@[]

[CFiggers]

Not sure if this counts, but what about something like this:

(peg/match ~(sequence :d+ (look -1 "0")) "0210")
# =>
@[]

Dude. Nice. 👍

[pepe]

@sogaiu, can you please add this as an answer to the main thread? It is the correct answer for me.

[stutonk]

Interesting. I wasn't even aware of short-fn and its | syntax. That combined with cmt would definitely shorten some things up in other PEG related code I have. Thank you!

[sogaiu]

As requested in this comment, here's an alternative peg:

~(sequence :d+ (look -1 "0"))

I confess to have seen something like it in bakpakin's code (^^;

> below is an alias for look IIUC:

      :long-bytes '{:delim (some "`")
                    :open (capture :delim :n)
                    :close (cmt (* (not (> -1 "`")) (-> :n) ':delim) ,=)
                    :main (drop (* :open (any (if-not :close 1)) :close))}

via: code in spork/fmt

[pepe]

Thank you very much!

[stutonk]

Brilliant. I knew it had to be possible in a concise way. Thank you!

[sogaiu]

Strictly speaking, the given peg fails the original specification because it will also match in this case:

(peg/match ~(sequence :d+ (look -1 "0")) "0")
# =>
@[]

May be the following is closer to correct:

(peg/match ~(sequence :d :d+ (look -1 "0")) "10")
# =>
@[]

(peg/match ~(sequence :d :d+ (look -1 "0")) "0")
# =>
nil