build.gradle

plugins {
    id 'groovy'
    id 'java-gradle-plugin'
    id 'maven'
    id 'jacoco'
    id 'pl.allegro.tech.build.axion-release' version '1.9.1'
    id 'com.github.kt3k.coveralls' version '2.8.2'
    id 'com.gradle.plugin-publish' version '0.9.10'
    id 'com.bmuschko.nexus' version '2.3.1' apply false
    id 'io.codearte.nexus-staging' version '0.11.0' apply false

    id 'com.bmuschko.docker-remote-api' version '3.2.1'
}

if (project.hasProperty('mavenCentral')) {
    apply from: 'gradle/mavenCentral.gradle'
}

scmVersion {
    tag {
        prefix = 'axion-release'
    }

    hooks {
        pre 'fileUpdate', [files: ['README.md', 'mkdocs.yml'], pattern: { v, p -> /'$v'/ }, replacement: { v, p -> "'$v'" }]
        pre 'commit'
    }

    versionCreator 'versionWithBranch'
}

group = 'pl.allegro.tech.build'
version = scmVersion.version

sourceCompatibility = '1.7'

repositories {
    mavenCentral()
}

project.ext.versions = [
        jgit: '4.11.0.201803080745-r',
        jsch: '0.1.54',
        jschAgent: '0.0.9'
]

sourceSets {
    integration {
        java.srcDir project.file('src/integration/java')
        groovy.srcDir project.file('src/integration/groovy')

        resources.srcDir project.file('src/integration/resources')
        resources.srcDir project.sourceSets.test.resources
        resources.srcDir project.sourceSets.main.resources

        compileClasspath = project.sourceSets.main.output +
                project.sourceSets.test.output +
                project.configurations.testRuntime
        runtimeClasspath = output + compileClasspath
    }

    remoteTest {
        java.srcDir project.file('src/test-remote/java')
        groovy.srcDir project.file('src/test-remote/groovy')

        resources.srcDir project.file('src/test-remote/resources')
        resources.srcDir project.sourceSets.test.resources
        resources.srcDir project.sourceSets.main.resources

        compileClasspath = project.sourceSets.main.output +
            project.sourceSets.test.output +
            project.configurations.testRuntime
        runtimeClasspath = output + compileClasspath
    }
}

dependencies {
    compile gradleApi()
    compile localGroovy()

    compile group: 'org.eclipse.jgit', name: 'org.eclipse.jgit', version: versions.jgit
    compile group: 'org.eclipse.jgit', name: 'org.eclipse.jgit.ui', version: versions.jgit

    compile group: 'com.jcraft', name: 'jsch', version: versions.jsch
    compile group: 'com.jcraft', name: 'jsch.agentproxy.core', version: versions.jschAgent
    compile group: 'com.jcraft', name: 'jsch.agentproxy.jsch', version: versions.jschAgent
    compile group: 'com.jcraft', name: 'jsch.agentproxy.sshagent', version: versions.jschAgent
    compile group: 'com.jcraft', name: 'jsch.agentproxy.pageant', version: versions.jschAgent
    compile group: 'com.jcraft', name: 'jsch.agentproxy.usocket-jna', version: versions.jschAgent
    compile group: 'com.jcraft', name: 'jsch.agentproxy.usocket-nc', version: versions.jschAgent

    compile group: 'com.github.zafarkhaja', name: 'java-semver', version: '0.9.0'

    testCompile (group: 'org.ajoberstar', name: 'grgit', version: '1.7.2') {
        exclude group: 'org.eclipse.jgit', module: 'org.eclipse.jgit.ui'
        exclude group: 'org.eclipse.jgit', module: 'org.eclipse.jgit'
    }

    testCompile(group: 'org.spockframework', name: 'spock-core', version: '1.0-groovy-2.4') {
        exclude group: 'org.codehaus.groovy', module: 'groovy-all'
    }
    testCompile group: 'cglib', name: 'cglib-nodep', version: '3.1'
    testCompile group: 'org.objenesis', name: 'objenesis', version: '2.4'
    testCompile group: 'org.apache.sshd', name: 'sshd-core', version: '1.6.0'
    testCompile group: 'org.apache.sshd', name: 'sshd-git', version: '1.6.0'

    testCompile gradleTestKit()
}

test {
    testLogging {
        events 'passed', 'skipped', 'failed'
        exceptionFormat = 'full'
    }
}

project.configurations {
    integration {
        extendsFrom project.configurations.testRuntime
        description = 'Dependencies for integration tests'
        transitive = true
        visible = true
    }

    remoteTest {
        extendsFrom project.configurations.testRuntime
        description = 'Dependencies for tests with Docker'
        transitive = true
        visible = true
    }
}

task integrationTest(type: Test) {
    testClassesDirs = project.sourceSets.integration.output.classesDirs
    classpath = project.sourceSets.main.output +
            project.sourceSets.test.output +
            project.sourceSets.integration.runtimeClasspath +
            project.configurations.testRuntime +
            project.configurations.integrationRuntime

    testLogging {
        events 'passed', 'skipped', 'failed'
        showStandardStreams = true
        exceptionFormat = 'full'
    }
}

task buildDockerImage(type: com.bmuschko.gradle.docker.tasks.image.DockerBuildImage) {
    inputDir = file('docker')
    tag = 'test/axion-release-remote:latest'
}

task createDockerContainer(type: com.bmuschko.gradle.docker.tasks.container.DockerCreateContainer) {
    dependsOn buildDockerImage
    targetImageId { buildDockerImage.getImageId() }
    portBindings = ['2222:22']
}

task startDockerContainer(type: com.bmuschko.gradle.docker.tasks.container.DockerStartContainer) {
    dependsOn createDockerContainer
    targetContainerId { createDockerContainer.getContainerId() }
}

task stopDockerContainer(type: com.bmuschko.gradle.docker.tasks.container.DockerStopContainer) {
    targetContainerId { createDockerContainer.getContainerId() }
}


task remoteTest(type: Test) {
    testClassesDirs = project.sourceSets.remoteTest.output.classesDirs
    classpath = project.sourceSets.main.output +
        project.sourceSets.test.output +
        project.sourceSets.remoteTest.runtimeClasspath +
        project.configurations.testRuntime +
        project.configurations.remoteTestRuntime

    testLogging {
        events 'passed', 'skipped', 'failed'
        exceptionFormat = 'full'
    }

    dependsOn startDockerContainer
    finalizedBy stopDockerContainer
}

tasks.check.dependsOn integrationTest, remoteTest

gradlePlugin {
    testSourceSets project.sourceSets.integration
}

jacoco {
    toolVersion = '0.8.2'
}

jacocoTestReport {
    reports {
        xml.enabled = true
        html.enabled = true
    }
}

pluginBundle {
    website = 'https://github.com/allegro/axion-release-plugin'
    vcsUrl = 'https://github.com/allegro/axion-release-plugin'
    description = 'Release and version management plugin.'
    tags = ['release', 'version']

    plugins {
        release {
            id = 'pl.allegro.tech.build.axion-release'
            displayName = 'axion-release-plugin'
        }
    }

    mavenCoordinates {
        groupId = 'pl.allegro.tech.build'
        artifactId = 'axion-release-plugin'
    }
}