-
Notifications
You must be signed in to change notification settings - Fork 2
/
Copy path.vimrc
executable file
·1478 lines (1282 loc) · 53.5 KB
/
.vimrc
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
" vim: foldmethod=marker
" __ ___ __ __ __
" \ \ / (_)_ __ _ _ __ / _|___ _ _ | \/ |___ _ __ _ __
" \ V /| | ' \| '_/ _| | _/ _ \ '_| | |\/| / _ \ '_ \ '_ \
" \_/ |_|_|_|_|_| \__| |_| \___/_| |_| |_\___/ .__/ .__/
" |_| |_|
set nocompatible
" Encoding. {{{
if has('vim_starting')
" Changing encoding in Vim at runtime is undefined behavior.
set encoding=utf-8
set fileencodings=utf-8,sjis,cp932,euc-jp
set fileformats=unix,mac,dos
endif
" This command has to be after `set encoding`.
scriptencoding utf-8
" }}}
" Indent. {{{
set autoindent
set backspace=indent,eol,start
set breakindent
set expandtab
set shiftwidth=4
set smartindent
set tabstop=4
" }}}
" Appearance. {{{
set cmdheight=2
set conceallevel=2
set display=lastline
set foldmethod=indent
set laststatus=2
set list
set listchars=tab:>\ ,trail:\ ,extends:<,precedes:<
set noarabicshape
set noshowcmd
set noshowmode
set nowrap
set number
set relativenumber
set scrolloff=3
set showmatch
set showtabline=2
set signcolumn=yes
set statusline=%<%F\ %m%r%h%w%y%{'['.(&fenc!=''?&fenc:&enc).']['.&fileformat.']'}%=%l/%L,%c%V%8P
set synmaxcol=512
" }}}
" Safety. {{{
set backup
set backupdir=~/.vim/backup
set directory=~/.vim/swap
set swapfile
set writebackup
" }}}
" History {{{
set history=2048
set undodir=~/.vim/undo
set undofile
set viewoptions=cursor,folds
" }}}
" Search. {{{
set hlsearch
set ignorecase
set incsearch
set smartcase
" }}}
" Others. {{{
set belloff=all
set completeopt=menu
set dictionary=/usr/share/dict/words
set diffopt+=iwhite
set formatoptions+=tjrol
set helplang=ja
set langnoremap
set lazyredraw
set matchpairs+=<:>
set mouse=
set regexpengine=2
set splitright
set updatetime=500
set virtualedit=all
set whichwrap=b,s,h,l,<,>,[,]
set wildignorecase
set wildmenu
" neovim only.
set inccommand=split
set scrollback=5000
set wildoptions=
" Turn off default plugins. {{{
let g:loaded_2html_plugin = 1
let g:loaded_gzip = 1
let g:loaded_rrhelper = 1
let g:loaded_tar = 1
let g:loaded_tarPlugin = 1
let g:loaded_vimballPlugin = 1
let g:loaded_zip = 1
let g:loaded_zipPlugin = 1
let g:loaded_matchparen = 1
" }}}
" Configs for default scripts. {{{
let g:lisp_rainbow = 1
let g:lisp_instring = 1
let g:lispsyntax_clisp = 1
let g:c_syntax_for_h = 1
let g:tex_conceal = ''
let g:tex_flavor = 'latex'
let g:markdown_folding = 1
" }}}
" }}}
" Mappings. {{{
" :help map-table
"---------------------------------------------------------------------------"
" Commands \ Modes | Normal | Insert | Command | Visual | Select | Operator |
"------------------|--------|--------|---------|--------|--------|----------|
" map / noremap | @ | - | - | @ | @ | @ |
" nmap / nnoremap | @ | - | - | - | - | - |
" vmap / vnoremap | - | - | - | @ | @ | - |
" omap / onoremap | - | - | - | - | - | @ |
" xmap / xnoremap | - | - | - | @ | - | - |
" smap / snoremap | - | - | - | - | @ | - |
" map! / noremap! | - | @ | @ | - | - | - |
" imap / inoremap | - | @ | - | - | - | - |
" cmap / cnoremap | - | - | @ | - | - | - |
"---------------------------------------------------------------------------"
" Set <Leader> and <LocalLeader>.
let g:mapleader = ' '
let g:maplocalleader = '\'
noremap <silent> j gj
noremap <silent> k gk
noremap ; :
noremap : ;
" Avoiding getting <NUL> from <C-Space>.
map <NUL> <C-Space>
map! <NUL> <C-Space>
" Movings.
noremap! <C-F> <Right>
noremap! <C-B> <Left>
noremap! <C-D> <Del>
cnoremap <C-A> <HOME>
cnoremap <C-E> <END>
cnoremap <C-P> <Up>
cnoremap <C-N> <Down>
noremap <silent> <C-J> G
noremap <silent> <C-K> gg
noremap <silent> <C-H> ^
noremap <silent> <C-L> $
" Managing tab.
nnoremap <Leader>to :<C-U>tabnew<Space>
nnoremap <silent> <Leader>tc <Cmd>tabclose<CR>
nnoremap <silent> <Leader>j gT
nnoremap <silent> <Leader>k gt
" Changing window size.
noremap <silent> <S-Left> <Cmd>wincmd <<CR>
noremap <silent> <S-Right> <Cmd>wincmd ><CR>
noremap <silent> <S-Up> <Cmd>wincmd -<CR>
noremap <silent> <S-Down> <Cmd>wincmd +<CR>
" Yank & Paste {{{
function! s:paste_with_register(register, paste_type, paste_cmd) abort " {{{
let l:reg_type = getregtype(a:register)
let l:store = getreg(a:register)
call setreg(a:register, l:store, a:paste_type)
exe 'normal! "' . a:register . a:paste_cmd
call setreg(a:register, l:store, l:reg_type)
endfunction " }}}
function! s:copy_to_clipboard() abort " {{{
let l:store = @@
silent normal! gvy
let l:selected = @@
let @@ = l:store
let @+ = l:selected
let @* = l:selected
endfunction " }}}
nnoremap <silent> Y y$
nnoremap <silent> <Leader>gp <Cmd>set paste!<CR>
xmap <silent> m <Nop>
nmap <silent> m <Nop>
xnoremap <silent> mY :<C-U>call <SID>copy_to_clipboard()<CR>
nnoremap <silent> mlp <Cmd>call <SID>paste_with_register('+', 'l', 'p')<CR>
nnoremap <silent> mlP <Cmd>call <SID>paste_with_register('+', 'l', 'P')<CR>
nnoremap <silent> mcp <Cmd>call <SID>paste_with_register('+', 'c', 'p')<CR>
nnoremap <silent> mcP <Cmd>call <SID>paste_with_register('+', 'c', 'P')<CR>
nnoremap <silent> mp <Cmd>call <SID>paste_with_register('+', 'l', 'p')<CR>
" }}}
" Overwrite the current line with yanked text.
nnoremap <silent> go pk"_dd
" Open help of a word under the cursor.
nnoremap <silent> <Leader>hh :<C-U>help <C-R><C-W><CR>
nnoremap <silent> <Leader>ht :<C-U>tab help <C-R><C-W><CR>
" Adding blank lines.
nnoremap <silent><expr> <CR> &buftype ==# 'quickfix' ? '<CR>' : '<Cmd>call append(".", repeat([""], v:count1))<CR>'
nnoremap <silent> <S-CR> <Cmd>call append(line('.') - 1, repeat([''], v:count1))<CR>
" Change tab local current directory to the directory of the file at the current window.
nnoremap <silent> <Leader>cd <Cmd>tcd %:p:h<CR>
" Open list if there are multiple tags.
nmap <silent> <C-]> <Nop>
nnoremap <silent> <C-]><C-]> g<C-]>zz
" Tab version `<C-]>`.
nnoremap <silent> <C-]><C-T> <C-W><C-]><C-W>T
" Repeat the previous macro.
nnoremap <silent> Q @@
" Turn off highlight of the current search words.
nnoremap <silent> <Esc><Esc> <Cmd>nohlsearch<CR>
" Save the current buffer.
nnoremap <silent> <Leader>w <Cmd>write<CR>
" Close the current window.
nnoremap <silent> <Leader>q <Cmd>quit<CR>
" Replace selected text.
vnoremap <C-R> "hy:%s/\V<C-R>h//g<left><left>
" Open vimrc at newtab.
nnoremap <silent> <Leader>ev <Cmd>tab drop $MYVIMRC<CR>
" Tab version `gf`.
nnoremap <silent> gtf :<C-U>execute 'tabnew' expand('<cfile>')<CR>
" Keep indent
nnoremap <silent><expr> i empty(getline('.')) ? 'S' : 'i'
nnoremap <silent><expr> a empty(getline('.')) ? 'S' : 'a'
" Terminal.
tnoremap <silent> <ESC> <C-\><C-n>
nnoremap <silent> <Leader>tm <Cmd>terminal<CR>
nnoremap <silent> <Leader>vpt <Cmd>split +terminal<CR>
nnoremap <silent> <Leader>vst <Cmd>vsplit +terminal<CR>
nnoremap <silent> <Leader>vtt <Cmd>tabnew +terminal<CR>
" }}}
" Autocommands {{{
augroup vimrc
" Remove all vimrc autocommands
autocmd!
" Turning off paste when escape insert mode.
autocmd InsertLeave * setlocal nopaste
" Store and load view.
autocmd BufWinLeave * if (bufname('%') != '') | mkview! | endif
autocmd BufWinEnter * if (bufname('%') != '') | silent! loadview | endif
" Detecting filetypes.
autocmd BufWinEnter *.nas nested setlocal filetype=nasm
autocmd BufWinEnter *.plt nested setlocal filetype=gnuplot
autocmd BufWinEnter *.sh nested setlocal filetype=sh
autocmd BufWinEnter *.toml nested setlocal filetype=toml
autocmd BufWinEnter *.{md,mdwn,mkd,mkdn} nested setlocal filetype=markdown conceallevel=0
autocmd BufWinEnter *.{pde,ino} nested setlocal filetype=arduino
autocmd TermOpen * nnoremap <silent><buffer> <Enter> A
if executable('fcitx5-remote')
" Disable IME when back to normal mode.
autocmd InsertLeave,CmdLineLeave * call system('fcitx5-remote -c')
endif
augroup END
" }}}
" Functions {{{
function! s:remove_tail_spaces() abort " {{{
if &filetype !=# 'markdown'
let l:c = getpos('.')
keeppatterns %s/\s\+$//ge
call setpos('.', l:c)
endif
endfunction
autocmd vimrc BufWritePre * silent call s:remove_tail_spaces()
" }}}
function! s:define_quickfix_mappings() abort
nnoremap <silent><buffer> q :<C-U>q<CR>
nnoremap <silent><buffer> <ESC> :<C-U>q<CR>
nnoremap <silent><buffer> t <C-W>gF<CR>
nnoremap <silent><buffer><nowait> s <C-W>F<CR>
nnoremap <silent><buffer> v <C-W>F<C-W>L<CR>
endfunction
autocmd vimrc FileType qf call s:define_quickfix_mappings()
" }}}
" Commands. {{{
" Reload .vimrc
command! ReloadVimrc :source $MYVIMRC
" Echo highlight name of an object under the cursor.
command! EchoHiID echomsg synIDattr(synID(line('.'), col('.'), 1), 'name')
" Evaluate the given number expression using the specified radix. {{{
let s:format = { 2: '0b%b', 8: '0o%o', 10: '%d', 16: '0x%x' }
function! s:eval_with_radix(base, exp) abort " {{{
let result = eval(a:exp)
if type(0) != type(result)
throw 'The result of the given expression have to be Number'
endif
return printf(s:format[a:base], result)
endfunction " }}}
inoremap <silent><expr> <C-G><C-B> <SID>eval_with_radix(2, input('= '))
inoremap <silent><expr> <C-G><C-O> <SID>eval_with_radix(8, input('= '))
inoremap <silent><expr> <C-G><C-D> <SID>eval_with_radix(10, input('= '))
inoremap <silent><expr> <C-G><C-H> <SID>eval_with_radix(16, input('= '))
" }}}
" Preview a converted number by each radix. {{{
function! PreviewRadixesInsert() abort
let l:n = line('.') - 1
quit
execute printf('normal! i%s', g:preview_radixes_values[l:n])
endfunction
function! PreviewRadixesAppend() abort
let l:n = line('.') - 1
quit
execute printf('normal! a%s', g:preview_radixes_values[l:n])
endfunction
function! PreviewRadixesReplace() abort
let l:n = line('.') - 1
quit
execute printf('normal! "_ciw%s', g:preview_radixes_values[l:n])
endfunction
function! s:preview_radixes(input) abort " {{{
let l:integer = str2nr(a:input)
if string(l:integer) != a:input
echohl ErrorMsg | echo 'The given value `' . a:input . '` is NOT number.' | echohl None
return
endif
let g:preview_radixes_values = [
\ printf('0b%b', l:integer),
\ printf('0o%o', l:integer),
\ printf('%d', l:integer),
\ printf('0x%x', l:integer),
\ ]
let l:content = [
\ printf(' Bin: 0b%b ', l:integer),
\ printf(' Oct: 0o%o', l:integer),
\ printf(' Dec: %d', l:integer),
\ printf(' Hex: 0x%x', l:integer),
\ ]
let l:buf = nvim_create_buf(v:false, v:true)
call nvim_buf_set_lines(l:buf, 0, -1, v:true, l:content)
let l:opts = {'noremap': v:true, 'nowait': v:true}
" Exit.
call nvim_buf_set_keymap(l:buf, 'n', 'q', 'ZQ', l:opts)
" Copy the number.
call nvim_buf_set_keymap(l:buf, 'n', '<cr>', '02Wyiw', {})
" Insert the number.
call nvim_buf_set_keymap(l:buf, 'n', 'i', '<Cmd>call PreviewRadixesInsert()<CR>', l:opts)
" Append the number.
call nvim_buf_set_keymap(l:buf, 'n', 'a', '<Cmd>call PreviewRadixesAppend()<CR>', l:opts)
" Replace the current cursor word by the number.
call nvim_buf_set_keymap(l:buf, 'n', 'r', '<Cmd>call PreviewRadixesReplace()<CR>', l:opts)
let l:opts = {
\ 'relative': 'cursor',
\ 'height': len(l:content),
\ 'width': max(map(l:content, {_, c -> len(c)})),
\ 'row': 1,
\ 'col': 0,
\ 'style': 'minimal'
\ }
call nvim_open_win(l:buf, v:true, l:opts)
endfunction " }}}
command! -nargs=0 PreviewRadixes call <SID>preview_radixes(expand('<cword>'))
command! -nargs=? PreviewRadixesEval call <SID>preview_radixes(eval(len(<q-args>) ? <q-args> : input('= ')))
" }}}
" Convert the given word case. {{{
function! PreviewWordCasesReplace(n) abort
if a:n == 0
let l:n = line('.') - 1
elseif 4 < a:n
echoerr 'invalid'
return
else
let l:n = a:n
endif
quit
execute printf('normal! "_ciw%s', g:preview_word_cases_values[l:n])
endfunction
function! s:to_lower_snake_case(str) abort
if empty(a:str) == 1
return ''
endif
if stridx(a:str, '_') == -1
" UpperCamelCase or lowerCamelCase
return tolower(a:str[0]) . substitute(a:str[1:-1], '\(\u\)', '\="_" . tolower(submatch(1))', 'g')
else
" lower_snake_case or UPPER_SNAKE_CASE
return tolower(a:str)
endif
endfunction
function! s:to_upper_snake_case(str) abort
return toupper(s:to_lower_snake_case(a:str))
endfunction
function! s:to_lower_camel_case(str) abort
if empty(a:str) == 1
return ''
endif
if stridx(a:str, '_') == -1
" UpperCamelCase or lowerCamelCase
return tolower(a:str[0]) . a:str[1 : -1]
else
" lower_snake_case or UPPER_SNAKE_CASE
return substitute(tolower(a:str), '_\(.\)', '\=toupper(submatch(1))', 'g')
endif
endfunction
function! s:to_upper_camel_case(str) abort
if empty(a:str) == 1
return ''
endif
let l:str = s:to_lower_camel_case(a:str)
return toupper(l:str[0]) . l:str[1 : -1]
endfunction
function! s:preview_word_cases(word) abort " {{{
let g:preview_word_cases_values = [
\ s:to_lower_snake_case(a:word),
\ s:to_upper_snake_case(a:word),
\ s:to_lower_camel_case(a:word),
\ s:to_upper_camel_case(a:word)
\ ]
let l:content = [
\ ' 1: ' . g:preview_word_cases_values[0] . ' ',
\ ' 2: ' . g:preview_word_cases_values[1] . ' ',
\ ' 3: ' . g:preview_word_cases_values[2] . ' ',
\ ' 4: ' . g:preview_word_cases_values[3] . ' '
\ ]
let l:buf = nvim_create_buf(v:false, v:true)
call nvim_buf_set_lines(l:buf, 0, -1, v:true, l:content)
let l:opts = #{noremap: v:true, nowait: v:true, silent: v:true}
" Exit.
call nvim_buf_set_keymap(l:buf, 'n', 'q', 'ZQ', l:opts)
call nvim_buf_set_keymap(l:buf, 'n', '<ESC>', 'ZQ', l:opts)
" Copy the word.
call nvim_buf_set_keymap(l:buf, 'n', 'y', '02Wyiw', {})
" Replace the current cursor word by the selected case.
call nvim_buf_set_keymap(l:buf, 'n', '<CR>', '<Cmd>call PreviewWordCasesReplace(0)<CR>', l:opts)
call nvim_buf_set_keymap(l:buf, 'n', '1', '<Cmd>call PreviewWordCasesReplace(1)<CR>', l:opts)
call nvim_buf_set_keymap(l:buf, 'n', '2', '<Cmd>call PreviewWordCasesReplace(2)<CR>', l:opts)
call nvim_buf_set_keymap(l:buf, 'n', '3', '<Cmd>call PreviewWordCasesReplace(3)<CR>', l:opts)
call nvim_buf_set_keymap(l:buf, 'n', '4', '<Cmd>call PreviewWordCasesReplace(4)<CR>', l:opts)
let l:opts = #{
\ relative: 'cursor',
\ height: len(l:content),
\ width: max(map(l:content, {_, c -> len(c)})),
\ row: 1,
\ col: 0,
\ style: 'minimal'
\ }
call nvim_open_win(l:buf, v:true, l:opts)
endfunction " }}}
command! -nargs=0 PreviewWordCases call <SID>preview_word_cases(expand('<cword>'))
" }}}
" Keep last session. {{{
let s:session_directory = '~/.vim/sessions/'
let s:last_session_filepath = s:session_directory . 'last_session.vim'
" Save session automatically.
autocmd vimrc VimLeave * execute 'mksession!' s:last_session_filepath
function! s:save_session(...) abort
execute 'mksession!' (a:0 == 0) ? (s:last_session_filepath) : (s:session_directory . a:1)
endfunction
function! s:get_session_list(arguments, cmd_line, cursor_pos) abort
let l:filepaths = split(glob(s:session_directory . '*'), '\n')
return map(l:filepaths, {i, v -> fnamemodify(v, ':t')})
endfunction
command! -nargs=? -complete=customlist,<SID>get_session_list SaveSession call <SID>save_session(<f-args>)
command! -nargs=1 -complete=customlist,<SID>get_session_list LoadSession execute 'source' s:session_directory . <q-args>
command! -nargs=0 LoadLastSession execute 'source' s:last_session_filepath
" }}}
" Create Vim directories if not found. {{{
command! -nargs=0 CreateVimDirectories call s:create_vim_directories()
function! s:create_vim_directories() abort
let base_dir = fnamemodify($MYVIMRC, ':h') . '/'
call mkdir(base_dir . 'sessions', 'p')
call mkdir(base_dir . 'undo', 'p')
call mkdir(base_dir . 'backup', 'p')
call mkdir(base_dir . 'swap', 'p')
call mkdir(base_dir . 'swap', 'p')
endfunction
" }}}
" Hide left columns {{{
function! s:hide_left_columns() abort
setlocal nonumber
setlocal norelativenumber
setlocal signcolumn=no
setlocal foldcolumn=0
endfunction
command! HideLeftColumns call s:hide_left_columns()
autocmd vimrc TermOpen * call s:hide_left_columns()
" }}}
" Toggle relative number {{{
function! s:toggle_relative_number() abort
let b:relnum = !get(b:, 'relnum', 1)
setlocal relativenumber!
setlocal number
endfunction
command! ToggleRelativeNumber call s:toggle_relative_number()
augroup vimrc
autocmd BufEnter,FocusGained,InsertLeave,WinEnter * if &nu && get(b:, 'relnum', 1) | setlocal relativenumber | endif
autocmd BufLeave,FocusLost,InsertEnter,WinLeave * if &nu && get(b:, 'relnum', 1) | setlocal norelativenumber | endif
augroup END
" }}}
" jq command wrapper. {{{
function! s:jq(...) abort " {{{
execute '%! jq ' . (a:0 ? a:1 : '.')
setlocal filetype=json
endfunction " }}}
command! -nargs=? Jq call s:jq(<f-args>)
" }}}
command! -nargs=0 RemoveBlankLines :global/^\s*$/delete
" Gote {{{
let s:gote_dir = $HOME . '/notes'
function! s:gote() abort
execute 'tcd' s:gote_dir
FernExplorer
endfunction
command! -nargs=0 GoteOpen call s:gote()
function! s:gote_today() abort " {{{
call s:gote()
wincmd l
let l:datestr = strftime('%Y-%m-%d')
execute 'drop' strftime(s:gote_dir . '/daily/' . l:datestr . '.md')
let l:text = [
\'## ' . l:datestr ,
\'',
\'### 今日やったこと',
\'',
\'### 明日やること',
\'',
\'### 雑記',
\'',
\]
call append(0, l:text)
call cursor(4, 0)
endfunction " }}}
command! -nargs=0 GoteToday call s:gote_today()
" }}}
" Copy file path {{{
function s:copy_absolute_path()
let @"=expand('%:p')
endfunction
function s:copy_relative_path()
let @"=expand('%')
endfunction
command! -nargs=0 CopyAbsolutePath call s:copy_absolute_path()
command! -nargs=0 CopyRelativePath call s:copy_relative_path()
" }}}
" }}}
" GUI. {{{
function! s:config_neovide() abort
if has('mac')
set guifont=Cica:h15
else
set guifont=Cica:h14.5
endif
inoremap <silent><D-v> <ESC>l"+Pli
tnoremap <silent><D-v> <C-\><C-N>l"+Pli
cnoremap <D-v> <C-R>+
let g:neovide_cursor_animation_length = 0.0
let g:neovide_scroll_animation_length = 0.1
let g:neovide_hide_mouse_when_typing = v:true
let g:neovide_refresh_rate = 120
endfunction
" apply neopvide config when it uses remove neovim server.
autocmd vimrc UIEnter * call s:config_neovide()
" }}}
" Plugins. {{{
" dein.vim {{{
let s:dein_base_path = expand('~/.vim/bundle/')
let s:dein_path = s:dein_base_path . 'repos/github.com/Shougo/dein.vim'
let s:has_dein = isdirectory(s:dein_path)
let &runtimepath .= ',' . s:dein_path
let g:dein#install_log_filename = '~/.vim/dein.log'
if s:has_dein && dein#min#load_state(s:dein_base_path) " {{{
call dein#begin(s:dein_base_path)
call dein#add('Shougo/dein.vim')
call dein#add('haya14busa/dein-command.vim', #{lazy: v:true, on_event: 'CmdlineEnter'})
call dein#add('vim-denops/denops.vim')
" Completions {{{
call dein#add('Shougo/ddc.vim')
call dein#add('Shougo/pum.vim')
" UI
call dein#add('Shougo/ddc-ui-native')
" Source
call dein#add('LumaKernel/ddc-source-file')
call dein#add('Shougo/ddc-source-around')
call dein#add('Shougo/ddc-source-line')
call dein#add('Shougo/neco-vim', #{lazy: v:true})
call dein#add('matsui54/ddc-buffer')
call dein#add('shun/ddc-source-vim-lsp')
call dein#add('Shougo/neco-syntax', #{lazy: v:true})
call dein#add('hokorobi/ddc-source-neco-syntax')
call dein#add('Shougo/neosnippet.vim', #{lazy: v:true})
call dein#add('Shougo/neosnippet-snippets')
call dein#add('honza/vim-snippets', #{lazy: v:true})
" Filter
call dein#add('tani/ddc-fuzzy')
call dein#add('Shougo/ddc-filter-matcher_head')
call dein#add('Shougo/ddc-filter-converter_remove_overlap')
" }}}
" Fuzzy finders {{{
call dein#add('Shougo/ddu.vim')
" UI
call dein#add('Shougo/ddu-ui-ff')
" Source
call dein#add('Shougo/ddu-source-action')
call dein#add('Shougo/ddu-source-file_rec')
call dein#add('Shougo/ddu-source-line')
call dein#add('matsui54/ddu-source-file_external')
call dein#add('shun/ddu-source-buffer')
call dein#add('shun/ddu-source-rg')
call dein#add('kuuote/ddu-source-mr')
call dein#add('lambdalisue/mr.vim')
" Filter
call dein#add('Shougo/ddu-filter-matcher_ignore_files')
call dein#add('Shougo/ddu-filter-matcher_relative')
call dein#add('Shougo/ddu-filter-matcher_substring')
call dein#add('gamoutatsumi/ddu-filter-converter_relativepath')
call dein#add('kyoh86/ddu-filter-converter_hl_dir')
" Kind
call dein#add('Shougo/ddu-kind-file')
call dein#add('Shougo/ddu-kind-word')
" }}}
" Operators and textobjs {{{
call dein#add('haya14busa/vim-operator-flashy', #{lazy: v:true, on_map: '<Plug>'})
call dein#add('kana/vim-operator-replace', #{lazy: v:true, on_map: '<Plug>'})
call dein#add('kana/vim-operator-user')
call dein#add('mopp/vim-operator-convert-case', #{lazy: v:true, on_map: '<Plug>'})
call dein#add('kana/vim-textobj-indent', #{lazy: v:true, on_map: [['ox', 'ai' , 'ii' , 'aI', 'iI']]})
call dein#add('kana/vim-textobj-line', #{lazy: v:true, on_map: [['ox', 'al', 'il']]})
call dein#add('kana/vim-textobj-user')
call dein#add('rhysd/vim-textobj-word-column', #{lazy: v:true, on_map: [['ox', 'av', 'iv']]})
call dein#add('sgur/vim-textobj-parameter', #{lazy: v:true, on_map: [['ox', 'a,', 'i,', 'i2,']]})
call dein#add('machakann/vim-sandwich')
" }}}
" LSP {{{
call dein#add('liuchengxu/vista.vim', #{lazy: v:true, on_cmd: 'Vista'})
call dein#add('mattn/vim-lsp-settings')
call dein#add('prabirshrestha/vim-lsp')
" }}}
" git {{{
call dein#add('lambdalisue/gin.vim')
call dein#add('lewis6991/gitsigns.nvim')
call dein#add('rhysd/committia.vim')
call dein#add('tyru/open-browser-github.vim', #{lazy: v:true, on_cmd: ['OpenGithubFile', 'OpenGithubProject', 'OpenGithubPullReq']})
" }}}
" Utils {{{
call dein#add('Chiel92/vim-autoformat', #{lazy: v:true, on_cmd: 'Autoformat'})
call dein#add('FooSoft/vim-argwrap', #{lazy: v:true, on_cmd: 'ArgWrap'})
call dein#add('LeafCage/yankround.vim', #{lazy: v:true, on_map: '<Plug>'})
call dein#add('Shougo/echodoc.vim', #{lazy: v:true, on_event: 'InsertEnter'})
call dein#add('Shougo/vinarise.vim', #{lazy: v:true, on_cmd: 'Vinarise'})
call dein#add('bronson/vim-trailing-whitespace')
call dein#add('chrisbra/Colorizer', #{lazy: v:true, on_cmd: 'ColorToggle'})
call dein#add('cohama/lexima.vim',#{lazy: v:true, on_event: 'InsertEnter', hook_post_source: 'call OnPostSourceLexima()'})
call dein#add('folke/tokyonight.nvim')
call dein#add('idanarye/vim-casetrate', #{lazy: v:true, on_cmd: 'Casetrate'})
call dein#add('inside/vim-search-pulse')
call dein#add('itchyny/lightline.vim')
call dein#add('itchyny/vim-parenmatch')
call dein#add('junegunn/vim-easy-align', #{lazy: v:true, on_cmd: 'EasyAlign', on_map: ['<Plug>(LiveEasyAlign)', '<Plug>(EasyAlign)']})
call dein#add('kana/vim-niceblock', #{lazy: v:true, on_map: [['x', 'I', 'A']]})
call dein#add('kana/vim-tabpagecd')
call dein#add('lambdalisue/fern-git-status.vim')
call dein#add('lambdalisue/fern-hijack.vim')
call dein#add('lambdalisue/fern.vim')
call dein#add('mopp/autodirmake.vim', #{lazy: v:true, on_event: 'InsertEnter'})
call dein#add('osyo-manga/vim-anzu', #{lazy: v:true, on_map: '<Plug>'})
call dein#add('rickhowe/diffchar.vim', #{lazy: &diff == 0, on_if: '&diff'})
call dein#add('simeji/winresizer', #{lazy: v:true, on_cmd: ['WinResizerStartFocus', 'WinResizerStartMove', 'WinResizerStartResize']})
call dein#add('smoka7/hop.nvim')
call dein#add('t9md/vim-choosewin', #{lazy: v:true, on_map: {'n': '<Plug>'}})
call dein#add('t9md/vim-quickhl', #{lazy: v:true, on_map : {'nx': '<Plug>'}})
call dein#add('thinca/vim-ambicmd')
call dein#add('thinca/vim-quickrun', #{lazy: v:true, on_cmd: 'QuickRun'})
call dein#add('thinca/vim-visualstar', #{lazy: v:true, on_map: {'v': ['*', '#']}})
call dein#add('tpope/vim-repeat')
call dein#add('tyru/capture.vim', #{lazy: v:true, on_cmd: 'Capture'})
call dein#add('tyru/open-browser.vim', #{lazy: v:true, on_map: [['n', '<Plug>(openbrowser-open)']], on_func: ['openbrowser#load', 'openbrowser#open'], on_source: ['open-browser-github.vim']})
call dein#add('vim-test/vim-test', #{lazy: v:true, on_cmd: ['TestNearest', 'TestClass', 'TestFile', 'TestSuite', 'TestLast', 'TestVisit']})
" }}}
" treesitter
call dein#add('HiPhish/rainbow-delimiters.nvim')
call dein#add('lukas-reineke/indent-blankline.nvim')
call dein#add('numToStr/Comment.nvim')
call dein#add('nvim-treesitter/nvim-treesitter', #{hook_post_update: 'TSUpdate'})
" Languages
call dein#add('vim-jp/vimdoc-ja')
call dein#end()
call dein#save_state()
endif " }}}
filetype plugin indent on
" ftplugins are loaded when 'filetype on'.
" The autocmds to override filetype local settings have to be executed after 'filetype on'.
augroup vimrc " {{{
autocmd FileType git setlocal nofoldenable
autocmd FileType lisp setlocal nocindent nosmartindent lisp lispwords=define
autocmd FileType text,man setlocal wrap
autocmd FileType help setlocal foldcolumn=0
autocmd FileType ruby,javascript,typescript,typescriptreact,html,css,pony,markdown,terraform setlocal shiftwidth=2
augroup END " }}}
if !s:has_dein " {{{
" Install all plugins.
command! SetupPlugins call s:setup_plugins()
function! s:setup_plugins() abort " {{{
if !executable('git')
echoerr 'git is not found.'
return
endif
call s:create_vim_directories()
execute '!git clone --depth=1 https://github.com/Shougo/dein.vim' s:dein_path
let &runtimepath .= ',' . s:dein_path
let g:is_setup = 1
source $MYVIMRC
call dein#install()
unlet g:is_setup
endfunction " }}}
" Minimum settings.
syntax enable
colorscheme desert
finish
elseif exists('g:is_setup')
finish
endif " }}}
" }}}
" ddc.vim {{{
function! s:config_ddc() abort
inoremap <silent> <C-E> <Cmd>call ddc#hide()<CR>
call dein#source([
\ 'neco-vim',
\ 'neco-syntax',
\ 'neosnippet.vim',
\ 'vim-snippets'
\ ])
let l:basic_sources = ['vim-lsp', 'neosnippet', 'around', 'necosyntax', 'buffer', 'file', 'line']
call ddc#custom#patch_global(#{
\ ui: 'native',
\ sources: l:basic_sources,
\ sourceOptions: #{
\ _: #{
\ matchers: ['matcher_fuzzy'],
\ sorters: ['sorter_fuzzy'],
\ converters: ['converter_fuzzy', 'converter_remove_overlap'],
\ timeout: 1000,
\ minAutoCompleteLength: 3,
\ },
\ vim-lsp: #{
\ mark: '[lsp]',
\ forceCompletionPattern: '\S+(->|.)',
\ maxItems: 8
\ },
\ neosnippet: #{mark: '[snippet]'},
\ around: #{mark: '[around]', maxItems: 8},
\ necosyntax: #{mark: '[syntax]'},
\ buffer: #{mark: '[buffer]', maxItems: 8},
\ file: #{
\ mark: '[file]',
\ isVolatile: v:true,
\ forceCompletionPattern: '\S/\S*',
\ },
\ line: #{mark: '[line]', matchers: ['matcher_head']},
\ necovim: #{mark: '[vim]'},
\ },
\ sourceParams: #{
\ buffer: #{
\ requireSameFiletype: v:false,
\ bufNameStyle: 'basename'
\ },
\ },
\ })
call ddc#custom#patch_filetype(['vim'], 'sources', (['necovim'] + l:basic_sources))
call ddc#enable()
endfunction
autocmd vimrc InsertEnter * call s:config_ddc()
" }}}
" pum.vim {{{
inoremap <C-n> <Cmd>call pum#map#insert_relative(+1)<CR>
inoremap <C-p> <Cmd>call pum#map#insert_relative(-1)<CR>
" }}}
" neosnippet.vim {{{
imap <C-s> <Plug>(neosnippet_expand_or_jump)
smap <C-s> <Plug>(neosnippet_expand_or_jump)
xmap <C-s> <Plug>(neosnippet_expand_target)
" }}}
" ddu.vim {{{
call ddu#custom#alias('default', 'source', 'mr_ignore', 'mr')
call ddu#custom#alias('default', 'source', 'file_rec_ignore', 'file_rec')
call ddu#custom#alias('default', 'source', 'file_external_ignore', 'file_external')
call ddu#custom#alias('default', 'source', 'grep', 'rg')
call ddu#custom#alias('default', 'source', 'grep_ignore', 'rg')
call ddu#custom#patch_global(#{
\ ui: 'ff',
\ uiParams: #{
\ ff: #{
\ autoResize: v:true,
\ statusline: v:false,
\ split: 'floating',
\ floatingBorder: 'double',
\ floatingTitle: 'ddu.vim',
\ floatingTitlePos: 'center',
\ previewFloating: v:true,
\ previewFloatingBorder: 'single',
\ previewFloatingTitle: 'Preview',
\ previewFloatingTitlePos: 'center',
\ }
\ },
\ sourceOptions: #{
\ _: #{
\ matchers: ['matcher_substring'],
\ },
\ mr: #{
\ matchers: ['matcher_relative', 'matcher_substring'],
\ converters: ['converter_relativepath', 'converter_hl_dir'],
\ },
\ mr_ignore: #{
\ matchers: ['matcher_relative', 'matcher_ignore_files', 'matcher_substring'],
\ converters: ['converter_relativepath', 'converter_hl_dir'],
\ },
\ file_rec: #{
\ matchers: ['matcher_substring'],
\ converters: ['converter_relativepath', 'converter_hl_dir'],
\ },
\ file_rec_ignore: #{
\ matchers: ['matcher_ignore_files', 'matcher_substring'],
\ converters: ['converter_relativepath', 'converter_hl_dir'],
\ },
\ file_external: #{
\ matchers: ['matcher_substring'],
\ converters: ['converter_relativepath', 'converter_hl_dir'],
\ },
\ file_external_ignore: #{
\ matchers: ['matcher_ignore_files', 'matcher_substring'],
\ converters: ['converter_relativepath', 'converter_hl_dir'],
\ },
\ grep: #{
\ matchers: ['matcher_substring']
\ },
\ grep_ignore: #{
\ matchers: ['matcher_ignore_files', 'matcher_substring']
\ },
\ },
\ sourceParams: #{
\ file_external: #{
\ cmd: ['git', 'ls-files']
\ },
\ file_external_ignore: #{
\ cmd: ['git', 'ls-files']
\ },
\ },
\ filterParams: #{
\ matcher_ignore_files: #{
\ ignoreGlobs: ['*test/*', '*test\.*', '*_spec*']
\ },
\ },
\ kindOptions: #{
\ action: #{
\ defaultAction: 'do',
\ },
\ file: #{
\ defaultAction: 'open',
\ },
\ word: #{
\ defaultAction: 'yank',
\ },
\ },
\ })
nnoremap <silent> <Leader>fb <Cmd>call ddu#start(#{uiParams: #{ff: #{floatingTitle: 'Buffers'}}, sources: ['buffer']})<CR>
nnoremap <silent> <Leader>ff <Cmd>call ddu#start(#{uiParams: #{ff: #{floatingTitle: 'Most Recently Used'}}, sources: ['mr_ignore']})<CR>
nnoremap <silent> <Leader>fa <Cmd>call ddu#start(#{uiParams: #{ff: #{floatingTitle: 'Most Recently Used'}}, sources: ['mr']})<CR>
nnoremap <silent> <Leader>fl <Cmd>call ddu#start(#{uiParams: #{ff: #{floatingTitle: 'Lines'}}, sources: ['line']})<CR>
nnoremap <silent> <Leader>fre <Cmd>call ddu#start(#{resume: v:true})<CR>
function! s:ddu_file(is_ignore) abort
if system('git rev-parse --is-inside-work-tree') == "true\n"
let l:sources = a:is_ignore ? ['file_external_ignore'] : ['file_external']
else
let l:sources = a:is_ignore ? ['file_rec_ignore'] : ['file_rec']
endif
call ddu#start(#{uiParams: #{ff: #{floatingTitle: 'Files'}}, sources: l:sources})
endfunction
nnoremap <silent> <Leader>fe <Cmd>call <SID>ddu_file(v:true)<CR>
nnoremap <silent> <Leader>ft <Cmd>call <SID>ddu_file(v:false)<CR>
function! s:ddu_grep(is_ignore, input) abort
if system('git rev-parse --is-inside-work-tree') == "true\n"
let l:cmd = 'git'
let l:args = ['--no-pager', 'grep', '--line-number', '--column', '--no-color']