feat(build): Add support for CMake package (facebookincubator#14738)

Summary:
Fixes facebookincubator#14275
Fixes facebookincubator#14756

This is not a complete CMake package support. This works only when:

* `VELOX_BUILD_SHARED=ON`
* `VELOX_BUILD_MINIMAL_WITH_DWIO=ON`
* All dependencies are resolved from system (No bundled dependencies)

FYI: I want to use this for Nimble: facebookincubator/nimble#215
Nimble uses `VELOX_BUILD_MINIMAL_WITH_DWIO=ON`.

This is disabled by default. We can enabled this by specifying `VELOX_BUILD_CMAKE_PACKAGE=ON`.

Users can find Velox by `find_package(Velox)`.

We can expand supported cases step by step. How about this as the first step?

Pull Request resolved: facebookincubator#14738

Reviewed By: mbasmanova

Differential Revision: D81923615

Pulled By: Yuhta

fbshipit-source-id: 8a7cb55c5e57c3b87b696fa7298cbd171e80d40d

Author: kou

CMake/VeloxConfig.cmake.in

@@ -0,0 +1,70 @@
+# Copyright (c) Facebook, Inc. and its affiliates.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+@PACKAGE_INIT@
+
+include(CMakeFindDependencyMacro)
+
+block()
+  list(PREPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_LIST_DIR}")
+
+  if("@Arrow_SOURCE@" STREQUAL "SYSTEM")
+    find_dependency(Arrow)
+  endif()
+  if("@Boost_SOURCE@" STREQUAL "SYSTEM")
+    find_dependency(Boost COMPONENTS "@BOOST_INCLUDE_LIBRARIES@")
+  endif()
+  find_dependency(double-conversion)
+  if("@folly_SOURCE@" STREQUAL "SYSTEM")
+    find_dependency(folly)
+  endif()
+  if("@fmt_SOURCE@" STREQUAL "SYSTEM")
+    find_dependency(fmt)
+  endif()
+  if("@gflags_SOURCE@" STREQUAL "SYSTEM")
+    find_dependency(gflags)
+  endif()
+  if("@glog_SOURCE@" STREQUAL "SYSTEM")
+    find_dependency(glog)
+  endif()
+  if("@VELOX_ENABLE_COMPRESSION_LZ4@")
+    find_dependency(lz4)
+  endif()
+  if("@Protobuf_SOURCE@" STREQUAL "SYSTEM")
+    find_dependency(Protobuf)
+  endif()
+  if("@re2_SOURCE@" STREQUAL "SYSTEM")
+    find_dependency(re2)
+  endif()
+  if("@stemmer_SOURCE@" STREQUAL "SYSTEM")
+    find_dependency(stemmer)
+  endif()
+  if("@VELOX_BUILD_MINIMAL_WITH_DWIO@" OR "@VELOX_ENABLE_HIVE_CONNECTOR@")
+    find_dependency(Snappy)
+    find_dependency(ZLIB)
+    find_dependency(zstd)
+  endif()
+  if("@simdjson_SOURCE@" STREQUAL "SYSTEM")
+    find_dependency(simdjson)
+  endif()
+  if("@THRIFT_SOURCE@" STREQUAL "SYSTEM")
+    find_dependency(Thrift)
+  endif()
+  if("@xsimd_SOURCE@" STREQUAL "SYSTEM")
+    find_dependency(xsimd)
+  endif()
+endblock()
+
+include("${CMAKE_CURRENT_LIST_DIR}/VeloxTargets.cmake")
+
+check_required_components(Velox)

CMake/VeloxUtils.cmake

@@ -12,6 +12,9 @@
 # See the License for the specific language governing permissions and
 # limitations under the License.
 include_guard(GLOBAL)
+
+include(CMakePackageConfigHelpers)
+
 function(velox_get_rpath_origin VAR)
   if(APPLE)
     set(_origin @loader_path)
@@ -99,7 +102,54 @@ function(velox_add_library TARGET)
       add_library(velox ${_type} ${ARGN})
       set_target_properties(velox PROPERTIES LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
       set_target_properties(velox PROPERTIES ARCHIVE_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
-      install(TARGETS velox DESTINATION lib/velox)
+      install(TARGETS velox DESTINATION lib/velox EXPORT velox_targets)
+      if(VELOX_BUILD_CMAKE_PACKAGE)
+        set(package_cmake_dir "lib/cmake/Velox")
+        set(config_cmake_in "${PROJECT_SOURCE_DIR}/CMake/VeloxConfig.cmake.in")
+        set(config_cmake "${PROJECT_BINARY_DIR}/CMake/VeloxConfig.cmake")
+        configure_package_config_file(
+          "${config_cmake_in}"
+          "${config_cmake}"
+          INSTALL_DESTINATION "${package_cmake_dir}"
+        )
+        install(FILES "${config_cmake}" DESTINATION "${package_cmake_dir}")
+        set(system_dependencies)
+        if(Arrow_SOURCE STREQUAL "SYSTEM")
+          list(APPEND system_dependencies Arrow)
+        endif()
+        if(glog_SOURCE STREQUAL "SYSTEM")
+          list(APPEND system_dependencies glog)
+        endif()
+        if(VELOX_ENABLE_COMPRESSION_LZ4)
+          list(APPEND system_dependencies lz4)
+        endif()
+        if(re2_SOURCE STREQUAL "SYSTEM")
+          list(APPEND system_dependencies re2)
+        endif()
+        if(stemmer_SOURCE STREQUAL "SYSTEM")
+          list(APPEND system_dependencies stemmer)
+        endif()
+        if(VELOX_BUILD_MINIMAL_WITH_DWIO OR VELOX_ENABLE_HIVE_CONNECTOR)
+          list(APPEND system_dependencies Snappy zstd)
+        endif()
+        foreach(system_dependency ${system_dependencies})
+          install(
+            FILES "${PROJECT_SOURCE_DIR}/CMake/Find${system_dependency}.cmake"
+            DESTINATION "${package_cmake_dir}"
+          )
+        endforeach()
+        # TODO: We can enable this once we add version to Velox.
+        # set(version_cmake "${PROJECT_BINARY_DIR}/CMake/VeloxConfigVersion.cmake")
+        # write_basic_package_version_file("${version_cmake}"
+        #                                  COMPATIBILITY SameMajorVersion)
+        # install(FILES "${version_cmake}" DESTINATION "${package_cmake_dir}")
+        install(
+          EXPORT velox_targets
+          DESTINATION "${package_cmake_dir}"
+          NAMESPACE "Velox::"
+          FILE "VeloxTargets.cmake"
+        )
+      endif()
     endif()
     # create alias for compatability
     if(NOT TARGET ${TARGET})

CMakeLists.txt

@@ -90,6 +90,7 @@ option(
 option(VELOX_MONO_LIBRARY "Build single unified library." ON)
 option(ENABLE_ALL_WARNINGS "Enable -Wall and -Wextra compiler warnings." ON)
 option(VELOX_BUILD_SHARED "Build Velox as shared libraries." OFF)
+option(VELOX_BUILD_CMAKE_PACKAGE "Build CMake package for Velox." OFF)
 option(VELOX_SKIP_WAVE_BRANCH_KERNEL_TEST "Disable Wave branch kernel test." OFF)
 # While it's possible to build both in one go we currently want to build either
 # static or shared.
@@ -193,6 +194,14 @@ if(${VELOX_BUILD_MINIMAL} OR ${VELOX_BUILD_MINIMAL_WITH_DWIO})
   set(VELOX_ENABLE_S3 OFF)
   set(VELOX_ENABLE_GCS OFF)
   set(VELOX_ENABLE_ABFS OFF)
+else()
+  if(VELOX_BUILD_CMAKE_PACKAGE)
+    message(
+      FATAL_ERROR
+      "VELOX_BUILD_CMAKE_PACKAGE is only available with "
+      "VELOX_BUILD_MINIMAL=ON or VELOX_BUILD_MINIMAL_WITH_DWIO=ON for now."
+    )
+  endif()
 endif()
 
 if(${VELOX_ENABLE_BENCHMARKS})

velox/dwio/dwrf/common/CMakeLists.txt

@@ -43,7 +43,10 @@ velox_link_libraries(
 )
 
 # required for the wrapped protobuf headers/sources
-velox_include_directories(velox_dwio_dwrf_common PUBLIC ${PROJECT_BINARY_DIR})
+velox_include_directories(
+  velox_dwio_dwrf_common
+  PUBLIC "$<BUILD_LOCAL_INTERFACE:${PROJECT_BINARY_DIR}>"
+)
 
 if(NOT VELOX_MONO_LIBRARY)
   # trigger generation of pb files

velox/tpcds/gen/CMakeLists.txt

@@ -17,7 +17,10 @@ add_subdirectory(utils)
 add_subdirectory(dsdgen)
 
 velox_add_library(velox_tpcds_gen TpcdsGen.cpp DSDGenIterator.cpp)
-velox_include_directories(velox_tpcds_gen PUBLIC dsdgen/include)
+velox_include_directories(
+  velox_tpcds_gen
+  PUBLIC "$<BUILD_LOCAL_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/dsdgen/include>"
+)
 velox_link_libraries(
   velox_tpcds_gen
   PUBLIC velox_memory velox_tpcds_append_info

velox/tpch/gen/CMakeLists.txt

@@ -18,7 +18,10 @@ velox_add_library(velox_tpch_gen DBGenIterator.cpp TpchGen.cpp)
 
 velox_include_directories(velox_tpch_gen PRIVATE dbgen/include)
 
-velox_link_libraries(velox_tpch_gen velox_memory velox_vector dbgen)
+velox_link_libraries(
+  velox_tpch_gen
+  PUBLIC velox_memory velox_vector "$<BUILD_LOCAL_INTERFACE:dbgen>"
+)
 
 if(${VELOX_BUILD_TESTING})
   add_subdirectory(tests)