Add Support for serviceprincipals in powerplatform_user

[elberfeld]

The resource powerplatform_user allows creation regular users as users in dataverse, but lacks the possibility to create ServicePricipals as users in dataverse.

Hence thise service principals are mostly identical to normal unsers in dataverse an also need to have roles assigned i wold suggest to extend powerplatform_user for this.
In Most cases these service proncibals are already created by terraform so it would be a great benefit if the according users can be created by terraform also.

There are 2 main types of service proncipals which are important:

• Entra AppRegistrations (Microsoft_AAD_RegisteredApps)
• ManagedIdentities

[mawasile]

@elberefld since we have the powerplatform_data_record resource we try to use it for all dataverse operations. Here's a code example for creating application user.
Is there any use case that this code would not support for you?

variable "applicationid" {
  type        = string
  description = "The Entra object id of the service principal"
}

variable "businessunitid" {
  type        = string
  description = "The GUID id of the business unit to add this application to."
}

variable "environment_id" {
  type        = string
  description = "The environment to which this application user is added"
}

variable "roles" {
  type        = set(string)
  description = "The roles that are granted to this application user"
}

data "powerplatform_security_roles" "all_roles" {
  business_unit_id = var.businessunitid
  environment_id   = var.environment_id
}

locals {
  selected_roles = [for role in coalesce(data.powerplatform_security_roles.all_roles.security_roles, []) : role.role_id if contains(var.roles, role.name)]
}

resource "powerplatform_data_record" "app_user" {
  table_logical_name = "systemuser"
  environment_id     = var.environment_id
  disable_on_destroy = true
  columns = {
    applicationid = var.applicationid
    businessunitid = {
      table_logical_name = "businessunit"
      data_record_id     = var.businessunitid
    }
    systemuserroles_association = tolist([for rid in local.selected_roles : { table_logical_name = "role", data_record_id = tostring(rid) }])
  }
}