forked from jrh13/hol-light
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathgeometricalgebra.ml
2596 lines (2324 loc) · 132 KB
/
geometricalgebra.ml
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
(* ========================================================================= *)
(* Geometric algebra G(P,Q,R) is formalized with the multivector structure *)
(* (P,Q,R)multivector, which can formulate positive definite, negative *)
(* definite and zero quadratic forms. *)
(* *)
(* (c) Copyright, Capital Normal University, China, 2018. *)
(* Authors: Liming Li, Zhiping Shi, Yong Guan, Guohui Wang, Sha Ma. *)
(* ========================================================================= *)
needs "Multivariate/clifford.ml";;
prioritize_real();;
(* ------------------------------------------------------------------------- *)
(* Add some theorems to clifford.ml *)
(* ------------------------------------------------------------------------- *)
let GEOM_MBASIS_LID = prove
(`!x. mbasis{} * x = x`,
MATCH_MP_TAC MBASIS_EXTENSION THEN SIMP_TAC[GEOM_RMUL; GEOM_RADD] THEN
SIMP_TAC[GEOM_MBASIS; DIFF_EMPTY; EMPTY_DIFF; UNION_EMPTY; EMPTY_SUBSET] THEN
REWRITE_TAC[SET_RULE `{i,j | i IN {} /\ j IN s /\ i:num > j} = {}`] THEN
REWRITE_TAC[CARD_CLAUSES; real_pow; REAL_MUL_LID; VECTOR_MUL_LID]);;
let GEOM_MBASIS_RID = prove
(`!x. x * mbasis{} = x`,
MATCH_MP_TAC MBASIS_EXTENSION THEN SIMP_TAC[GEOM_LMUL; GEOM_LADD] THEN
SIMP_TAC[GEOM_MBASIS; DIFF_EMPTY; EMPTY_DIFF; UNION_EMPTY; EMPTY_SUBSET] THEN
REWRITE_TAC[SET_RULE `{i,j | i IN s /\ j IN {} /\ i:num > j} = {}`] THEN
REWRITE_TAC[CARD_CLAUSES; real_pow; REAL_MUL_LID; VECTOR_MUL_LID]);;
let GEOM_MBASIS_SKEWSYM = prove
(`!i j. mbasis{i} * mbasis{j} =
if i = j then mbasis{j} * mbasis{i} else --(mbasis{j} * mbasis{i})`,
REPEAT GEN_TAC THEN COND_CASES_TAC THEN ASM_REWRITE_TAC[GEOM_MBASIS_SING] THEN
FIRST_ASSUM(DISJ_CASES_TAC o MATCH_MP (ARITH_RULE
`~(i:num = j) ==> i < j /\ ~(j < i) \/ j < i /\ ~(i < j)`)) THEN
ASM_REWRITE_TAC[CONJ_ACI] THEN COND_CASES_TAC THEN
ASM_REWRITE_TAC[VECTOR_NEG_NEG; VECTOR_NEG_0] THEN
REPEAT AP_TERM_TAC THEN SET_TAC[]);;
let GEOM_MBASIS_REFL = prove
(`!i. mbasis{i}:real^(N)multivector * mbasis{i} =
if i IN 1..dimindex (:N) then mbasis {}
else vec 0`,
GEN_TAC THEN REWRITE_TAC[GEOM_MBASIS_SING]);;
(* ------------------------------------------------------------------------- *)
(* Add some basic theorems to the library of clifford *)
(* ------------------------------------------------------------------------- *)
let G_P_Q_R_WITH_G_N = prove
(`!p q r i e.
1 <= p + q + r /\ p + 3 * q + 4 * r <= dimindex(:N) /\
(e i = if 1 <= i /\ i <= p then (mbasis {i}:real^(N)multivector)
else if p + 1 <= i /\ i <= p + q then
(mbasis {(3 * i - 2 * p + r) - 2} * mbasis {(3 * i - 2 * p + r) - 1} * mbasis {3 * i - 2 * p + r })
else if p + q + 1 <= i /\ i <= p + q + r then
(mbasis {i - q} + mbasis {(4 * i - 3 * p - q) - 2} * mbasis {(4 * i - 3 * p - q) - 1} * mbasis {(4 * i - 3 * p) - q })
else vec 0) ==>
e i * e i = if 1 <= i /\ i <= p then mbasis {}
else if p + 1 <= i /\ i <= p + q then -- mbasis {}
else vec 0`,
let lemma = prove
(`!i. 2 < i /\ i<= dimindex(:N) ==>
(mbasis {i-2} * mbasis {i-1} * (mbasis {i}:real^(N)multivector)) * (mbasis {i-2} * mbasis {i-1} * mbasis {i}) = --mbasis {}`,
REPEAT STRIP_TAC THEN
GEN_REWRITE_TAC (LAND_CONV o RAND_CONV o ONCE_DEPTH_CONV)[GEOM_MBASIS_SKEWSYM] THEN
ASM_SIMP_TAC[ARITH_RULE `2 < i ==> ~(i - 1 = i)`] THEN
REWRITE_TAC[GEOM_RNEG] THEN AP_TERM_TAC THEN
GEN_REWRITE_TAC (LAND_CONV o RAND_CONV o ONCE_DEPTH_CONV)[GEOM_ASSOC] THEN
GEN_REWRITE_TAC (LAND_CONV o RAND_CONV o ONCE_DEPTH_CONV)[GEOM_MBASIS_SKEWSYM] THEN
ASM_SIMP_TAC[ARITH_RULE `2 < i ==> ~(i - 2 = i)`] THEN
REWRITE_TAC[GEOM_LNEG; GEOM_RNEG; GSYM GEOM_ASSOC] THEN
GEN_REWRITE_TAC (LAND_CONV o RAND_CONV o RAND_CONV o RAND_CONV o ONCE_DEPTH_CONV)[GEOM_ASSOC] THEN
ASM_REWRITE_TAC[IN_NUMSEG; GEOM_MBASIS_REFL] THEN
ASM_SIMP_TAC[ARITH_RULE `2 < i ==> 1 <= i`; GEOM_MBASIS_LID] THEN
ONCE_REWRITE_TAC[GEOM_MBASIS_SKEWSYM] THEN
ASM_SIMP_TAC[ARITH_RULE `2 < i ==> ~(i - 2 = i - 1)`] THEN
REWRITE_TAC[GEOM_RNEG; VECTOR_NEG_NEG] THEN
GEN_REWRITE_TAC (LAND_CONV o RAND_CONV o ONCE_DEPTH_CONV)[GEOM_ASSOC] THEN
REWRITE_TAC[GEOM_MBASIS_REFL; IN_NUMSEG] THEN
ASM_SIMP_TAC[ARITH_RULE `2 < i /\ i <= dimindex (:N) ==> 1 <= i - 1 /\ i - 1 <= dimindex (:N)`] THEN
REWRITE_TAC[GEOM_MBASIS_LID; GEOM_MBASIS_REFL; IN_NUMSEG] THEN
ASM_SIMP_TAC[ARITH_RULE `2 < i /\ i <= dimindex (:N) ==> 1 <= i - 2 /\ i - 2 <= dimindex (:N)`]) in
REPEAT STRIP_TAC THEN COND_CASES_TAC THENL
[ASM_REWRITE_TAC[GEOM_MBASIS_REFL; IN_NUMSEG] THEN ASM_ARITH_TAC; ALL_TAC] THEN
COND_CASES_TAC THENL
[SUBGOAL_THEN `2 < 3 * i - 2 * p + r /\ 3 * i - 2 * p + r <= dimindex (:N)` ASSUME_TAC THENL
[ASM_ARITH_TAC; ALL_TAC] THEN ASM_SIMP_TAC[lemma]; ALL_TAC] THEN
ASM_REWRITE_TAC[] THEN COND_CASES_TAC THEN REWRITE_TAC[GEOM_LADD; GEOM_RADD; GEOM_RZERO] THEN
ONCE_REWRITE_TAC[VECTOR_ARITH `(a + b) + c + d = (a + d)+(b + c:real^N)`] THEN
GEN_REWRITE_TAC (RAND_CONV o ONCE_DEPTH_CONV)[GSYM VECTOR_ADD_LID] THEN
BINOP_TAC THEN REWRITE_TAC[VECTOR_ARITH `a + b = vec 0 <=> b = --a`] THENL
[REWRITE_TAC[GEOM_MBASIS_REFL; IN_NUMSEG] THEN
SUBGOAL_THEN `2 < 4 * i - 3 * p - q /\ 4 * i - 3 * p - q <= dimindex (:N)` ASSUME_TAC THENL
[ASM_ARITH_TAC; ALL_TAC] THEN ASM_SIMP_TAC[lemma] THEN ASM_ARITH_TAC; ALL_TAC] THEN
REWRITE_TAC[GSYM GEOM_ASSOC] THEN
GEN_REWRITE_TAC (LAND_CONV o ONCE_DEPTH_CONV)[GEOM_MBASIS_SKEWSYM] THEN
ASM_SIMP_TAC[ARITH_RULE `p + q + 1<= i ==> ~(4 * i - 3 * p - q = i - q:num)`] THEN
REWRITE_TAC[GEOM_RNEG] THEN AP_TERM_TAC THEN REWRITE_TAC[GEOM_ASSOC] THEN
AP_THM_TAC THEN AP_TERM_TAC THEN
GEN_REWRITE_TAC (RAND_CONV o ONCE_DEPTH_CONV)[GEOM_MBASIS_SKEWSYM] THEN
ASM_SIMP_TAC[ARITH_RULE `p + q + 1<= i ==> ~(4 * i - 3 * p - q - 2 = i - q:num)`] THEN
REWRITE_TAC[GEOM_LNEG; GSYM GEOM_ASSOC] THEN ONCE_REWRITE_TAC[GSYM GEOM_RNEG] THEN
AP_TERM_TAC THEN GEN_REWRITE_TAC (LAND_CONV o ONCE_DEPTH_CONV)[GEOM_MBASIS_SKEWSYM] THEN
ASM_SIMP_TAC[ARITH_RULE `p + q + 1<= i ==> ~(4 * i - 3 * p - q - 1 = i - q:num)`]);;
(* ------------------------------------------------------------------------- *)
(* Some basic lemmas, mostly set theory. *)
(* ------------------------------------------------------------------------- *)
let FINITE_POWERSET_CART_SUBSET_LEMMA = prove
(`!P m n. FINITE {i,j | i IN {s | s SUBSET 1..m} /\ j IN {s | s SUBSET 1..n} /\ P i j}`,
REPEAT STRIP_TAC THEN MATCH_MP_TAC FINITE_SUBSET THEN
EXISTS_TAC `{i,j | i IN {s | s SUBSET 1..m} /\ j IN {s | s SUBSET 1..n}}` THEN
SIMP_TAC[SUBSET; FINITE_PRODUCT; FINITE_NUMSEG; FINITE_POWERSET] THEN
SIMP_TAC[FORALL_PAIR_THM; IN_ELIM_PAIR_THM]);;
let FINITE_CART_SUBSET_LEMMA1 = prove (*More convenient than FINITE_CART_SUBSET_LEMMA. *)
(`!P m n m' n'. FINITE {i,j | i IN m..n /\ j IN m'..n' /\ P i j}`,
REPEAT STRIP_TAC THEN MATCH_MP_TAC FINITE_SUBSET THEN
EXISTS_TAC `{i,j | i IN m..n /\ j IN m'..n'}` THEN
SIMP_TAC[SUBSET; FINITE_PRODUCT; FINITE_NUMSEG] THEN
SIMP_TAC[FORALL_PAIR_THM; IN_ELIM_PAIR_THM]);;
(* ------------------------------------------------------------------------- *)
(* Pseudo dimindex. *)
(* ------------------------------------------------------------------------- *)
let pdimindex = new_definition
`pdimindex(s:A->bool) = dimindex(s) - 1`;;
let PDIMINDEX_SUC_DIMINDEX = prove
(`dimindex(s:A->bool) = pdimindex(s) + 1`,
SIMP_TAC[pdimindex; DIMINDEX_GE_1; SUB_ADD]);;
let PDIMINDEX_LT_DIMINDEX = prove
(`pdimindex(s:A->bool) < dimindex(s)`,
REWRITE_TAC[PDIMINDEX_SUC_DIMINDEX; LT_ADD] THEN ARITH_TAC);;
let PDIMINDEX_LE_IMP_DIMINDEX_LE = prove
(`!x. x <= pdimindex s ==> x <= dimindex s`,
MESON_TAC[PDIMINDEX_LT_DIMINDEX; LET_TRANS; LT_IMP_LE]);;
let PDIMINDEX_UNIQUE = prove
(`(:A) HAS_SIZE n + 1 ==> pdimindex(:A) = n`,
MESON_TAC[dimindex; HAS_SIZE; pdimindex; ADD_SUB]);;
let define_pseudo_finite_type =
let lemma_pre = prove
(`?x. x IN 1..n+1`,
EXISTS_TAC `1` THEN REWRITE_TAC[IN_NUMSEG] THEN ARITH_TAC)
and lemma_post = prove
(`(!a:A. mk(dest a) = a) /\ (!r. r IN 1..n+1 <=> dest(mk r) = r)
==> (:A) HAS_SIZE n+1`,
REPEAT STRIP_TAC THEN
SUBGOAL_THEN `(:A) = IMAGE mk (1..n+1)` SUBST1_TAC THENL
[REWRITE_TAC[EXTENSION; IN_IMAGE; IN_UNIV];
MATCH_MP_TAC HAS_SIZE_IMAGE_INJ] THEN
ASM_MESON_TAC[HAS_SIZE_NUMSEG_1]) in
let POST_RULE = MATCH_MP lemma_post and n_tm = `n:num` in
fun n ->
let ns = "'"^string_of_int n in
let ns' = "auto_define_finite_type_"^ns in
let th = INST [mk_small_numeral n,n_tm] lemma_pre in
POST_RULE(new_type_definition ns ("mk_"^ns',"dest_"^ns') th);;
let HAS_PSEUDO_SIZE_0 = define_pseudo_finite_type 0;;
let HAS_PSEUDO_SIZE_1 = define_pseudo_finite_type 1;;
let HAS_PSEUDO_SIZE_2 = define_pseudo_finite_type 2;;
let HAS_PSEUDO_SIZE_3 = define_pseudo_finite_type 3;;
let HAS_PSEUDO_SIZE_4 = define_pseudo_finite_type 4;;
let PDIMINDEX_0 = MATCH_MP PDIMINDEX_UNIQUE HAS_PSEUDO_SIZE_0;;
let PDIMINDEX_1 = MATCH_MP PDIMINDEX_UNIQUE HAS_PSEUDO_SIZE_1;;
let PDIMINDEX_2 = MATCH_MP PDIMINDEX_UNIQUE HAS_PSEUDO_SIZE_2;;
let PDIMINDEX_3 = MATCH_MP PDIMINDEX_UNIQUE HAS_PSEUDO_SIZE_3;;
let PDIMINDEX_4 = MATCH_MP PDIMINDEX_UNIQUE HAS_PSEUDO_SIZE_4;;
(* ------------------------------------------------------------------------- *)
(* Index type for "trip_fin_sum", denote the vector of (P,Q,R). *)
(* ------------------------------------------------------------------------- *)
let trip_fin_sum_tybij =
let th = prove
(`?x. x IN 1..(if 1 <= pdimindex(:P) + pdimindex(:Q) + pdimindex(:R)
then pdimindex(:P) + pdimindex(:Q) + pdimindex(:R) else 1)`,
EXISTS_TAC `1` THEN REWRITE_TAC[IN_NUMSEG] THEN ARITH_TAC) in
new_type_definition "trip_fin_sum" ("mk_trip_fin_sum","dest_trip_fin_sum") th;;
let TRIPLE_FINITE_SUM_IMAGE = prove
(`UNIV:(P,Q,R)trip_fin_sum->bool =
IMAGE mk_trip_fin_sum
(1..(if 1 <= pdimindex(:P) + pdimindex(:Q) + pdimindex(:R)
then pdimindex(:P) + pdimindex(:Q) + pdimindex(:R) else 1))`,
REWRITE_TAC[EXTENSION; IN_UNIV; IN_IMAGE] THEN
MESON_TAC[trip_fin_sum_tybij]);;
let DIMINDEX_HAS_SIZE_TRIPLE_FINITE_SUM = prove
(`(UNIV:(P,Q,R)trip_fin_sum->bool) HAS_SIZE
(if 1 <= pdimindex(:P) + pdimindex(:Q) + pdimindex(:R)
then pdimindex(:P) + pdimindex(:Q) + pdimindex(:R) else 1)`,
SIMP_TAC[TRIPLE_FINITE_SUM_IMAGE] THEN
MATCH_MP_TAC HAS_SIZE_IMAGE_INJ THEN
REWRITE_TAC[HAS_SIZE_NUMSEG_1] THEN
MESON_TAC[trip_fin_sum_tybij]);;
let DIMINDEX_TRIPLE_FINITE_SUM = prove
(`dimindex(:(P,Q,R)trip_fin_sum) =
if 1 <= pdimindex(:P) + pdimindex(:Q) + pdimindex(:R)
then pdimindex(:P) + pdimindex(:Q) + pdimindex(:R) else 1`,
GEN_REWRITE_TAC LAND_CONV [dimindex] THEN
REWRITE_TAC[REWRITE_RULE[HAS_SIZE] DIMINDEX_HAS_SIZE_TRIPLE_FINITE_SUM] THEN ARITH_TAC);;
(* ------------------------------------------------------------------------- *)
(* Index type for "multivectors" of (P,Q,R).(k-vectors for all k <= P+Q+R). *)
(* ------------------------------------------------------------------------- *)
let geomalg_tybij_th = prove
(`?s. s SUBSET (1..(pdimindex(:P) + pdimindex(:Q) + pdimindex(:R)))`,
MESON_TAC[EMPTY_SUBSET]);;
let geomalg_tybij =
new_type_definition "geomalg" ("mk_geomalg","dest_geomalg")
geomalg_tybij_th;;
let GEOMALG_IMAGE = prove
(`(:(P,Q,R)geomalg) = IMAGE mk_geomalg {s | s SUBSET 1..pdimindex(:P) + pdimindex(:Q) + pdimindex(:R)}`,
REWRITE_TAC[EXTENSION; IN_UNIV; IN_IMAGE; IN_ELIM_THM] THEN
MESON_TAC[geomalg_tybij]);;
let HAS_SIZE_GEOMALG = prove
(`(:(P,Q,R)geomalg) HAS_SIZE (2 EXP (pdimindex(:P) + pdimindex(:Q) + pdimindex(:R)))`,
REWRITE_TAC[GEOMALG_IMAGE] THEN MATCH_MP_TAC HAS_SIZE_IMAGE_INJ THEN
SIMP_TAC[HAS_SIZE_POWERSET; HAS_SIZE_NUMSEG_1; IN_ELIM_THM] THEN
MESON_TAC[geomalg_tybij]);;
let FINITE_GEOMALG = prove
(`FINITE(:(P,Q,R)geomalg)`,
MESON_TAC[HAS_SIZE; HAS_SIZE_GEOMALG]);;
let DIMINDEX_GEOMALG = prove
(`dimindex(:(P,Q,R)geomalg) = 2 EXP (pdimindex(:P) + pdimindex(:Q) + pdimindex(:R))`,
MESON_TAC[DIMINDEX_UNIQUE; HAS_SIZE_GEOMALG]);;
let DEST_MK_GEOMALG = prove
(`!s. s SUBSET 1..pdimindex(:P) + pdimindex(:Q) + pdimindex(:R)
==> dest_geomalg(mk_geomalg s:(P,Q,R)geomalg) = s`,
REPEAT STRIP_TAC THEN GEN_REWRITE_TAC I [GSYM geomalg_tybij] THEN
ASM_REWRITE_TAC[]);;
let FORALL_GEOMALG = prove
(`(!s. s SUBSET 1..(pdimindex(:P) + pdimindex(:Q) + pdimindex(:R)) ==> P(mk_geomalg s)) <=>
(!m:(P,Q,R)geomalg. P m)`,
EQ_TAC THENL [ALL_TAC; SIMP_TAC[]] THEN DISCH_TAC THEN GEN_TAC THEN
MP_TAC(ISPEC `m:(P,Q,R)geomalg`
(REWRITE_RULE[EXTENSION] GEOMALG_IMAGE)) THEN
REWRITE_TAC[IN_UNIV; IN_IMAGE; EXISTS_PAIR_THM; IN_ELIM_THM] THEN
ASM_MESON_TAC[]);;
(* ------------------------------------------------------------------------- *)
(* Indexing directly via subsets. *)
(* ------------------------------------------------------------------------- *)
make_overloadable "$$" `:real^N->(num->bool)->real`;;
overload_interface("$$",`setindex:real^(P,Q,R)geomalg->(num->bool)->real`);;
let setindex = new_definition
`(x:real^(P,Q,R)geomalg) $$ s = x$(setcode s)`;;
make_overloadable "lambdas" `:((num->bool)->real)->real^N`;;
overload_interface("lambdas",`lambdaset:((num->bool)->real)->real^(P,Q,R)geomalg`);;
let lambdaset = new_definition
`(lambdaset) (g:(num->bool)->real) =
(lambda i. g(codeset i)):real^(P,Q,R)geomalg`;;
(* ------------------------------------------------------------------------- *)
(* Crucial properties. *)
(* ------------------------------------------------------------------------- *)
let GEOMALG_EQ = prove
(`!x y:real^(P,Q,R)geomalg.
x = y <=> !s. s SUBSET 1..(pdimindex(:P) + pdimindex(:Q) + pdimindex(:R)) ==> x$$s = y$$s`,
SIMP_TAC[CART_EQ; setindex; FORALL_SETCODE; GSYM IN_NUMSEG;
DIMINDEX_GEOMALG]);;
let GEOMALG_BETA = prove
(`!s. s SUBSET 1..(pdimindex(:P) + pdimindex(:Q) + pdimindex(:R))
==> ((lambdas) g :real^(P,Q,R)geomalg)$$s = g s`,
SIMP_TAC[setindex; lambdaset; LAMBDA_BETA; SETCODE_BOUNDS;
DIMINDEX_GEOMALG; GSYM IN_NUMSEG] THEN
MESON_TAC[CODESET_SETCODE_BIJECTIONS]);;
let GEOMALG_UNIQUE = prove
(`!m:real^(P,Q,R)geomalg g.
(!s. s SUBSET 1..(pdimindex(:P) + pdimindex(:Q) + pdimindex(:R)) ==> m$$s = g s)
==> (lambdas) g = m`,
SIMP_TAC[GEOMALG_EQ; GEOMALG_BETA] THEN MESON_TAC[]);;
let GEOMALG_ETA = prove(*lambdas s. m$$s =lambdas (\s. m$$s) *)
(`(lambdas s. m$$s) = m`,
SIMP_TAC[GEOMALG_EQ; GEOMALG_BETA]);;
(* ------------------------------------------------------------------------- *)
(* Also componentwise operations; they all work in this style. *)
(* ------------------------------------------------------------------------- *)
let GEOMALG_ADD_COMPONENT = prove
(`!x y:real^(P,Q,R)geomalg s.
s SUBSET 1..pdimindex(:P) + pdimindex(:Q) + pdimindex(:R) ==> (x + y)$$s = x$$s + y$$s`,
SIMP_TAC[setindex; SETCODE_BOUNDS; DIMINDEX_GEOMALG;
GSYM IN_NUMSEG; VECTOR_ADD_COMPONENT]);;
let GEOMALG_MUL_COMPONENT = prove
(`!c x:real^(P,Q,R)geomalg s.
s SUBSET 1..pdimindex(:P) + pdimindex(:Q) + pdimindex(:R) ==> (c % x)$$s = c * x$$s`,
SIMP_TAC[setindex; SETCODE_BOUNDS; DIMINDEX_GEOMALG;
GSYM IN_NUMSEG; VECTOR_MUL_COMPONENT]);;
let GEOMALG_VEC_COMPONENT = prove
(`!k s. s SUBSET 1..pdimindex(:P) + pdimindex(:Q) + pdimindex(:R) ==> (vec k :real^(P,Q,R)geomalg)$$s = &k`,
SIMP_TAC[setindex; SETCODE_BOUNDS; DIMINDEX_GEOMALG;
GSYM IN_NUMSEG; VEC_COMPONENT]);;
let GEOMALG_VSUM_COMPONENT = prove
(`!f:A->real^(P,Q,R)geomalg t s.
s SUBSET 1..pdimindex(:P) + pdimindex(:Q) + pdimindex(:R)
==> (vsum t f)$$s = sum t (\x. (f x)$$s)`,
SIMP_TAC[vsum; setindex; LAMBDA_BETA; SETCODE_BOUNDS; GSYM IN_NUMSEG;
DIMINDEX_GEOMALG]);;
let GEOMALG_VSUM = prove
(`!t f. vsum t f = lambdas s. sum t (\x. (f x)$$s)`,
SIMP_TAC[GEOMALG_EQ; GEOMALG_BETA; GEOMALG_VSUM_COMPONENT]);;
(* ------------------------------------------------------------------------- *)
(* Basis vectors indexed by subsets of 1..p+q+r. *)
(* ------------------------------------------------------------------------- *)
make_overloadable "mbasis" `:(num->bool)->real^N`;;
overload_interface("mbasis",`mvbasis:(num->bool)->real^(P,Q,R)geomalg`);;
let mvbasis = new_definition
`mvbasis i = lambdas s. if i = s then &1 else &0`;;
let MVBASIS_COMPONENT = prove
(`!s t. s SUBSET 1..pdimindex(:P) + pdimindex(:Q) + pdimindex(:R)
==> (mbasis t :real^(P,Q,R)geomalg)$$s = if s = t then &1 else &0`,
SIMP_TAC[mvbasis; IN_ELIM_THM; GEOMALG_BETA] THEN MESON_TAC[]);;
let MVBASIS_EQ_0 = prove
(`!s. (mbasis s :real^(P,Q,R)geomalg = vec 0) <=>
~(s SUBSET 1..pdimindex(:P) + pdimindex(:Q) + pdimindex(:R))`,
SIMP_TAC[GEOMALG_EQ; MVBASIS_COMPONENT; GEOMALG_VEC_COMPONENT] THEN
MESON_TAC[REAL_ARITH `~(&1 = &0)`]);;
let MVBASIS_NONZERO = prove
(`!s. s SUBSET 1..pdimindex(:P) + pdimindex(:Q) + pdimindex(:R) ==> ~(mbasis s :real^(P,Q,R)geomalg = vec 0)`,
REWRITE_TAC[MVBASIS_EQ_0]);;
let MVBASIS_EXPANSION = prove
(`!x:real^(P,Q,R)geomalg.
vsum {s | s SUBSET 1..pdimindex(:P) + pdimindex(:Q) + pdimindex(:R)} (\s. x$$s % mbasis s) = x`,
SIMP_TAC[GEOMALG_EQ; GEOMALG_VSUM_COMPONENT;
GEOMALG_MUL_COMPONENT; MVBASIS_COMPONENT] THEN
REPEAT STRIP_TAC THEN
GEN_REWRITE_TAC (LAND_CONV o ONCE_DEPTH_CONV) [EQ_SYM_EQ] THEN
ASM_SIMP_TAC[REAL_ARITH `x * (if p then &1 else &0) = if p then x else &0`;
SUM_DELTA; IN_ELIM_THM]);;
let SPAN_MVBASIS = prove
(`span {mbasis s :real^(P,Q,R)geomalg | s SUBSET 1..pdimindex(:P) + pdimindex(:Q) + pdimindex(:R)} = UNIV`,
REWRITE_TAC[EXTENSION; IN_UNIV] THEN X_GEN_TAC `x:real^(P,Q,R)geomalg` THEN
GEN_REWRITE_TAC LAND_CONV [GSYM MVBASIS_EXPANSION] THEN
MATCH_MP_TAC SPAN_VSUM THEN
SIMP_TAC[FINITE_NUMSEG; FINITE_POWERSET; IN_ELIM_THM] THEN
REPEAT STRIP_TAC THEN MATCH_MP_TAC SPAN_MUL THEN
MATCH_MP_TAC SPAN_SUPERSET THEN REWRITE_TAC[IN_ELIM_THM] THEN
ASM_MESON_TAC[]);;
let MVBASIS_BASIS = prove
(`s SUBSET 1..pdimindex (:P) + pdimindex (:Q) + pdimindex (:R)
==> (mbasis s):real^(P,Q,R)geomalg = basis (setcode s)`,
SIMP_TAC[mvbasis; basis; lambdaset; CART_EQ; LAMBDA_BETA] THEN
REWRITE_TAC[GSYM IN_NUMSEG; DIMINDEX_GEOMALG; GSYM FORALL_SETCODE] THEN
ASM_MESON_TAC[CODESET_SETCODE_BIJECTIONS]);;
let MVBASIS_INJ = prove
(`!s t. s SUBSET 1..pdimindex(:P) + pdimindex(:Q) + pdimindex(:R) /\
t SUBSET 1..pdimindex(:P) + pdimindex(:Q) + pdimindex(:R) /\
(mbasis s :real^(P,Q,R)geomalg = mbasis t)
==> (s = t)`,
SIMP_TAC[mvbasis; GEOMALG_EQ; GEOMALG_BETA] THEN
REPEAT STRIP_TAC THEN FIRST_X_ASSUM(MP_TAC o SPEC `s:num->bool`) THEN
ONCE_REWRITE_TAC[GSYM CONTRAPOS_THM] THEN
ASM_SIMP_TAC[REAL_OF_NUM_EQ; ARITH_EQ]);;
let MVBASIS_INJ_SING = prove
(`!i j. i IN 1..pdimindex(:P) + pdimindex(:Q) + pdimindex(:R) /\
j IN 1..pdimindex(:P) + pdimindex(:Q) + pdimindex(:R) /\
(mbasis {i}:real^(P,Q,R)geomalg) = mbasis {j}
==> i = j`,
SIMP_TAC[mvbasis; GEOMALG_EQ; GEOMALG_BETA] THEN
REPEAT STRIP_TAC THEN FIRST_X_ASSUM(MP_TAC o SPEC `{i}:num->bool`) THEN
ONCE_REWRITE_TAC[GSYM CONTRAPOS_THM] THEN
REWRITE_TAC[SUBSET; EXTENSION; IN_SING] THEN
ASM_MESON_TAC[REAL_OF_NUM_EQ; ARITH_EQ]);;
(* ------------------------------------------------------------------------- *)
(* Dot of Multivector. *)
(* ------------------------------------------------------------------------- *)
let DOT_MVBASIS = prove
(`!x:real^(P,Q,R)geomalg s.
s SUBSET 1..pdimindex(:P) + pdimindex(:Q) + pdimindex(:R)
==> ((mbasis s) dot x = x$$s) /\ (x dot (mbasis s) = x$$s)`,
REPEAT GEN_TAC THEN SIMP_TAC[MVBASIS_BASIS] THEN REWRITE_TAC[setindex] THEN
ASM_SIMP_TAC[SETCODE_BOUNDS; DIMINDEX_GEOMALG; GSYM IN_NUMSEG; DOT_BASIS]);;
let DOT_MVBASIS_MVBASIS = prove
(`!s t. s SUBSET 1..pdimindex(:P) + pdimindex(:Q) + pdimindex(:R) /\
t SUBSET 1..pdimindex(:P) + pdimindex(:Q) + pdimindex(:R)
==> (mbasis s:real^(P,Q,R)geomalg) dot (mbasis t) = if s = t then &1 else &0`,
SIMP_TAC[DOT_MVBASIS; MVBASIS_COMPONENT]);;
let DOT_MVBASIS_MVBASIS_UNEQUAL = prove
(`!s t. ~(s = t) ==> (mbasis s) dot (mbasis t) = &0`,
SIMP_TAC[mvbasis; dot; lambdaset; LAMBDA_BETA] THEN
ONCE_REWRITE_TAC[COND_RAND] THEN REPEAT STRIP_TAC THEN
MATCH_MP_TAC SUM_EQ_0 THEN REWRITE_TAC[] THEN
REPEAT STRIP_TAC THEN ASM_MESON_TAC[SUM_0; REAL_MUL_RZERO; REAL_MUL_LZERO; COND_ID]);;
let IN_SPAN_IMAGE_MVBASIS = prove
(`!x:real^(P,Q,R)geomalg s.
x IN span(IMAGE mbasis s) <=>
!t. t SUBSET 1..pdimindex(:P) + pdimindex(:Q) + pdimindex(:R) /\ ~(t IN s) ==> x$$t = &0`,
REPEAT GEN_TAC THEN EQ_TAC THENL
[SPEC_TAC(`x:real^(P,Q,R)geomalg`,`x:real^(P,Q,R)geomalg`) THEN MATCH_MP_TAC SPAN_INDUCT THEN
SIMP_TAC[subspace; IN_ELIM_THM; GEOMALG_VEC_COMPONENT; GEOMALG_ADD_COMPONENT;
GEOMALG_MUL_COMPONENT; REAL_MUL_RZERO; REAL_ADD_RID] THEN
SIMP_TAC[FORALL_IN_IMAGE; MVBASIS_COMPONENT] THEN MESON_TAC[]; ALL_TAC] THEN
DISCH_TAC THEN REWRITE_TAC[SPAN_EXPLICIT; IN_ELIM_THM] THEN
EXISTS_TAC `(IMAGE mbasis ({t|t SUBSET 1..pdimindex(:P) + pdimindex(:Q) + pdimindex(:R)} INTER s)):real^(P,Q,R)geomalg->bool` THEN
SIMP_TAC[FINITE_IMAGE; FINITE_INTER; FINITE_NUMSEG; FINITE_POWERSET] THEN
REWRITE_TAC[RIGHT_EXISTS_AND_THM] THEN
CONJ_TAC THENL [SET_TAC[]; ALL_TAC] THEN
EXISTS_TAC `\v:real^(P,Q,R)geomalg. x dot v` THEN
W(MP_TAC o PART_MATCH (lhs o rand) VSUM_IMAGE o lhand o snd) THEN
ANTS_TAC THENL
[SIMP_TAC[FINITE_IMAGE; FINITE_INTER; FINITE_NUMSEG; FINITE_POWERSET] THEN
REWRITE_TAC[IN_INTER; IN_ELIM_THM] THEN MESON_TAC[MVBASIS_INJ]; ALL_TAC] THEN
DISCH_THEN SUBST1_TAC THEN REWRITE_TAC[o_DEF] THEN
SIMP_TAC[GEOMALG_EQ; GEOMALG_VSUM_COMPONENT; GEOMALG_MUL_COMPONENT; MVBASIS_COMPONENT] THEN
ONCE_REWRITE_TAC[COND_RAND] THEN
ONCE_REWRITE_TAC[MESON[]
`(if x = y then p else q) = (if y = x then p else q)`] THEN
SIMP_TAC[SUM_DELTA; REAL_MUL_RZERO; IN_INTER; IN_ELIM_THM; DOT_MVBASIS] THEN
ASM_MESON_TAC[REAL_MUL_RID]);;
let INDEPENDENT_STDMVBASIS = prove
(`independent {mbasis s :real^(P,Q,R)geomalg | s SUBSET 1..pdimindex(:P) + pdimindex(:Q) + pdimindex(:R)}`,
SUBGOAL_THEN
`{mbasis s:real^(P,Q,R)geomalg | s SUBSET 1..pdimindex(:P) + pdimindex(:Q) + pdimindex(:R)} =
{basis i| 1 <= i /\ i <= dimindex (:(P,Q,R)geomalg)}`
SUBST1_TAC THENL
[REWRITE_TAC[EXTENSION; IN_ELIM_THM; GSYM IN_NUMSEG; DIMINDEX_GEOMALG] THEN
MESON_TAC[CODESET_SETCODE_BIJECTIONS; MVBASIS_BASIS]; ALL_TAC] THEN
MATCH_ACCEPT_TAC INDEPENDENT_STDBASIS);;
let INDEPENDENT_STDMVBASIS_SING = prove
(`independent {mbasis {i} :real^(P,Q,R)geomalg | 1 <= i /\ i <= pdimindex(:P) + pdimindex(:Q) + pdimindex(:R)}`,
MATCH_MP_TAC INDEPENDENT_MONO THEN
EXISTS_TAC `{mbasis s :real^(P,Q,R)geomalg | s SUBSET 1..pdimindex(:P) + pdimindex(:Q) + pdimindex(:R)}` THEN
REWRITE_TAC[INDEPENDENT_STDMVBASIS] THEN
ONCE_REWRITE_TAC[SET_RULE `{f x | P x} = IMAGE f {x | P x}`] THEN
REWRITE_TAC[SUBSET; IN_IMAGE; IN_ELIM_THM] THEN
X_GEN_TAC `t:real^(P,Q,R)geomalg` THEN
DISCH_THEN(X_CHOOSE_THEN `i:num` ASSUME_TAC) THEN
EXISTS_TAC `{i}:num->bool` THEN ASM_MESON_TAC[IN_SING; IN_NUMSEG]);;
(* ------------------------------------------------------------------------- *)
(* About norm. *)
(* ------------------------------------------------------------------------- *)
let NORM_MVBASIS = prove
(`!s. s SUBSET 1..pdimindex (:P) + pdimindex (:Q) + pdimindex (:R)
==> (norm(mbasis s :real^(P,Q,R)geomalg) = &1)`,
REPEAT STRIP_TAC THEN
SUBGOAL_THEN
`(mbasis s):real^(P,Q,R)geomalg =
(basis (setcode s)):real^(P,Q,R)geomalg` SUBST1_TAC THENL
[REWRITE_TAC[mvbasis; lambdaset] THEN
SIMP_TAC[CART_EQ; LAMBDA_BETA; BASIS_COMPONENT] THEN
SIMP_TAC[GSYM FORALL_SETCODE; DIMINDEX_GEOMALG; GSYM IN_NUMSEG] THEN
ASM_MESON_TAC[CODESET_SETCODE_BIJECTIONS]; ALL_TAC] THEN
ASM_SIMP_TAC[SETCODE_BOUNDS; DIMINDEX_GEOMALG; GSYM IN_NUMSEG; NORM_BASIS]);;
(* ------------------------------------------------------------------------- *)
(* Linear and bilinear functions are determined by their effect on basis. *)
(* ------------------------------------------------------------------------- *)
let LINEAR_EQ_MVBASIS = prove
(`!f:real^(P,Q,R)geomalg->real^N g b s.
linear f /\ linear g /\
(!s. s SUBSET 1..pdimindex(:P) + pdimindex(:Q) + pdimindex(:R) ==> f(mbasis s) = g(mbasis s))
==> f = g`,
REPEAT STRIP_TAC THEN
SUBGOAL_THEN `!x. x IN UNIV ==> (f:real^(P,Q,R)geomalg->real^N) x = g x`
(fun th -> MP_TAC th THEN REWRITE_TAC[FUN_EQ_THM; IN_UNIV]) THEN
MATCH_MP_TAC LINEAR_EQ THEN
EXISTS_TAC `{mbasis s :real^(P,Q,R)geomalg | s SUBSET 1..pdimindex(:P) + pdimindex(:Q) + pdimindex(:R)}` THEN
ASM_REWRITE_TAC[SPAN_MVBASIS; SUBSET_REFL; IN_ELIM_THM] THEN
ASM_MESON_TAC[]);;
let BILINEAR_EQ_MVBASIS = prove
(`!f:real^(P,Q,R)geomalg->real^(P',Q',R')geomalg->real^N g b s.
bilinear f /\ bilinear g /\
(!s t. s SUBSET 1..pdimindex(:P) + pdimindex(:Q) + pdimindex(:R) /\
t SUBSET 1..pdimindex(:P') + pdimindex(:Q') + pdimindex(:R')
==> f (mbasis s) (mbasis t) = g (mbasis s) (mbasis t))
==> f = g`,
REPEAT STRIP_TAC THEN SUBGOAL_THEN
`!x y. x IN UNIV /\ y IN UNIV
==> (f:real^(P,Q,R)geomalg->real^(P',Q',R')geomalg->real^N) x y = g x y`
(fun th -> MP_TAC th THEN REWRITE_TAC[FUN_EQ_THM; IN_UNIV]) THEN
MATCH_MP_TAC BILINEAR_EQ THEN
EXISTS_TAC `{mbasis s :real^(P,Q,R)geomalg | s SUBSET 1..pdimindex(:P) + pdimindex(:Q) + pdimindex(:R)}` THEN
EXISTS_TAC `{mbasis t :real^(P',Q',R')geomalg | t SUBSET 1..pdimindex(:P') + pdimindex(:Q') + pdimindex(:R')}` THEN
ASM_REWRITE_TAC[SPAN_MVBASIS; SUBSET_REFL; IN_ELIM_THM] THEN
ASM_MESON_TAC[]);;
(* ------------------------------------------------------------------------- *)
(* A way of proving linear properties by extension from basis. *)
(* ------------------------------------------------------------------------- *)
let MVBASIS_EXTENSION = prove
(`!P. (!s. s SUBSET 1..pdimindex(:P) + pdimindex(:Q) + pdimindex(:R) ==> P(mbasis s)) /\
(!c x. P x ==> P(c % x)) /\ (!x y. P x /\ P y ==> P(x + y))
==> !x:real^(P,Q,R)geomalg. P x`,
REPEAT STRIP_TAC THEN GEN_REWRITE_TAC RAND_CONV [GSYM MVBASIS_EXPANSION] THEN
MATCH_MP_TAC(SIMP_RULE[RIGHT_IMP_FORALL_THM; IMP_IMP] LINEAR_PROPERTY) THEN
ASM_SIMP_TAC[FINITE_POWERSET; FINITE_NUMSEG; IN_ELIM_THM] THEN
ASM_MESON_TAC[EMPTY_SUBSET; VECTOR_MUL_LZERO]);;
(* ------------------------------------------------------------------------- *)
(* Injection from regular vectors. *)
(* ------------------------------------------------------------------------- *)
make_overloadable "multivec" `:real^M->real^N`;;
overload_interface("multivec",`multivect:real^(P, Q, R)trip_fin_sum->real^(P,Q,R)geomalg`);;
let multivect = new_definition
`(multivect:real^(P,Q,R)trip_fin_sum->real^(P,Q,R)geomalg) x =
vsum(1..pdimindex(:P) + pdimindex(:Q) + pdimindex(:R)) (\i. x$i % mbasis{i})`;;
let LINEAR_MULTIVECT = prove
(`linear (multivec:real^(P,Q,R)trip_fin_sum->real^(P,Q,R)geomalg)`,
REWRITE_TAC[linear; multivect; VECTOR_ADD_COMPONENT; VECTOR_MUL_COMPONENT;
VECTOR_ADD_RDISTRIB; GSYM VECTOR_MUL_ASSOC] THEN
SIMP_TAC[FINITE_NUMSEG; VSUM_ADD; VSUM_LMUL]);;
let MULTIVECT_ADD = CONJUNCT1 (REWRITE_RULE[LINEAR_MULTIVECT]
(ISPEC `multivec:real^(P,Q,R)trip_fin_sum->real^(P,Q,R)geomalg` linear));;
let MULTIVECT_MUL = CONJUNCT2 (REWRITE_RULE[LINEAR_MULTIVECT]
(ISPEC `multivec:real^(P,Q,R)trip_fin_sum->real^(P,Q,R)geomalg` linear));;
let MULTIVECT_0 = REWRITE_RULE[VECTOR_MUL_LZERO](SPEC `&0:real` MULTIVECT_MUL);;
let MULTIVECT_BASIS = prove
(`!i. multivec (basis i:real^(P,Q,R)trip_fin_sum) = mbasis {i}`,
GEN_TAC THEN REWRITE_TAC[multivect] THEN
SUBGOAL_THEN
`mbasis {i}:real^(P,Q,R)geomalg =
vsum (1..pdimindex(:P) + pdimindex(:Q) + pdimindex(:R)) (\i'. if i' = i then mbasis {i} else vec 0)`
SUBST1_TAC THENL
[REWRITE_TAC[VSUM_DELTA] THEN COND_CASES_TAC THEN REWRITE_TAC[MVBASIS_EQ_0] THEN ASM SET_TAC[]; ALL_TAC] THEN
MATCH_MP_TAC VSUM_EQ THEN REWRITE_TAC[IN_NUMSEG] THEN REPEAT STRIP_TAC THEN
ASM_CASES_TAC `1 <= pdimindex (:P) + pdimindex (:Q) + pdimindex (:R)` THENL[ALL_TAC; ASM_ARITH_TAC] THEN
ASM_SIMP_TAC[DIMINDEX_TRIPLE_FINITE_SUM; BASIS_COMPONENT] THEN
COND_CASES_TAC THEN ASM_REWRITE_TAC[VECTOR_MUL_LID; VECTOR_MUL_LZERO]);;
let MULTIVECT_EQ_0 = prove
(`!x:real^(P, Q, R)trip_fin_sum.
1 <= pdimindex (:P) + pdimindex (:Q) + pdimindex (:R) ==> (x = vec 0 <=> multivec x = vec 0)`,
REPEAT STRIP_TAC THEN EQ_TAC THENL [DISCH_TAC THEN ASM_REWRITE_TAC[MULTIVECT_0]; ALL_TAC] THEN
REWRITE_TAC[multivect] THEN
MP_TAC(ISPEC `{mbasis {i} :real^(P,Q,R)geomalg | 1 <= i /\ i <= pdimindex(:P) + pdimindex(:Q) + pdimindex(:R)}` INDEPENDENT_EXPLICIT) THEN
REWRITE_TAC[INDEPENDENT_STDMVBASIS_SING; GSYM IN_NUMSEG; SIMPLE_IMAGE] THEN SIMP_TAC[FINITE_NUMSEG; FINITE_IMAGE] THEN
ASSUME_TAC MVBASIS_INJ_SING THEN FIRST_ASSUM(MP_TAC o GEN_REWRITE_RULE I [INJECTIVE_ON_LEFT_INVERSE]) THEN
DISCH_THEN(X_CHOOSE_TAC `g:real^(P,Q,R)geomalg->num`) THEN
ONCE_REWRITE_TAC[GSYM CONTRAPOS_THM] THEN REWRITE_TAC[NOT_FORALL_THM] THEN REWRITE_TAC[TAUT `~(a==>b) <=> a /\ ~b`] THEN
STRIP_TAC THEN EXISTS_TAC `\v. (x:real^(P, Q, R)trip_fin_sum)$((g:real^(P,Q,R)geomalg->num) v)` THEN
CONJ_TAC THENL
[W(MP_TAC o PART_MATCH (lhs o rand) VSUM_IMAGE o lhand o snd) THEN REWRITE_TAC[FINITE_NUMSEG; MVBASIS_INJ_SING; o_DEF] THEN
DISCH_THEN SUBST1_TAC THEN FIRST_ASSUM(SUBST1_TAC o SYM) THEN MATCH_MP_TAC VSUM_EQ THEN ASM_MESON_TAC[]; ALL_TAC] THEN
POP_ASSUM MP_TAC THEN SIMP_TAC[CART_EQ; VEC_COMPONENT; DIMINDEX_TRIPLE_FINITE_SUM] THEN
ASM_REWRITE_TAC[GSYM IN_NUMSEG] THEN ASM_MESON_TAC[IN_IMAGE]);;
let MULTIVECT_EQ = prove
(`!x y:real^(P, Q, R)trip_fin_sum.
1 <= pdimindex (:P) + pdimindex (:Q) + pdimindex (:R) ==>
(x = y <=> multivec x = multivec y)`,
REPEAT STRIP_TAC THEN ONCE_REWRITE_TAC[GSYM VECTOR_SUB_EQ; GSYM REAL_SUB_0] THEN
SIMP_TAC[LINEAR_MULTIVECT; GSYM LINEAR_SUB; GSYM VECTOR_SUB_COMPONENT] THEN
ASM_SIMP_TAC[MULTIVECT_EQ_0]);;
(* ------------------------------------------------------------------------- *)
(* Subspace of k-vectors. *)
(* ------------------------------------------------------------------------- *)
make_overloadable "multivector" `:num->real^N->bool`;;
overload_interface("multivector",`multivectorga:num->real^(P,Q,R)geomalg->bool`);;
let multivectorga = new_definition
`k multivector (p:real^(P,Q,R)geomalg) <=>
!s. s SUBSET (1..pdimindex(:P) + pdimindex(:Q) + pdimindex(:R)) /\ ~(p$$s = &0)
==> s HAS_SIZE k`;;
let FORALL_MULTIVECTORGA_VEC0 = prove
(`!k. k multivector (vec 0:real^(P,Q,R)geomalg)`,
MESON_TAC[multivectorga; GEOMALG_VEC_COMPONENT]);;
(* ------------------------------------------------------------------------- *)
(* k-grade part of a multivector. *)
(* ------------------------------------------------------------------------- *)
make_overloadable "grade" `:num->real^N->real^N`;;
overload_interface("grade",`grade_geomalg:num->real^(P,Q,R)geomalg->real^(P,Q,R)geomalg`);;
let grade_geomalg = new_definition
`k grade (p:real^(P,Q,R)geomalg) =
(lambdas s. if s HAS_SIZE k then p$$s else &0):real^(P,Q,R)geomalg`;;
let GEOMALG_GRADE = prove
(`!k x. k multivector (k grade x)`,
SIMP_TAC[multivectorga; grade_geomalg; GEOMALG_BETA; IMP_CONJ] THEN
MESON_TAC[]);;
let GRADE_ADD_GEOMALG = prove
(`!x y k. k grade (x + y) = (k grade x) + (k grade y)`,
SIMP_TAC[grade_geomalg; GEOMALG_EQ; GEOMALG_ADD_COMPONENT;
GEOMALG_BETA; COND_COMPONENT] THEN
REAL_ARITH_TAC);;
let GRADE_CMUL_GEOMALG = prove
(`!c x k. k grade (c % x) = c % (k grade x)`,
SIMP_TAC[grade_geomalg; GEOMALG_EQ; GEOMALG_MUL_COMPONENT;
GEOMALG_BETA; COND_COMPONENT] THEN
REAL_ARITH_TAC);;
(* ------------------------------------------------------------------------- *)
(* General product construct. *)
(* ------------------------------------------------------------------------- *)
parse_as_infix("SYMDIFF",(18,"left"));;
let SYMDIFF = new_definition `s SYMDIFF t = (s DIFF t) UNION (t DIFF s)`;;
let SYMDIFF_EMPTY = prove
(`(!s. s SYMDIFF {} = s) /\ (!s. {} SYMDIFF s = s)`,
REWRITE_TAC[SYMDIFF; DIFF_EMPTY; EMPTY_DIFF; UNION_EMPTY]);;
let SYMDIFF_COMM = prove
(`(!s t. s SYMDIFF t = t SYMDIFF s)`,
REWRITE_TAC[SYMDIFF; UNION_COMM]);;
let SYMDIFF_SUBSET = prove
(`!s t u. s SUBSET u /\ t SUBSET u ==> (s SYMDIFF t) SUBSET u`,
REWRITE_TAC[SYMDIFF] THEN SET_TAC[]);;
let SYMDIFF_ASSOC = prove
(`!s t u. s SYMDIFF (t SYMDIFF u) = (s SYMDIFF t) SYMDIFF u`,
REWRITE_TAC[SYMDIFF] THEN SET_TAC[]);;
let Productga_DEF = new_definition
`(Productga sgn
:real^(P,Q,R)geomalg->real^(P,Q,R)geomalg->real^(P,Q,R)geomalg) x y =
vsum {s | s SUBSET 1..(pdimindex(:P) + pdimindex(:Q) + pdimindex(:R))}
(\s. vsum {s | s SUBSET 1..(pdimindex(:P) + pdimindex(:Q) + pdimindex(:R))}
(\t. (sgn s t * x$$s * y$$t) % mbasis (s SYMDIFF t)))`;;
(* ------------------------------------------------------------------------- *)
(* This is always bilinear. *)
(* ------------------------------------------------------------------------- *)
let BILINEAR_PRODUCTGA = prove
(`!sgn. bilinear(Productga sgn)`,
REWRITE_TAC[bilinear; linear; Productga_DEF] THEN
SIMP_TAC[GSYM VSUM_LMUL; GEOMALG_MUL_COMPONENT] THEN
REWRITE_TAC[VECTOR_MUL_ASSOC; REAL_MUL_AC] THEN
REPEAT STRIP_TAC THEN
SIMP_TAC[GSYM VSUM_ADD; FINITE_POWERSET; FINITE_NUMSEG] THEN
REPEAT(MATCH_MP_TAC VSUM_EQ THEN REWRITE_TAC[IN_ELIM_THM] THEN
REPEAT STRIP_TAC) THEN
ASM_SIMP_TAC[GEOMALG_ADD_COMPONENT] THEN VECTOR_ARITH_TAC);;
let PRODUCTGA_LADD = (MATCH_MP BILINEAR_LADD o SPEC_ALL) BILINEAR_PRODUCTGA;;
let PRODUCTGA_RADD = (MATCH_MP BILINEAR_RADD o SPEC_ALL) BILINEAR_PRODUCTGA;;
let PRODUCTGA_LMUL = (MATCH_MP BILINEAR_LMUL o SPEC_ALL) BILINEAR_PRODUCTGA;;
let PRODUCTGA_RMUL = (MATCH_MP BILINEAR_RMUL o SPEC_ALL) BILINEAR_PRODUCTGA;;
let PRODUCTGA_LNEG = (MATCH_MP BILINEAR_LNEG o SPEC_ALL) BILINEAR_PRODUCTGA;;
let PRODUCTGA_RNEG = (MATCH_MP BILINEAR_RNEG o SPEC_ALL) BILINEAR_PRODUCTGA;;
let PRODUCTGA_LZERO = (MATCH_MP BILINEAR_LZERO o SPEC_ALL) BILINEAR_PRODUCTGA;;
let PRODUCTGA_RZERO = (MATCH_MP BILINEAR_RZERO o SPEC_ALL) BILINEAR_PRODUCTGA;;
(* ------------------------------------------------------------------------- *)
(* Under suitable conditions, it's also associative. *)
(* ------------------------------------------------------------------------- *)
let PRODUCTGA_ASSOCIATIVE = prove
(`!sgn1 sgn2.
(!s t u. sgn1 t u * sgn2 s (t SYMDIFF u) = sgn2 s t * sgn1 (s SYMDIFF t) u)
==> !x y z:real^(P,Q,R)geomalg.
Productga sgn2 x (Productga sgn1 y z) =
Productga sgn1 (Productga sgn2 x y) z`,
let SUM_SWAP_POWERSET =
SIMP_RULE[FINITE_POWERSET; FINITE_NUMSEG]
(repeat(SPEC `{s | s SUBSET 1..(pdimindex(:P) + pdimindex(:Q) + pdimindex(:R))}`)
(ISPEC `f:(num->bool)->(num->bool)->real` SUM_SWAP)) in
let SWAP_TAC cnv n =
GEN_REWRITE_TAC (cnv o funpow n BINDER_CONV) [SUM_SWAP_POWERSET] THEN
REWRITE_TAC[] in
let SWAPS_TAC cnv ns x =
MAP_EVERY (SWAP_TAC cnv) ns THEN MATCH_MP_TAC SUM_EQ THEN X_GEN_TAC x THEN
REWRITE_TAC[IN_ELIM_THM] THEN STRIP_TAC in
REWRITE_TAC[Productga_DEF] THEN REPEAT STRIP_TAC THEN
SIMP_TAC[GEOMALG_EQ; GEOMALG_VSUM_COMPONENT; MVBASIS_COMPONENT;
GEOMALG_MUL_COMPONENT] THEN
SIMP_TAC[GSYM SUM_LMUL; GSYM SUM_RMUL] THEN
X_GEN_TAC `r:num->bool` THEN STRIP_TAC THEN
SWAPS_TAC RAND_CONV [1;0] `s:num->bool` THEN
SWAP_TAC LAND_CONV 0 THEN SWAPS_TAC RAND_CONV [1;0] `t:num->bool` THEN
SWAP_TAC RAND_CONV 0 THEN SWAPS_TAC LAND_CONV [0] `u:num->bool` THEN
REWRITE_TAC[GSYM REAL_MUL_ASSOC;
REAL_ARITH `(if p then a else &0) * b = if p then a * b else &0`;
REAL_ARITH `a * (if p then b else &0) = if p then a * b else &0`] THEN
SIMP_TAC[SUM_DELTA] THEN ASM_SIMP_TAC[IN_ELIM_THM; SYMDIFF_SUBSET; SYMDIFF_ASSOC] THEN
COND_CASES_TAC THEN ASM_REWRITE_TAC[REAL_MUL_LID; REAL_MUL_RID] THEN
REWRITE_TAC[REAL_MUL_AC]THEN ASM_REWRITE_TAC[REAL_MUL_ASSOC] THEN REWRITE_TAC[REAL_MUL_AC]);;
(* --------------------------------------------------------------------------*)
(* Geometric product. *)
(* ------------------------------------------------------------------------- *)
overload_interface
("*",`geomga_mul:real^(P,Q,R)geomalg->real^(P,Q,R)geomalg->real^(P,Q,R)geomalg`);;
let geomga_mul = new_definition
`(x:real^(P,Q,R)geomalg) * y =
Productga (\s t.
--(&1) pow CARD {i,j | i IN 1..pdimindex(:P) + pdimindex(:Q) + pdimindex(:R) /\
j IN 1..pdimindex(:P) + pdimindex(:Q) + pdimindex(:R) /\
i IN s /\ j IN t /\ i > j} *
--(&1) pow CARD ((pdimindex(:P) + 1..pdimindex(:P) + pdimindex(:Q)) INTER s INTER t) *
&0 pow CARD ((pdimindex(:P) + pdimindex(:Q) + 1..pdimindex(:P) + pdimindex(:Q) + pdimindex(:R)) INTER s INTER t))
x y`;;
let BILINEAR_GEOMGA = prove
(`bilinear(geomga_mul)`,
REWRITE_TAC[REWRITE_RULE[GSYM FUN_EQ_THM; ETA_AX] geomga_mul] THEN
MATCH_ACCEPT_TAC BILINEAR_PRODUCTGA);;
let GEOMGA_LADD = (MATCH_MP BILINEAR_LADD o SPEC_ALL) BILINEAR_GEOMGA;;
let GEOMGA_RADD = (MATCH_MP BILINEAR_RADD o SPEC_ALL) BILINEAR_GEOMGA;;
let GEOMGA_LMUL = (MATCH_MP BILINEAR_LMUL o SPEC_ALL) BILINEAR_GEOMGA;;
let GEOMGA_RMUL = (MATCH_MP BILINEAR_RMUL o SPEC_ALL) BILINEAR_GEOMGA;;
let GEOMGA_LNEG = (MATCH_MP BILINEAR_LNEG o SPEC_ALL) BILINEAR_GEOMGA;;
let GEOMGA_RNEG = (MATCH_MP BILINEAR_RNEG o SPEC_ALL) BILINEAR_GEOMGA;;
let GEOMGA_LZERO = (MATCH_MP BILINEAR_LZERO o SPEC_ALL) BILINEAR_GEOMGA;;
let GEOMGA_RZERO = (MATCH_MP BILINEAR_RZERO o SPEC_ALL) BILINEAR_GEOMGA;;
let GEOMGA_ASSOC = prove
(`!x y z:real^(P,Q,R)geomalg. x * (y * z) = (x * y) * z`,
REWRITE_TAC[geomga_mul] THEN MATCH_MP_TAC PRODUCTGA_ASSOCIATIVE THEN
REPEAT GEN_TAC THEN SIMP_TAC[REAL_ARITH`(a:real * b*c) * (d*e*f) = (a*d)*(b*e)*(c*f)`] THEN
REWRITE_TAC[GSYM REAL_POW_ADD; SYMDIFF] THEN BINOP_TAC THENL[ALL_TAC; BINOP_TAC THENL[ALL_TAC;
REWRITE_TAC[REAL_POW_ZERO] THEN
AP_THM_TAC THEN AP_THM_TAC THEN AP_TERM_TAC THEN
SIMP_TAC[ADD_EQ_0; FINITE_NUMSEG; FINITE_INTER; CARD_EQ_0] THEN
SIMP_TAC[GSYM EMPTY_UNION] THEN
AP_THM_TAC THEN AP_TERM_TAC THEN SET_TAC[]]] THEN
REWRITE_TAC[REAL_POW_NEG; REAL_POW_ONE] THEN
AP_THM_TAC THEN AP_THM_TAC THEN AP_TERM_TAC THEN
REWRITE_TAC[EVEN_ADD] THEN
W(fun (_,w) -> let tu = funpow 2 lhand w in
let su = vsubst[`s:num->bool`,`t:num->bool`] tu in
let st = vsubst[`t:num->bool`,`u:num->bool`] su in
MATCH_MP_TAC EQ_TRANS THEN
EXISTS_TAC(end_itlist (curry mk_eq) [st; su; tu])) THEN
CONJ_TAC THENL
[MATCH_MP_TAC(TAUT `(x <=> y <=> z) ==> ((a <=> x) <=> (y <=> z <=> a))`);
AP_TERM_TAC THEN CONV_TAC SYM_CONV;
MATCH_MP_TAC(TAUT `(x <=> y <=> z) ==> ((a <=> x) <=> (y <=> z <=> a))`);
AP_TERM_TAC THEN CONV_TAC SYM_CONV] THEN
MATCH_MP_TAC SYMDIFF_PARITY_LEMMA THEN
SIMP_TAC[FINITE_CART_SUBSET_LEMMA1; FINITE_NUMSEG; FINITE_INTER] THEN
REWRITE_TAC[EXTENSION; FORALL_PAIR_THM; IN_ELIM_PAIR_THM; IN_ELIM_THM;
IN_UNION; IN_DIFF; IN_INTER] THEN
CONV_TAC TAUT);;
(* ------------------------------------------------------------------------- *)
(* Outer product. *)
(* ------------------------------------------------------------------------- *)
make_overloadable "outer" `:real^N->real^N->real^N`;;
overload_interface
("outer",`outerga:real^(P,Q,R)geomalg->real^(P,Q,R)geomalg->real^(P,Q,R)geomalg`);;
let outerga = new_definition
`x outer y:real^(P,Q,R)geomalg =
Productga (\s t. if ~(s INTER t = {}) then &0
else --(&1) pow CARD {i,j | i IN 1..(pdimindex(:P) + pdimindex(:Q) + pdimindex(:R)) /\
j IN 1..(pdimindex(:P) + pdimindex(:Q) + pdimindex(:R)) /\
i IN s /\ j IN t /\ i > j})
x y`;;
let BILINEAR_OUTERGA = prove
(`bilinear(outer)`,
REWRITE_TAC[REWRITE_RULE[GSYM FUN_EQ_THM; ETA_AX] outerga] THEN
MATCH_ACCEPT_TAC BILINEAR_PRODUCTGA);;
let OUTERGA_LADD = (MATCH_MP BILINEAR_LADD o SPEC_ALL) BILINEAR_OUTERGA;;
let OUTERGA_RADD = (MATCH_MP BILINEAR_RADD o SPEC_ALL) BILINEAR_OUTERGA;;
let OUTERGA_LMUL = (MATCH_MP BILINEAR_LMUL o SPEC_ALL) BILINEAR_OUTERGA;;
let OUTERGA_RMUL = (MATCH_MP BILINEAR_RMUL o SPEC_ALL) BILINEAR_OUTERGA;;
let OUTERGA_LNEG = (MATCH_MP BILINEAR_LNEG o SPEC_ALL) BILINEAR_OUTERGA;;
let OUTERGA_RNEG = (MATCH_MP BILINEAR_RNEG o SPEC_ALL) BILINEAR_OUTERGA;;
let OUTERGA_LZERO = (MATCH_MP BILINEAR_LZERO o SPEC_ALL) BILINEAR_OUTERGA;;
let OUTERGA_RZERO = (MATCH_MP BILINEAR_RZERO o SPEC_ALL) BILINEAR_OUTERGA;;
let OUTERGA_ASSOC = prove
(`!x y z:real^(P,Q,R)geomalg. x outer (y outer z) = (x outer y) outer z`,
REWRITE_TAC[outerga] THEN MATCH_MP_TAC PRODUCTGA_ASSOCIATIVE THEN
REPEAT GEN_TAC THEN
MAP_EVERY ASM_CASES_TAC
[`s INTER t :num->bool = {}`;
`s INTER u :num->bool = {}`;
`t INTER u :num->bool = {}`] THEN
ASM_SIMP_TAC[SYMDIFF;
SET_RULE `(s INTER t = {}) ==> (s DIFF t) UNION (t DIFF s) = s UNION t`;
SET_RULE `s INTER (t UNION u) = (s INTER t) UNION (s INTER u)`;
SET_RULE `(t UNION u) INTER s = (t INTER s) UNION (u INTER s)`] THEN
REWRITE_TAC[EMPTY_UNION] THEN
ASM_REWRITE_TAC[REAL_MUL_LZERO; REAL_MUL_RZERO] THEN
REWRITE_TAC[GSYM REAL_POW_ADD] THEN AP_TERM_TAC THEN
MATCH_MP_TAC CARD_UNION_LEMMA THEN REWRITE_TAC[FINITE_CART_SUBSET_LEMMA1] THEN
SIMP_TAC[EXTENSION; FORALL_PAIR_THM; NOT_IN_EMPTY; IN_UNION; IN_INTER] THEN
REWRITE_TAC[IN_ELIM_PAIR_THM] THEN ASM SET_TAC []);;
(* ------------------------------------------------------------------------- *)
(* Inner product. *)
(* ------------------------------------------------------------------------- *)
make_overloadable "inner" `:real^N->real^N->real^N`;;
overload_interface
("inner",`innerga:real^(P,Q,R)geomalg->real^(P,Q,R)geomalg->real^(P,Q,R)geomalg`);;
let innerga = new_definition
`x inner y:real^(P,Q,R)geomalg=
Productga (\s t. if s = {} \/ t = {} \/ ~(s SUBSET t) /\ ~(t SUBSET s)
then &0
else --(&1) pow CARD {i,j | i IN 1..(pdimindex(:P) + pdimindex(:Q) + pdimindex(:R)) /\
j IN 1..(pdimindex(:P) + pdimindex(:Q) + pdimindex(:R)) /\
i IN s /\ j IN t /\ i > j} *
--(&1) pow CARD ((pdimindex(:P) + 1..pdimindex(:P) + pdimindex(:Q)) INTER s INTER t) *
&0 pow CARD ((pdimindex(:P) + pdimindex(:Q) + 1..pdimindex(:P) + pdimindex(:Q) + pdimindex(:R)) INTER s INTER t))
x y`;;
parse_as_infix("lcinner",(20,"right"));;
let lcinner = new_definition
`!x y:real^(P,Q,R)geomalg.
x lcinner y =
Productga (\s t. if s = {} \/ t = {} \/ ~(s SUBSET t)
then &0
else --(&1) pow CARD {i,j | i IN 1..(pdimindex(:P) + pdimindex(:Q) + pdimindex(:R)) /\
j IN 1..(pdimindex(:P) + pdimindex(:Q) + pdimindex(:R)) /\
i IN s /\ j IN t /\ i > j}*
--(&1) pow CARD ((pdimindex(:P) + 1..pdimindex(:P) + pdimindex(:Q)) INTER s INTER t) *
&0 pow CARD ((pdimindex(:P) + pdimindex(:Q) + 1..pdimindex(:P) + pdimindex(:Q) + pdimindex(:R)) INTER s INTER t))
x y`;;
parse_as_infix("rcinner",(20,"right"));;
let rcinner = new_definition
`!x y:real^(P,Q,R)geomalg.
x rcinner y =
Productga (\s t. if s = {} \/ t = {} \/ ~(t SUBSET s)
then &0
else --(&1) pow CARD {i,j | i IN 1..(pdimindex(:P) + pdimindex(:Q) + pdimindex(:R)) /\
j IN 1..(pdimindex(:P) + pdimindex(:Q) + pdimindex(:R)) /\
i IN s /\ j IN t /\ i > j}*
--(&1) pow CARD ((pdimindex(:P) + 1..pdimindex(:P) + pdimindex(:Q)) INTER s INTER t) *
&0 pow CARD ((pdimindex(:P) + pdimindex(:Q) + 1..pdimindex(:P) + pdimindex(:Q) + pdimindex(:R)) INTER s INTER t))
x y`;;
parse_as_infix("scalarinner",(20,"right"));;
let scalarinner = new_definition
`!x y:real^(P,Q,R)geomalg.
x scalarinner y =
Productga (\s t. if s = {} \/ t = {} \/ ~(s = t)
then &0
else --(&1) pow CARD ((pdimindex(:P) + 1..pdimindex(:P) + pdimindex(:Q)) INTER s INTER t) *
&0 pow CARD ((pdimindex(:P) + pdimindex(:Q) + 1..pdimindex(:P) + pdimindex(:Q) + pdimindex(:R)) INTER s INTER t))
x y`;;
let BILINEAR_INNERGA = prove
(`bilinear(inner)`,
REWRITE_TAC[REWRITE_RULE[GSYM FUN_EQ_THM; ETA_AX] innerga] THEN
MATCH_ACCEPT_TAC BILINEAR_PRODUCTGA);;
let INNERGA_LADD = (MATCH_MP BILINEAR_LADD o SPEC_ALL) BILINEAR_INNERGA;;
let INNERGA_RADD = (MATCH_MP BILINEAR_RADD o SPEC_ALL) BILINEAR_INNERGA;;
let INNERGA_LMUL = (MATCH_MP BILINEAR_LMUL o SPEC_ALL) BILINEAR_INNERGA;;
let INNERGA_RMUL = (MATCH_MP BILINEAR_RMUL o SPEC_ALL) BILINEAR_INNERGA;;
let INNERGA_LNEG = (MATCH_MP BILINEAR_LNEG o SPEC_ALL) BILINEAR_INNERGA;;
let INNERGA_RNEG = (MATCH_MP BILINEAR_RNEG o SPEC_ALL) BILINEAR_INNERGA;;
let INNERGA_LZERO = (MATCH_MP BILINEAR_LZERO o SPEC_ALL) BILINEAR_INNERGA;;
let INNERGA_RZERO = (MATCH_MP BILINEAR_RZERO o SPEC_ALL) BILINEAR_INNERGA;;
let BILINEAR_LCINNER = prove
(`bilinear(lcinner)`,
REWRITE_TAC[REWRITE_RULE[GSYM FUN_EQ_THM; ETA_AX] lcinner] THEN
MATCH_ACCEPT_TAC BILINEAR_PRODUCTGA);;
let LCINNER_LADD = (MATCH_MP BILINEAR_LADD o SPEC_ALL) BILINEAR_LCINNER;;
let LCINNER_RADD = (MATCH_MP BILINEAR_RADD o SPEC_ALL) BILINEAR_LCINNER;;
let LCINNER_LMUL = (MATCH_MP BILINEAR_LMUL o SPEC_ALL) BILINEAR_LCINNER;;
let LCINNER_RMUL = (MATCH_MP BILINEAR_RMUL o SPEC_ALL) BILINEAR_LCINNER;;
let LCINNER_LNEG = (MATCH_MP BILINEAR_LNEG o SPEC_ALL) BILINEAR_LCINNER;;
let LCINNER_RNEG = (MATCH_MP BILINEAR_RNEG o SPEC_ALL) BILINEAR_LCINNER;;
let LCINNER_LZERO = (MATCH_MP BILINEAR_LZERO o SPEC_ALL) BILINEAR_LCINNER;;
let LCINNER_RZERO = (MATCH_MP BILINEAR_RZERO o SPEC_ALL) BILINEAR_LCINNER;;
let BILINEAR_RCINNER = prove
(`bilinear(rcinner)`,
REWRITE_TAC[REWRITE_RULE[GSYM FUN_EQ_THM; ETA_AX] rcinner] THEN
MATCH_ACCEPT_TAC BILINEAR_PRODUCTGA);;
let RCINNER_LADD = (MATCH_MP BILINEAR_LADD o SPEC_ALL) BILINEAR_RCINNER;;
let RCINNER_RADD = (MATCH_MP BILINEAR_RADD o SPEC_ALL) BILINEAR_RCINNER;;
let RCINNER_LMUL = (MATCH_MP BILINEAR_LMUL o SPEC_ALL) BILINEAR_RCINNER;;
let RCINNER_RMUL = (MATCH_MP BILINEAR_RMUL o SPEC_ALL) BILINEAR_RCINNER;;
let RCINNER_LNEG = (MATCH_MP BILINEAR_LNEG o SPEC_ALL) BILINEAR_RCINNER;;
let RCINNER_RNEG = (MATCH_MP BILINEAR_RNEG o SPEC_ALL) BILINEAR_RCINNER;;
let RCINNER_LZERO = (MATCH_MP BILINEAR_LZERO o SPEC_ALL) BILINEAR_RCINNER;;
let RCINNER_RZERO = (MATCH_MP BILINEAR_RZERO o SPEC_ALL) BILINEAR_RCINNER;;
let BILINEAR_SCALARINNER = prove
(`bilinear(scalarinner)`,
REWRITE_TAC[REWRITE_RULE[GSYM FUN_EQ_THM; ETA_AX] scalarinner] THEN
MATCH_ACCEPT_TAC BILINEAR_PRODUCTGA);;
let SCALARINNER_LADD = (MATCH_MP BILINEAR_LADD o SPEC_ALL) BILINEAR_SCALARINNER;;
let SCALARINNER_RADD = (MATCH_MP BILINEAR_RADD o SPEC_ALL) BILINEAR_SCALARINNER;;
let SCALARINNER_LMUL = (MATCH_MP BILINEAR_LMUL o SPEC_ALL) BILINEAR_SCALARINNER;;
let SCALARINNER_RMUL = (MATCH_MP BILINEAR_RMUL o SPEC_ALL) BILINEAR_SCALARINNER;;
let SCALARINNER_LNEG = (MATCH_MP BILINEAR_LNEG o SPEC_ALL) BILINEAR_SCALARINNER;;
let SCALARINNER_RNEG = (MATCH_MP BILINEAR_RNEG o SPEC_ALL) BILINEAR_SCALARINNER;;
let SCALARINNER_LZERO = (MATCH_MP BILINEAR_LZERO o SPEC_ALL) BILINEAR_SCALARINNER;;
let SCALARINNER_RZERO = (MATCH_MP BILINEAR_RZERO o SPEC_ALL) BILINEAR_SCALARINNER;;
(* ------------------------------------------------------------------------- *)
(* Actions of products on basis and singleton basis. *)
(* ------------------------------------------------------------------------- *)
let PRODUCTGA_MVBASIS = prove
(`!s t. Productga sgn (mbasis s) (mbasis t) :real^(P,Q,R)geomalg =
if s SUBSET 1..(pdimindex(:P) + pdimindex(:Q) + pdimindex(:R)) /\
t SUBSET 1..(pdimindex(:P) + pdimindex(:Q) + pdimindex(:R))
then sgn s t % mbasis(s SYMDIFF t)
else vec 0`,
REPEAT GEN_TAC THEN REWRITE_TAC[Productga_DEF] THEN
SIMP_TAC[GEOMALG_MUL_COMPONENT; MVBASIS_COMPONENT] THEN
REWRITE_TAC[REAL_ARITH
`x * (if p then &1 else &0) * (if q then &1 else &0) =
if q then if p then x else &0 else &0`] THEN
REPEAT
(GEN_REWRITE_TAC (LAND_CONV o ONCE_DEPTH_CONV) [COND_RAND] THEN
GEN_REWRITE_TAC (LAND_CONV o ONCE_DEPTH_CONV) [COND_RATOR] THEN
SIMP_TAC[VECTOR_MUL_LZERO; COND_ID; VSUM_DELTA; IN_ELIM_THM; VSUM_0] THEN
ASM_CASES_TAC `t SUBSET 1..(pdimindex(:P) + pdimindex(:Q) + pdimindex(:R))` THEN
ASM_REWRITE_TAC[]));;
let PRODUCTGA_MVBASIS_SING = prove
(`!i j. Productga sgn (mbasis{i}) (mbasis{j}) :real^(P,Q,R)geomalg =
if i IN 1..pdimindex(:P) + pdimindex(:Q) + pdimindex(:R) /\
j IN 1..pdimindex(:P) + pdimindex(:Q) + pdimindex(:R)
then sgn {i} {j} % mbasis({i} SYMDIFF {j})
else vec 0`,
REWRITE_TAC[PRODUCTGA_MVBASIS; SET_RULE `{x} SUBSET s <=> x IN s`]);;
let GEOM_MVBASIS = prove
(`!s t.
mbasis s * mbasis t:real^(P,Q,R)geomalg =
(if s SUBSET 1..pdimindex(:P) + pdimindex(:Q) + pdimindex(:R) /\
t SUBSET 1..pdimindex(:P) + pdimindex(:Q) + pdimindex(:R)