build.gradle

/*
 * Copyright 2014 Netflix, Inc.
 * Copyright (c) 2018, salesforce.com, inc. All rights reserved.
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *    http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

buildscript {
  ext {
    kotlinVersion = "1.4.0"
    junitPlatformVersion = "1.0.2"
  }

  repositories {
    gradlePluginPortal()
  }

  dependencies {
    classpath "org.junit.platform:junit-platform-gradle-plugin:${junitPlatformVersion}"
  }
}

plugins {
  id 'io.spinnaker.project' version "$spinnakerGradleVersion" apply false
  id 'org.jetbrains.kotlin.jvm' version "$kotlinVersion"
  id 'org.jetbrains.kotlin.plugin.allopen' version "$kotlinVersion" apply false
  id "com.google.protobuf" version "0.8.12" apply false
}

allprojects {
  repositories {
    jcenter()
  }
}

subprojects {
  group = "com.netflix.spinnaker.clouddriver"
  apply plugin: 'io.spinnaker.project'

  if (name != "clouddriver-bom" && name != "clouddriver-api") {
    apply plugin: 'java-library'
    apply plugin: 'groovy'
    apply plugin: 'kotlin'
    apply plugin: "kotlin-allopen"
    apply plugin: "jacoco"

    sourceSets.main.java.srcDirs = []
    sourceSets.main.groovy.srcDirs += ["src/main/java"]

    dependencies {
      implementation platform("com.netflix.spinnaker.kork:kork-bom:$korkVersion")

      annotationProcessor platform("com.netflix.spinnaker.kork:kork-bom:$korkVersion")
      annotationProcessor "org.projectlombok:lombok"
      annotationProcessor("org.springframework.boot:spring-boot-configuration-processor")
      testAnnotationProcessor platform("com.netflix.spinnaker.kork:kork-bom:$korkVersion")
      testAnnotationProcessor "org.projectlombok:lombok"
      testRuntimeOnly "org.junit.vintage:junit-vintage-engine" // Required for Spock tests to execute along with Junit5 tests.
    }

    test {
      useJUnitPlatform()
      testLogging {
        exceptionFormat = 'full'
        if (project.hasProperty('slowTest')) {
          long slow = 250
          try {
            slow = Long.parseLong(project.property('slowTest'))
          } catch (Exception ex) {
          }
          afterTest { desc, result ->
            long duration = result.getEndTime() - result.getStartTime()
            if (duration > slow) {
              logger.warn("test exceeded $slow ms: $desc.className :: $desc.name ($duration milliseconds)")
            }
          }
        }
        minHeapSize = "512m"
        maxHeapSize = "512m"
      }
      jacoco {
        enabled = project.hasProperty('testCoverage')
      }
    }

    // The test report requires tests to have run first
    jacocoTestReport {
      dependsOn test
    }
  }

  if ([korkVersion, fiatVersion].any { it.endsWith("-SNAPSHOT") }) {
    logger.info("Enabling mavenLocal")
    repositories {
      mavenLocal()
    }
  }

  tasks.withType(JavaExec) {
    if (System.getProperty('DEBUG', 'false') == 'true') {
      jvmArgs '-agentlib:jdwp=transport=dt_socket,server=y,suspend=n,address=7102'
    }
  }
}

defaultTasks ':clouddriver-web:run'