databricks-iac/vpc.tf at main · mmmmxa/databricks-iac · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
resource "aws_vpc" "databricks" {
  cidr_block           = "10.0.0.0/16"
  enable_dns_hostnames = true
  enable_dns_support   = true

  tags = {
    Name = "databricks-vpc"
  }
}

resource "aws_internet_gateway" "databricks" {
  vpc_id = aws_vpc.databricks.id

  tags = {
    Name = "databricks-igw"
  }
}

resource "aws_subnet" "public" {
  vpc_id                  = aws_vpc.databricks.id
  cidr_block              = "10.0.1.0/24"
  availability_zone       = "${var.region}a"
  map_public_ip_on_launch = true

  tags = {
    Name = "databricks-public"
  }
}

resource "aws_subnet" "private_a" {
  vpc_id            = aws_vpc.databricks.id
  cidr_block        = "10.0.2.0/24"
  availability_zone = "${var.region}a"

  tags = {
    Name = "databricks-private-a"
  }
}

resource "aws_subnet" "private_b" {
  vpc_id            = aws_vpc.databricks.id
  cidr_block        = "10.0.3.0/24"
  availability_zone = "${var.region}b"

  tags = {
    Name = "databricks-private-b"
  }
}

resource "aws_eip" "nat" {
  domain = "vpc"

  tags = {
    Name = "databricks-nat-eip"
  }
}

resource "aws_nat_gateway" "databricks" {
  allocation_id = aws_eip.nat.id
  subnet_id     = aws_subnet.public.id

  tags = {
    Name = "databricks-nat"
  }

  depends_on = [aws_internet_gateway.databricks]
}

resource "aws_route_table" "public" {
  vpc_id = aws_vpc.databricks.id

  route {
    cidr_block = "0.0.0.0/0"
    gateway_id = aws_internet_gateway.databricks.id
  }

  tags = {
    Name = "databricks-public-rt"
  }
}

resource "aws_route_table_association" "public" {
  subnet_id      = aws_subnet.public.id
  route_table_id = aws_route_table.public.id
}

resource "aws_route_table" "private" {
  vpc_id = aws_vpc.databricks.id

  route {
    cidr_block     = "0.0.0.0/0"
    nat_gateway_id = aws_nat_gateway.databricks.id
  }

  tags = {
    Name = "databricks-private-rt"
  }
}

resource "aws_route_table_association" "private_a" {
  subnet_id      = aws_subnet.private_a.id
  route_table_id = aws_route_table.private.id
}

resource "aws_route_table_association" "private_b" {
  subnet_id      = aws_subnet.private_b.id
  route_table_id = aws_route_table.private.id
}

resource "aws_security_group" "databricks" {
  name        = "databricks-sg"
  description = "Security group for Databricks clusters"
  vpc_id      = aws_vpc.databricks.id

  tags = {
    Name = "databricks-sg"
  }
}

resource "aws_security_group_rule" "ingress_self_tcp" {
  type              = "ingress"
  from_port         = 0
  to_port           = 65535
  protocol          = "tcp"
  security_group_id = aws_security_group.databricks.id
  self              = true
}

resource "aws_security_group_rule" "ingress_self_udp" {
  type              = "ingress"
  from_port         = 0
  to_port           = 65535
  protocol          = "udp"
  security_group_id = aws_security_group.databricks.id
  self              = true
}

resource "aws_security_group_rule" "egress_all" {
  type              = "egress"
  from_port         = 0
  to_port           = 0
  protocol          = "-1"
  cidr_blocks       = ["0.0.0.0/0"]
  security_group_id = aws_security_group.databricks.id
}

resource "databricks_mws_networks" "this" {
  provider           = databricks.mws
  account_id         = var.databricks_account_id
  network_name       = "${var.prefix}-network"
  security_group_ids = [aws_security_group.databricks.id]
  subnet_ids         = [aws_subnet.private_a.id, aws_subnet.private_b.id]
  vpc_id             = aws_vpc.databricks.id
}