spotify-ad

#!/usr/bin/env osascript

-- Show help subroutine
on showMSG()
    set msg to "Use the following commands:\n"
    set msg to msg & "  mute               - Mute all Ads\n"
    set msg to msg & "  swap               - Swap ad with your local playlist instead of ads\n"
    set msg to msg & "  rm                 - Play your local playlist like there's no ads at all\n"
    return msg
end showMSG

on run argv
    if count of argv is equal to 0 then
  	    return showMSG()
    end if
  
    set state to "Music"
    set command to item 1 of argv
    using terms from application "Spotify"
        repeat while true
            repeat 1 times
                delay 0.5
                if application "Spotify" is not running then exit repeat -- simulate continue
                -- Set LastVolume
                set lastVolume to 100
                tell application "Spotify" to if sound volume is not 0 then set lastVolume to sound volume

                -- Mute Mode
                if command is equal to "mute" then
                    tell application "Spotify"
                        if ":ad:" is in spotify url of current track then
                            set sound volume to 0
                        else
                            set sound volume to lastVolume 
                        end if
                    end tell

                -- Swap Mode
                else if command is equal to "swap" then -- TODO fix pausing issue
                    tell application "Spotify"
                        if ":ad:" is in spotify url of current track then
                            set sound volume to 0
                            Tell application "Music" to play
                        else
                            Tell application "Music" to pause
                            set sound volume to lastVolume 
                        end if
                    end tell

                -- Remove Mode
                else if command is equal to "rm" then -- TODO do somthing here :)
                    tell application "Spotify"
                        if ":ad:" is in spotify url of current track and state is equal to "Music" then
                            set state to "Ad"
                            set sound volume to 0
                            Tell application "Music"  to play
                            Tell application "Spotify" to play
                        else if state is equal to "Ad"
                            Tell application "Music" 
                                if get finish of current track -  player position is less than 1
                                    set state to "Music"
                                    Tell application "Spotify" to set sound volume to lastVolume
                                    Tell application "Spotify" to play
                                    Tell application "Music"  to next track
                                    Tell application "Music"  to pause
                                else
                                    Tell application "Spotify" to if ":ad:" is not in spotify url of current track then pause
                                end if
                            end Tell
                        end if
                    end tell

                -- Show Help
                else 
                    return showMSG()
                end if
            end repeat
        end repeat
    end using terms from
end run