Add fields to the frontmater and a question

[quijote-asim]

I would like to be able to include in the frontmatter of the notes these fields:

#+category:
#+lastmod:
#+startup: content (or shownlevels)

This raises two questions for me:

1. what is the simplest way to do this. Making a function that adds it I suppose is feasible, but it's out of my scope today.
2. How could one make a function that updates lastmod when saving a note.

Thanks

[lmq-10]

1. If you just want to append those keywords to the front matter (not filling them automatically at note creation), then this will work:

(setq denote-org-front-matter
      "#+title:      %s
#+date:       %s
#+filetags:   %s
#+identifier: %s
#+signature:  %s
#+category:   
#+lastmod:    
#+startup:    content
\n")

With that, every new note will have these fields and you will be able to fill them yourself.

2. Your second question requires you to know a little bit of Elisp. If you want to learn the language, I recommend you to read the Emacs Lisp Intro bundled with Emacs (type C-h R eintr RET).

I'll give you a solution, for now:

(defun my/update-lastmod-keyword ()
  "Update #+lastmod keyword for Denote files."
  (when (denote-file-is-note-p buffer-file-name)
    ;; In the above line, we check if we are saving a note. If (and
    ;; only if) that is true, then we instruct Emacs to do the
    ;; following:
    (save-excursion
      (goto-char (point-min))
      ;; We just moved to the start of the file. Now, we search the
      ;; keyword we want:
      (when (re-search-forward "^#\\+lastmod: +" nil t)
        ;; If (and only if) we found it, then we clean it by deleting
        ;; the previous modification time
        (delete-region (point) (line-end-position))
        ;; Now we insert the new modification time using Org (I assume
        ;; you use Org by the keywords you used)
        (org-insert-timestamp (current-time) t t)))))

;; The next line instructs Emacs to call the previous function before
;; saving a file
(add-hook 'before-save-hook #'my/update-lastmod-keyword)

That's it! Just add that to your configuration. Be sure to add it after loading Denote (if you use use-package, add it under the :config block).

[quijote-asim]

Thanks you for your suggestions

[lmq-10]

De nada, es un placer ayudar 🙂