android-common/build.gradle at main · nextcloud/android-common · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
/*
 * Nextcloud Android Common Library
 *
 * SPDX-FileCopyrightText: 2026 Alper Ozturk <alper.ozturk@nextcloud.com>
 * SPDX-FileCopyrightText: 2022-2023 Nextcloud GmbH and Nextcloud contributors
 * SPDX-License-Identifier: MIT
 */

buildscript {
    ext {
        daggerVersion = "2.60.1"
        kotlinVersion = "2.4.20"
        lifecycleVersion = "2.11.0"
        composeUiToolingVersion = "1.12.1"
        coilVersion = "3.6.3"
        okHttpVersion = "5.5.0"
        composeBomVersion = "2026.09.00"
        kotlinxSerializationVersion = "1.11.0"
        jUnitVersion = "4.13.2"
        androidXTestVersion = "1.3.0"
        androidXEspressoTestVersion = "3.7.0"
        mockkVersion = "1.14.11"
        mockitoVersion = "5.24.0"
        mockitoKotlinVersion = "6.4.0"
    }
}

// Top-level build file where you can add configuration options common to all sub-projects/modules.
plugins {
    id 'org.jetbrains.kotlin.plugin.compose' version '2.4.20' apply false
    id 'com.android.library' version '9.4.1' apply false
    id 'org.jetbrains.kotlin.android' version "$kotlinVersion" apply false
    id 'com.android.legacy-kapt' version '9.4.1' apply false
    id 'com.diffplug.spotless' version '8.10.2' apply false
    id 'io.gitlab.arturbosch.detekt' version '1.23.8' apply false
    id 'com.android.application' version '9.4.1' apply false
}

tasks.register('clean', Delete) {
    delete rootProject.buildDir
}

tasks.register('installGitHooks', Copy) {
    def sourceFolder = "${rootProject.projectDir}/scripts/hooks"
    def destFolder = "${rootProject.projectDir}/.git/hooks"

    description = "Install git hooks"
    group = "development"

    from(sourceFolder) {
        include '*'
    }
    into destFolder

    eachFile { file ->
        println "${sourceFolder}/${file.relativeSourcePath} -> ${destFolder}/${file.path}"
    }
}

allprojects {
    group = 'com.nextcloud.android-common'
}

subprojects {
    apply plugin: 'com.diffplug.spotless'
    apply plugin: 'io.gitlab.arturbosch.detekt'
    spotless {
        kotlin {
            target '**/*.kt'
            ktlint().editorConfigOverride([
                'ktlint_function_naming_ignore_when_annotated_with': 'Composable'
            ])
        }
    }
    detekt {
        buildUponDefaultConfig = true
        config.setFrom(rootProject.file('detekt.yml'))
    }
}