include.gradle

// http://jedicoder.blogspot.com.es/2011/11/automated-gradle-project-deployment-to.html
apply plugin: 'java'
apply plugin: 'maven'
apply plugin: 'signing'

group = "${project.ext.group}"
version = "${project.ext.mediaVersion}"

repositories {
	mavenLocal()
	mavenCentral()
}

sourceSets {
	main.java.srcDirs = [ 'src' ]
	main.resources.srcDirs = [ 'resources' ]
	test.java.srcDirs = [ 'test' ]
}

task javadocJar(type: Jar, dependsOn: javadoc) {
	classifier = 'javadoc'
	from 'build/docs/javadoc'
}

task sourcesJar(type: Jar) {
	from sourceSets.main.allSource
	classifier = 'sources'
}

artifacts {
	archives jar
	archives javadocJar
	archives sourcesJar
}

dependencies {
	compile "com.jtransc:jtransc-rt-core:${project.ext.jtranscVersion}"
	testCompile "junit:junit:4.12"
}


signing {
	sign configurations.archives
}

uploadArchives {
	repositories {
		mavenDeployer {
			beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }

			repository(url: "https://oss.sonatype.org/service/local/staging/deploy/maven2/") {
				authentication(userName: sonatypeUsername, password: sonatypePassword)
			}

			pom.project {
				name "${project.name}"
				packaging 'jar'
				description 'JVM AOT compiler currently generating Javascript and Haxe, with initial focus on Kotlin and games.'
				url 'https://github.com/jtransc/jtransc-media/'

				scm {
					url 'scm:git@github.com:jtransc/jtransc-media.git'
					connection 'scm:git@github.com:jtransc/jtransc-media.git'
					developerConnection 'scm:git@github.com:jtransc/jtransc-media.git'
				}

				licenses {
					license {
						name 'The Apache Software License, Version 2.0'
						url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
						distribution 'repo'
					}
				}

				developers {
					developer {
						id 'soywiz'
						name 'Carlos Ballesteros Velasco'
					}
				}
			}
		}
	}
}

//println("uploadArchives!: ${project.name}")