Main procedures in Odin can't return a value ?

[eleriaqueen]

Hi, I only do some coding here and there and I'm new to the Odin language so forgive my ignorance.

Can main procedures Odin programs not return a value?
It would seem to me like not having the ability to do so would be problematic as lots of linux shellscripts and scripts in general depend on exit values of apps.
I've kept thinking about this for a day while working on a very small game modding tool (in Odin) and haven't found a clear answer on the website or in the documentation like "Main proc in Odin don't/can't return a value" or "Here's how to return a value from a main proc".

[z64]

Are you looking for os.exit()?

If you want to emulate something like int main() from C, for example, you can define another proc like run which does return a value. Then all your main does is call that function, and handle any error it returned accordingly - using os.exit() to abort with an exit code, or whatever you would like your specific application to do.

package main

import "core:os"
import "core:fmt"

main :: proc() {
    // your "real" `main`
    err := run()

    exit_code := 0
    exit_message: Maybe(string)

    // map error values to status codes & messages
    switch err {
    case .None:
        // OK
    case .Oops:
        exit_code = 1
        exit_message = "Oops..."
    }

    if message, ok := exit_message.?; ok {
        fmt.eprintln("Error:", exit_message)
    }
    os.exit(exit_code)
}

Error :: enum {
    None,
    Oops,
    // add more
}

run :: proc() -> (err: Error) {
    // (app code here)
    return .Oops
}

[eleriaqueen]

Ohhh, thank you very much for the explanation and example code.

[avelican]

Thanks. Perhaps this should be explained in the docs, I had a hard time finding anything about it and thought it was an oversight in the language design.