Why is #partial switch required also with case:?

[programandala-net]

When a switch value is enum or union, Odin requires #partial in order to omit certain cases, even when a default case: is included. Why the presence of case: is not considered enough to make the intention of the programmer explicit? Paradoxically, when the checked value is not enum or union, a default case: is not required.

Complete example, after a similar code from the documentation of #partial switch:

package partial_switch

import "core:fmt"

Foo :: enum {
	A,
	B,
	C,
}

main :: proc() {

	f := Foo.A

	// This works fine:
	switch f {
		case .A: fmt.println("A")
		case .B: fmt.println("B")
		case .C: fmt.println("C")
		case:    fmt.println("?")
	}

	// This works fine:
	#partial switch f {
		case .A: fmt.println("A")
		case .C: fmt.println("C")
	}

	// Error:
	// Unhandled switch case: B
	// Suggestion: Was '#partial switch' wanted?
	switch f {
		case .A: fmt.println("A")
		case .C: fmt.println("C")
		case:    fmt.println("?")
	}
}

[z64]

The reason is that this is valid: f := Foo(5)

You can create variants of an enum that are not backed by any named member. This value may come from a piece of runtime information that cannot be checked by the compiler.

In other words, non-partial switch requires you to handle

• All named values must have an explicit case .Value
• A default codepath for unnamed values

package main

import "core:fmt"

Foo :: enum {
    A,
    B,
    C,
}

test :: proc(foo: Foo) {
    switch foo {
    case .A: fmt.println("Named A")
    case .B: fmt.println("Named B")
    case .C: fmt.println("Named C")
    case:
        fmt.println("Unnamed", foo)
    }
}

main :: proc() {
    test(.A)
    test(.B)
    test(Foo(5))
}

Named A
Named B
Unnamed %!(BAD ENUM VALUE=5)