-
Notifications
You must be signed in to change notification settings - Fork 33
/
JSONReaderWriter.pas
1210 lines (1054 loc) · 47.8 KB
/
JSONReaderWriter.pas
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
// ###################################################################
// #### This file is part of the mathematics library project, and is
// #### offered under the licence agreement described on
// #### http://www.mrsoft.org/
// ####
// #### Copyright:(c) 2016, Michael R. . All rights reserved.
// ####
// #### Unless required by applicable law or agreed to in writing, software
// #### distributed under the License is distributed on an "AS IS" BASIS,
// #### WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// #### See the License for the specific language governing permissions and
// #### limitations under the License.
// ###################################################################
unit JSONReaderWriter;
interface
// ###################################################
// #### Simple JSON reader and writer classes
// ###################################################
// note: there are a few restrictions that are not
// defined in the JSON format as is.
// 1.) The objects write some kind of header, aka the writer itself identifies
// itself with the property "Lib":"mrMath". This tag is optional but only if
// TJSONReaderWriter is invoked directly. Reading from the generic reader function does not work
// without this header.
// 2.) each Object and thus also the library have a version property. If it is missing
// Version 1 is assumed.
// 3.) Reading a file is done in one pass and character by character thus the object description needs to be
// the first property of an object. Before that property only the lib header
// and the version are allowed to be placed. Ensure that your JSON writer
// can handle this.
// 4.) Binary properties are simply strings with the prefix 0x .
// Each byte in the binary stream is simply encoded as hex value of that byte (00-FF)
// meaing that every byte is encoded into 2 characters.
// e.g. the byte streams $54$FA$11 is encoded into the string: 0x54FA11
// todo: perhaps Base64 encoding?
uses SysUtils, Classes, BaseMathPersistence, MathUtilFunc, types;
// #############################################################
// #### Loading/saving data
type
TJsonReaderWriter = class(TCustomMathPersistenceIO)
private
fFmt : TFormatSettings;
fIsFirst : boolean;
function EncodeJSONString(const s : string) : UTF8String;
function InternalLoadFromStream(aStream : TStream) : TBaseMathPersistence;
protected
class function CanReadStream(aStream : TStream) : boolean; override;
procedure WriteStreamHeader; override;
procedure FinalizeStream; override;
procedure WriteObjDescriptor(const Name : String; const Value : String); override;
procedure WriteDoubleArr(const Name : String; const Value : Array of double); override;
procedure WriteListBegin(const Name : String; count : integer); override;
procedure WriteListEnd; override;
procedure WriteBinaryProperty(const Name : String; const Value; size : integer); override;
procedure WriteProperty(const Name : String; const Value : double); overload; override;
procedure WriteProperty(const Name : String; const Value : String); overload; override;
procedure WriteProperty(const Name : String; const Value : integer); overload; override;
procedure WriteObject(Obj : TBaseMathPersistence); override;
procedure WriteObject(const Name : String; Obj : TBaseMathPersistence); overload; override;
procedure WriteListDoubleArr(const Value : Array of double); override;
procedure WriteIntArr(const Name : String; const Value : Array of Integer); override;
procedure WriteListIntArr(const Value : Array of Integer); override;
public
function LoadFromStream(aStream : TStream) : TBaseMathPersistence; override;
procedure AfterConstruction; override;
end;
implementation
uses Math;
const cJSONHeader : UTF8String = '{"Lib":"mrMath"';
cJSONVersion : UTF8String = ',"Version":1';
cJSONFinalize : UTF8String = '}';
{ TJsonReaderWriter }
procedure TJsonReaderWriter.AfterConstruction;
begin
ffmt := GetLocalFMTSet;
fFmt.DecimalSeparator := '.';
inherited;
end;
class function TJsonReaderWriter.CanReadStream(aStream: TStream): boolean;
var buf : UTF8String;
begin
SetLength(buf, Length(cJSONHeader));
Result := aStream.Read(buf[1], Length(cJSONHeader)) = Length(cJSONHeader);
if Result then
Result := (CompareStr(String(buf), String(cJSONHeader)) = 0);
end;
procedure TJsonReaderWriter.WriteStreamHeader;
begin
Stream.WriteBuffer(cJSONHeader[1], Length(cJSONHeader));
Stream.WriteBuffer(cJSONVersion[1], Length(cJSONVersion));
end;
procedure TJsonReaderWriter.FinalizeStream;
begin
Stream.WriteBuffer(cJSONFinalize[1], Length(cJSONFinalize));
end;
procedure TJsonReaderWriter.WriteObjDescriptor(const Name, Value: String);
var s : UTF8String;
begin
s := ',"' + EncodeJSONString(Name) + '":"' + EncodeJSONString(Value) + '"';
Stream.WriteBuffer(s[1], Length(s));
end;
procedure TJsonReaderWriter.WriteDoubleArr(const Name: String;
const Value: array of double);
var s : UTF8String;
counter: Integer;
begin
s := ',"' + EncodeJSONString(Name) + '":[';
Stream.WriteBuffer(s[1], Length(s));
for counter := 0 to Length(Value) - 1 do
begin
s := UTF8String( Format('%g', [Value[counter]], fFmt) );
if counter <> Length(Value) - 1 then
s := s + ',';
stream.WriteBuffer(s[1], Length(s));
end;
s := ']';
stream.WriteBuffer(s[1], Length(s));
end;
procedure TJsonReaderWriter.WriteListBegin(const Name: String; count: integer);
var s : UTF8String;
begin
s := ',"' + EncodeJSONString(Name) + '":[';
Stream.WriteBuffer(s[1], Length(s));
fIsFirst := True;
end;
procedure TJsonReaderWriter.WriteListEnd;
var s : UTF8String;
begin
s := ']';
stream.WriteBuffer(s[1], Length(s));
fIsFirst := False;
end;
procedure TJsonReaderWriter.WriteBinaryProperty(const Name: String; const Value;
size: integer);
var s : UTF8String;
counter: Integer;
pVal : PByte;
begin
s := ',"' + EncodeJSONString(Name) + '":"0x'; // 0x indicates a binary data string
// simple encoding (todo: use base64?!)
pVal := @Value;
for counter := 0 to size - 1 do
begin
s := s + UTF8String( IntToHex(pVal^, 2) );
inc(pVal);
end;
s := s + '"';
stream.WriteBuffer(s[1], Length(s));
end;
procedure TJsonReaderWriter.WriteProperty(const Name: String;
const Value: integer);
var s : utf8String;
begin
s := UTF8String(Format(',"%s":%d', [EncodeJSONString(Name), Value]));
Stream.WriteBuffer(s[1], Length(s));
end;
procedure TJsonReaderWriter.WriteProperty(const Name, Value: String);
var s : UTF8String;
begin
s := ',"' + EncodeJSONString(Name) + '":"' + EncodeJSONString(Value) + '"';
Stream.WriteBuffer(s[1], Length(s));
end;
procedure TJsonReaderWriter.WriteProperty(const Name: String;
const Value: double);
var s : UTF8String;
begin
s := ',"' + EncodeJSONString(Name) + '":' + UTF8String( Format('%g', [Value], fFmt) );
Stream.WriteBuffer(s[1], Length(s));
end;
procedure TJsonReaderWriter.WriteObject(const Name: String;
Obj: TBaseMathPersistence);
var s : UTF8String;
aWriter : TJsonReaderWriter;
begin
s := ',"' + EncodeJSONString(Name) + '":';
Stream.WriteBuffer(s[1], Length(s));
// Now write the object
aWriter := TJsonReaderWriter.Create;
try
aWriter.SaveToStream(Obj, Stream);
finally
aWriter.Free;
end;
end;
procedure TJsonReaderWriter.WriteObject(Obj: TBaseMathPersistence);
var aWriter : TJsonReaderWriter;
c : AnsiChar;
begin
if not fIsFirst then
begin
c := ',';
Stream.WriteBuffer(c, sizeof(c));
end;
fIsFirst := False;
aWriter := TJsonReaderWriter.Create;
try
aWriter.SaveToStream(Obj, Stream);
finally
aWriter.Free;
end;
end;
procedure TJsonReaderWriter.WriteListDoubleArr(const Value: array of double);
var s : UTF8String;
counter: Integer;
begin
s := '';
if not fIsFirst then
s := ',';
s := s + '[';
for counter := 0 to Length(Value) - 1 do
begin
s := s + UTF8String( Format('%g', [Value[counter]], fFmt) );
if counter <> Length(Value) - 1 then
s := s + ',';
end;
s := s + ']';
fIsFirst := False;
if Length(s) > 0 then
Stream.WriteBuffer(s[1], Length(s));
end;
procedure TJsonReaderWriter.WriteIntArr(const Name: String;
const Value: array of Integer);
var s : UTF8String;
counter: Integer;
begin
s := ',"' + EncodeJSONString(Name) + '":[';
for counter := 0 to Length(Value) - 1 do
begin
s := s + UTF8String( Format('%d', [Value[counter]], fFmt) );
if counter <> Length(Value) - 1 then
s := s + ',';
end;
s := s + ']';
Stream.WriteBuffer(s[1], Length(s));
end;
procedure TJsonReaderWriter.WriteListIntArr(const Value: array of Integer);
var s : UTF8String;
counter: Integer;
begin
s := '';
if not fIsFirst then
s := ',';
s := s + '[';
for counter := 0 to Length(Value) - 1 do
begin
s := s + UTF8String( Format('%d', [Value[counter]], fFmt) );
if counter <> Length(Value) - 1 then
s := s + ',';
end;
fIsFirst := False;
s := s + ']';
if Length(s) > 0 then
Stream.WriteBuffer(s[1], Length(s));
end;
function TJsonReaderWriter.EncodeJSONString(const s: string): UTF8String;
var counter: Integer;
resIdx : integer;
res : UTF8String;
hexStr : UTF8String;
procedure AddChar(const c : AnsiChar);
begin
res[resIdx] := c;
inc(resIdx);
end;
begin
resIdx := 1;
// reserve the largest possible encoded string as memory once
SetLength(res, 6*Length(s));
for counter := 1 to Length(s) do
begin
// check if the char needs to be encoded
case s[counter] of
'"',
'\',
'/': begin
AddChar('\');
AddChar( AnsiChar( s[counter]) );
end;
#08: begin // backspace
AddChar('\');
AddChar('b');
end;
#09: begin // tab
AddChar('\');
AddChar('t');
end;
#10: begin // carrige return
AddChar('\');
AddChar('r');
end;
#12: begin // form feed
AddChar('\');
AddChar('f');
end;
#13: begin // line feed
AddChar('\');
AddChar('n');
end;
else
// check for: numeric, letter (a..z) and white space
// all others encode!
if ((Ord(s[counter]) >= Ord('a')) and (ord(s[counter]) <= Ord('z'))) or
((Ord(s[counter]) >= Ord('A')) and (ord(s[counter]) <= Ord('Z'))) or
(s[counter] = ' ') or ((Ord(s[counter]) >= Ord('0')) and (Ord(s[counter]) <= Ord('9')))
then
AddChar(AnsiChar(s[counter]))
else
begin
AddChar('\');
AddChar('u');
hexStr := Utf8String( IntToHex(ord(s[counter]), 4) );
assert(Length(hexStr) = 4, 'IntToHex failed');
AddChar(hexStr[1]);
AddChar(hexStr[2]);
AddChar(hexStr[3]);
AddChar(hexStr[4]);
end;
end;
end;
Result := Copy(res, 1, resIdx - 1);
end;
function TJsonReaderWriter.LoadFromStream(
aStream: TStream): TBaseMathPersistence;
var c : AnsiChar;
begin
// state machine to decode json:
aStream.ReadBuffer(c, sizeof(c));
if c <> '{' then
raise EReadError.Create('No valid JSON format - stream must start with "{"');
Result := InternalLoadFromStream(aStream);
end;
type
TJSONState = (sObj, sString, sStringEscape, sStringEscHex, sPropertyEnd,
sValueBegin, sValueEnd, sListBegin, slistValue, slistNextValue, sListEnd,
sNumericBegin, sNumericNum, sNumericFrac, sNumericExp,
sNumericExpSign, sNumericExpVal);
TJSONListType = (jlNone, jlDouble, jlString, jlInt, jlObject, jlDoubleArr, jlIntArr);
function TJsonReaderWriter.InternalLoadFromStream(
aStream: TStream): TBaseMathPersistence;
var c : Ansichar;
sProp : string;
sVal : string;
states : Array of TJSONState;
stateIdx : integer;
listType : TJSONListType;
dVal : double;
iVal : integer;
intIdx : integer;
numType : TPropType;
binDat : TByteDynArray;
listD : TDoubleDynArray;
listDD : Array of TDoubleDynArray;
listI : TIntegerDynArray;
listII : Array of TIntegerDynArray;
listS : TStringDynArray;
listO : Array of TBaseMathPersistence;
listCnt : integer;
aObj : TBaseMathPersistence;
mathIOClass : TBaseMathPersistenceClass;
version: Integer;
counter: Integer;
function DecodeStringToBinary(const s : string) : TByteDynArray;
var binIdx : integer;
counter : integer;
begin
SetLength(Result, (Length(s) - 2) div 2);
binIdx := 0;
counter := 3;
while counter < Length(s) do
begin
Result[binIdx] := StrToInt( '$' + s[counter] + s[counter + 1] );
inc(counter, 2);
inc(binIdx);
end;
end;
procedure PushState(aState : TJSONState);
begin
if stateIdx >= Length(states) then
SetLength(states, 100 + Length(states));
states[stateIdx] := aState;
inc(stateIdx);
end;
function PeekState : TJSONState;
begin
Result := states[stateIdx - 1];
end;
procedure PopState;
begin
dec(stateIdx);
if stateIdx < 0 then
raise EReadError.Create('Error - json stack went negative');
end;
function IsWhiteSpace(c : AnsiChar) : boolean;
begin
Result := c in [#9, ' ', #13, #10];
end;
function ReadValue(ch : AnsiChar; readInt : boolean) : double;
const cBase : double = 10;
var sign : double;
c : AnsiChar;
fracFact : double;
expSign : integer;
expVal : integer;
begin
Result := 0;
PushState(sNumericBegin);
sign := 1;
expSign := 1;
expVal := 0;
c := ch;
fracFact := 0.1;
repeat
case PeekState of
sNumericBegin: begin
if c = '+'
then
sign := 1
else if c = '-'
then
sign := -1
else if c in ['0'..'9']
then
Result := Ord(c) - Ord('0')
else
raise EReadError.Create('Error: unsupported character on numerics');
PopState;
PushState(sNumericNum);
end;
sNumericNum: begin
if c = '.' then
begin
if readInt then
raise EReadError.Create('Error integer value expected');
PopState;
PushState(sNumericFrac);
end
else if (c = 'e') or (c = 'E') then
begin
PopState;
PushState(sNumericExpSign);
end
else if (c in ['0'..'9']) then
begin
Result := Result*10 + Ord(c) - Ord('0');
end
else
break; // any other character stops the decoding
end;
sNumericFrac: begin
if (c = 'e') or (c = 'E') then
begin
if readInt then
raise EReadError.Create('Error no exponential allowed on integer values');
PopState;
PushState(sNumericExpSign);
end
else if (c in ['0'..'9']) then
begin
Result := Result + fracFact*(Ord(c) - Ord('0'));
fracFact := fracFact*0.1;
end
else
break; // any other character stops the decoding
end;
sNumericExpSign: begin
if (c = '-')
then
expSign := -1
else if (c = '+')
then
expSign := 1
else if c in ['0'..'9']
then
expVal := Ord(c) - Ord('0')
else
raise EReadError.Create('Error in decoding the exponent');
PopState;
PushState(sNumericExp);
end;
sNumericExp: begin
if c in ['0'..'9']
then
expVal := expVal*10 + (Ord(c) - Ord('0'))
else
break; // any other character stops the decoding
end;
else
raise EReadError.Create('Error: unrecognized state on numerics');
end;
until aStream.Read(c, sizeof(c)) <> sizeof(c);
PopState;
// calculate the result
Result := sign*Result;
if expVal <> 0 then
Result := Result*IntPower(cBase, expSign*expVal);
// undo the last read -> it is not part of the value
aStream.Seek(-sizeof(c), soFromCurrent);
end;
function ReadInt(ch : AnsiChar) : integer;
begin
Result := Round(ReadValue(Ch, True));
end;
function ReadNumeric(ch : AnsiChar) : double;
begin
Result := ReadValue(ch, False);
end;
function ReadString : string;
var c : AnsiChar;
sHlp : string;
begin
sHlp := '';
PushState(sString);
Result := '';
while aStream.Read(c, sizeof(c)) = 1 do
begin
case PeekState of
sString: begin
// deode a string
if c = '\' then
begin
PushState(sStringEscape);
continue;
end;
if c = '"' then
begin
// string end -> return
PopState;
break;
end
else
Result := Result + String(c);
end;
sStringEscape: begin
// last character was escaped
// -> check current
if c = 'u' then
begin
sHlp := '$';
PushState(sStringEscHex); // next four chars are hex chars
continue;
end;
if (c = '"') or (c = '\') or (c = '/')
then
Result := Result + String(c)
else if c = 'b'
then
Result := Result + #8
else if c = 't'
then
Result := Result + #9
else if c = 'r'
then
Result := Result + #10
else if c = 'f'
then
Result := Result + #12
else if c = 'n'
then
Result := Result + #13
else
raise EReadError.Create('JSON string not encoded correctly ');
PopState;
end;
sStringEscHex: begin
if c in ['0'..'9', 'a'..'f', 'A'..'F']
then
sHlp := sHlp + String(c)
else
raise EReadError.Create('Not a correct hex value');
if Length(sHlp) = 5 then
begin
Result := Result + Char( StrToInt(sHlp) );
PopState;
PopState;
end;
end;
else
raise EReadError.Create('Incorrect state when reading strings');
end;
end;
end;
function ReadList(readIntVal : boolean) : TDoubleDynArray;
var c : AnsiChar;
retCnt : integer;
begin
PushState(slistNextValue);
Result := nil;
retCnt := 0;
while stateIdx > 0 do
begin
aStream.ReadBuffer(c, sizeof(c));
case PeekState of
slistValue: begin
if IsWhiteSpace(c) then
continue;
if c = ',' then
begin
PopState;
PushState(slistNextValue);
end
else if c = ']' then
begin
// ###################################
// #### Break the loop here!
break;
end
else
raise EReadError.Create('Error unrecognized character when reading the list');
end;
slistNextValue: begin
if IsWhiteSpace(c) then
continue;
if c in ['+', '-', '0'..'9'] then
begin
if retCnt >= Length(Result) then
SetLength(Result, Min(Length(Result) + 100, 1 + 2*Length(Result)));
if readIntVal
then
Result[retCnt] := ReadInt(c)
else
Result[retCnt] := ReadNumeric(c);
inc(retCnt);
PopState;
PushState(slistValue);
end;
end;
else
raise EReadError.Create('Error state not recognized in reading a list');
end;
end;
PopState;
SetLength(Result, retCnt);
end;
function ReadListDouble : TDoubleDynArray;
begin
Result := ReadList(False);
end;
function ReadListInt : TIntegerDynArray;
var dblArr : TDoubleDynArray;
counter : integer;
begin
dblArr := ReadList(True);
SetLength(Result, Length(dblArr));
for counter := 0 to Length(Result) - 1 do
Result[counter] := round(dblArr[counter]);
end;
begin
states := nil;
stateIdx := 0;
Result := nil;
listType := jlNone;
listCnt := 0;
listD := nil;
listO := nil;
listI := nil;
listS := nil;
listdd := nil;
listii := nil;
sProp := '';
PushState(sObj);
while stateIdx > 0 do
begin
aStream.ReadBuffer(c, sizeof(c));
case PeekState of
sObj: begin
// white spaces are allowed (and ignored)
if IsWhiteSpace(c) then
continue;
if c = '"' then
begin
sProp := ReadString;
PopState;
PushState(sPropertyEnd);
end
else
raise EReadError.Create('Decode Error - no property found');
end;
sPropertyEnd: begin
if IsWhiteSpace(c) then
continue;
if c = ':' then
begin
PopState;
PushState(sValueBegin);
end;
end;
sValueBegin: begin
if IsWhiteSpace(c) then
continue;
if c = '"' then
begin
PushState(sString);
sVal := ReadString;
if sProp = '' then
raise EReadError.Create('Error - no object name given');
if sameText(sProp, 'lib') then
begin
if not SameText(sVal, 'mrMath') then
raise EReadError.Create('Error wrong lib qualifier');
end
else if SameText(sProp, 'obj') then
begin
mathIOClass := MathIOClassFromName(sVal);
if not Assigned(mathIOClass) then
raise EReadError.Create('Unknown class ' + sVal);
Result := mathIOClass.Create;
end
else
begin
if not Assigned(Result) then
raise EReadError.Create('Error no object type given before a value has been read.');
if (Length(sVal) > 2) and (sVal[1] = '0') and (sVal[2] = 'x') then
begin
// decode binary property...
binDat := DecodeStringToBinary(sVal);
if Length(binDat) = 0 then
raise EReadError.Create('Error: No binary data decoded');
ReadBinaryProperty(Result, sProp, binDat[0], Length(binDat));
end
else
ReadStringProperty(Result, sProp, sVal);
end;
sProp := '';
sVal := '';
PopState;
PushState(sValueEnd);
end
else if c in ['+', '-', '0'..'9'] then
begin
iVal := 0;
dVal := 0;
if SameText(sProp, 'Version') then
begin
version := ReadInt(c);
WriteVersion(version);
// todo: do something with the version
PopState;
PushState(sValueEnd);
continue;
end;
if not Assigned(Result) then
raise EReadError.Create('Error no object type given before a value has been read.');
numType := PropTypeOfName(Result, sProp);
intIdx := Pos('_i', sProp);
if (IntIdx > 0) and (intIdx = Length(sProp) - 1) then
begin
SetLength(sProp, Length(sProp) - 2);
numType := ptInteger;
end;
if numType = ptInteger
then
iVal := ReadInt(c)
else
dVal := ReadNumeric(c);
if sProp = '' then
raise EReadError.Create('Error - no object name given');
if numType = ptInteger
then
ReadIntProperty(Result, sProp, iVal)
else
ReadDoubleProperty(Result, sProp, dVal);
sProp := '';
sVal := '';
PopState;
PushState(sValueEnd);
end
else if c = '[' then
begin
PopState;
PushState(sListBegin);
listCnt := 0;
listType := jlNone;
end
else if c = '{' then
begin
aObj := InternalLoadFromStream(aStream);
if not Assigned(Result) then
raise EReadError.Create('Error no object type given before a value has been read.');
if sProp = '' then
raise EReadError.Create('Error - no object name given');
if not ReadObject( Result, sProp, aObj ) then
aObj.Free;
sProp := '';
PopState;
PushState(sValueEnd);
end
else if c = '[' then
begin
listCnt := 0;
listType := jlNone;
PopState;
PushState(sListBegin);
end
else
raise EReadError.Create('Error illegal character');
end;
sListBegin: begin
if IsWhiteSpace(c) then
continue;
if c = ']' then
begin
// empty list...
PopState;
PushState(sValueEnd);
end
else if c = '"' then
begin
if listType = jlNone
then
listType := jlString
else
raise EReadError.Create('Error list already initalized');
if listCnt >= Length(listS) then
SetLength(listS, Min(length(listS) + 100, 1 + 2*Length(listS)));
listS[listCnt] := ReadString;
inc(listCnt);
PopState;
PushState(slistValue);
end
else if c = '{' then
begin
if listType = jlNone
then
listType := jlObject
else
raise EReadError.Create('Error list already initalized');
if listCnt >= Length(listO) then
SetLength(listO, Min(length(listO) + 100, 1 + 2*Length(listO)));
listO[listCnt] := InternalLoadFromStream(aStream);
inc(listCnt);
PopState;
PushState(slistValue);
end
else if c = '[' then
begin
if listType <> jlNone then
raise EReadError.Create('Error list already initalized');
intIdx := Pos('_i', sProp);
numType := PropTypeOfName(Result, sProp);
if (numType = ptInteger) or ((intIdx > 0) and (intIdx = Length(sProp) - 1)) then
begin
if numType <> ptInteger then
SetLength(sProp, Length(sProp) - 2);
listType := jlIntArr;
if listCnt >= Length(listII) then
SetLength(listII, Min(length(listII) + 100, 1 + 2*Length(listII)));
end
else
begin
listType := jlDoubleArr;
if listCnt >= Length(listDD) then
SetLength(listDD, Min(length(listDD) + 100, 1 + 2*Length(listDD)));
end;
if listType = jlDoubleArr
then
listDD[listCnt] := ReadListDouble
else
listII[listCnt] := ReadListInt;
inc(listCnt);
PopState;
PushState(slistValue);
end
else if c in ['0'..'9', '+', '-'] then
begin
if listType <> jlNone then
raise EReadError.Create('Error list already initalized');
intIdx := Pos('_i', sProp);
numType := PropTypeOfName(Result, sProp);
if (numType = ptInteger) or ((intIdx > 0) and (intIdx = Length(sProp) - 1)) then
begin