palette: add option to allow swapping colorscheme generator logic

Signed-off-by: lucasew <[email protected]>

Author: lucasew

stylix/palette.nix

@@ -8,6 +8,35 @@
 let
   cfg = config.stylix;
   opts = options.stylix;
+
+  # Validates that a palette contains all required base16 colors
+  validateBase16Palette =
+    palette:
+    let
+      requiredColors = [
+        "base00"
+        "base01"
+        "base02"
+        "base03"
+        "base04"
+        "base05"
+        "base06"
+        "base07"
+        "base08"
+        "base09"
+        "base0A"
+        "base0B"
+        "base0C"
+        "base0D"
+        "base0E"
+        "base0F"
+      ];
+      missingColors = lib.filter (c: !(palette ? ${c})) requiredColors;
+    in
+    if missingColors != [ ] then
+      throw "Palette generator output is missing required base16 colors: ${lib.concatStringsSep ", " missingColors}"
+    else
+      palette;
 in
 {
   options.stylix = {
@@ -41,6 +70,53 @@ in
       default = null;
     };
 
+    paletteGeneratorFunction = lib.mkOption {
+      description = ''
+        Function to generate palette from image. Must return a derivation that
+        produces a JSON file with a base16 color scheme (base00-base0F).
+
+        The function receives an attribute set with the following arguments:
+        - `polarity`: The polarity setting ("either", "light", or "dark")
+        - `image`: Path to the wallpaper image
+
+        Example:
+        ```nix
+
+            paletteGeneratorFunction = { polarity, image }:
+                  let
+                    color = "ffffff";
+                    colormap = {
+                      base00 = color;
+                      base01 = color;
+                      base02 = color;
+                      base03 = color;
+                      base04 = color;
+                      base05 = color;
+                      base06 = color;
+                      base07 = color;
+                      base08 = color;
+                      base09 = color;
+                      base0A = color;
+                      base0B = color;
+                      base0C = color;
+                      base0D = color;
+                      base0E = color;
+                      base0F = color;
+                    };
+                  in
+                  pkgs.runCommand "palette.json" {color = "ffffff"; } \'\'
+                    echo \'\$\{builtins.toJSON colormap}\' > $out
+                  \'\';
+        ```
+      '';
+      type = lib.types.functionTo lib.types.package;
+      default =
+        { polarity, image }:
+        pkgs.runCommand "palette.json" { } ''
+          ${lib.getExe cfg.paletteGenerator} "${polarity}" ${lib.escapeShellArg image} "$out"
+        '';
+    };
+
     imageScalingMode = lib.mkOption {
       type = lib.types.enum [
         "stretch"
@@ -80,20 +156,17 @@ in
         # and not anything indirect such as filling a template, otherwise
         # the output of the palette generator will not be protected from
         # garbage collection.
-        default = pkgs.runCommand "palette.json" { } ''
-          ${lib.getExe cfg.paletteGenerator} \
-            "${cfg.polarity}" \
-            ${lib.escapeShellArg cfg.image} \
-            "$out"
-        '';
+        default = cfg.paletteGeneratorFunction {
+          inherit (cfg) polarity image;
+        };
       };
 
       palette = lib.mkOption {
         type = lib.types.attrs;
         description = "The palette generated by the palette generator.";
         readOnly = true;
         internal = true;
-        default = (lib.importJSON cfg.generated.json) // {
+        default = validateBase16Palette (lib.importJSON cfg.generated.json) // {
           author = "Stylix";
           scheme = "Stylix";
           slug = "stylix";