build.gradle

// Top-level build file where you can add configuration options common to all sub-projects/modules.

buildscript {
    repositories {
        google()
        mavenCentral()
        maven{  url "https://plugins.gradle.org/m2/" }
    }

    dependencies {

        classpath 'com.android.tools.build:gradle:8.4.2'
        classpath 'com.github.dcendents:android-maven-gradle-plugin:2.0'
        classpath 'gradle.plugin.org.kt3k.gradle.plugin:coveralls-gradle-plugin:2.12.2'
        classpath 'com.google.firebase:firebase-crashlytics-gradle:3.0.2'
        //classpath 'com.palantir:jacoco-coverage:0.4.0'
        // NOTE: Do not place your application dependencies here; they belong
        // in the individual module build.gradle files
    }
}

apply plugin: 'com.github.kt3k.coveralls'
apply from: 'configs.gradle'

allprojects {
    repositories {
        google()
        mavenCentral()
        mavenLocal()
        maven { url "https://jitpack.io" }
        maven { url "https://repository.liferay.com/nexus/content/repositories/public" }
        maven {
            url "https://dl.cloudsmith.io/public/terraframe/geoprism-registry/maven/"
        }
        maven {
            url "https://api.mapbox.com/downloads/v2/releases/maven"
            authentication {
                basic(BasicAuthentication)
            }
            credentials {
                // Do not change the username below.
                // This should always be `mapbox` (not your username).
                username = "mapbox"
                // Use the secret token you stored in gradle.properties as the password
                password = localProperties['mapbox.sdk.token'] ?: ""
            }
        }
        maven{url  "https://oss.sonatype.org/content/repositories/snapshots"}
        maven{url  "https://s01.oss.sonatype.org/content/repositories/snapshots"}
    }

}
/*
task clean(type: Delete) {
    delete rootProject.buildDir
}
 */

apply plugin: 'java'

coveralls {
    jacocoReportPath = layout.buildDirectory.dir("reports/jacoco/jacocoFullReport/jacocoFullReport.xml")
    sourceDirs += ["utils/src/main/java"
                   , "library/src/main/java"
                   , "sample/src/main/java"
                   , "wrapper/src/main/java"]
}

task jacocoFullReport(type: JacocoReport, group: 'Coverage reports') {

    mustRunAfter ":library:testDebugUnitTest"
    mustRunAfter ":utils:testDebugUnitTest"
    mustRunAfter ":sample:testDebugUnitTest"

    mustRunAfter ":library:connectedDebugAndroidTest"
    mustRunAfter ":utils:connectedDebugAndroidTest"
    mustRunAfter ":sample:connectedDebugAndroidTest"

    mustRunAfter ":library:jacocoTestReport"
    mustRunAfter ":utils:jacocoTestReport"
    mustRunAfter ":sample:jacocoTestReport"

    description = 'Generates an aggregate report from all subprojects'

    additionalSourceDirs.from = files(subprojects.sourceSets.main.allSource.srcDirs)
    sourceDirectories.from = files(subprojects.sourceSets.main.allSource.srcDirs)
    classDirectories.from = files(subprojects.sourceSets.main.output)


    List<File> executionDataPaths = new ArrayList<>()
    List<File> classPaths = new ArrayList<>()
    List<File> sourcePaths = new ArrayList<>()
    List<File> jacocoClasspathPaths = new ArrayList<>()

    for (subModule in subprojects) {
        def jacocoTestReportTask = subModule.getTasksByName("jacocoTestReport", false)
        jacocoTestReportTask.forEach({task ->
            if (task instanceof JacocoReport) {
                executionDataPaths.addAll((task as JacocoReport).executionData.getFiles())
                classPaths.addAll((task as JacocoReport).classDirectories)
                sourcePaths.addAll((task as JacocoReport).sourceDirectories)
                jacocoClasspathPaths.addAll((task as JacocoReport).jacocoClasspath)
            }
        })
    }

    executionData.from = executionDataPaths
    sourceDirectories.from = sourcePaths
    classDirectories.from = classPaths

    reports {
        xml.required.set(true)
        html.required.set(true)
        xml.outputLocation = layout.buildDirectory.file("reports/jacoco/jacocoFullReport/jacocoFullReport.xml")
        html.outputLocation = layout.buildDirectory.dir("reports/jacoco/jacocoFullReport/html")
    }

    jacocoClasspath = files(jacocoClasspathPaths)
}


task printClasspath {
    doLast {
        this.printClasspath
    }

    //def task = org.gradle.testing.jacoco.tasks.JacocoReport()
}