Enable HIDAPI for cmake build.

Author: t-paul

CMakeLists.txt

@@ -272,6 +272,22 @@ message(STATUS "LibXml2: ${LIBXML2_VERSION_STRING}")
 include_directories(${LIBXML2_INCLUDE_DIR})
 list(APPEND COMMON_LIBRARIES ${LIBXML2_LIBRARIES})
 
+option(ENABLE_HIDAPI "Enable support for HIDAPI input driver." ON)
+if(ENABLE_HIDAPI)
+  find_package(HidAPI 0.10 QUIET)
+  if(HIDAPI_FOUND)
+    message(STATUS "HidAPI: ${HIDAPI_VERSION_STRING}")
+    set(INPUT_DRIVER_HIDAPI_SOURCES src/input/HidApiInputDriver.cc)
+    include_directories(${HIDAPI_INCLUDE_DIR})
+    list(APPEND COMMON_LIBRARIES ${HIDAPI_LIBRARY})
+    add_definitions(-DENABLE_HIDAPI)
+  else()
+    message(STATUS "HIDAPI: disabled")
+  endif()
+else()
+  message(STATUS "HIDAPI: disabled per user request")
+endif()
+
 option(ENABLE_CAIRO "Enable support for cairo vector graphics library." ON)
 if(ENABLE_CAIRO)
   find_package(Cairo 1.14 QUIET)
@@ -632,6 +648,7 @@ endif()
 
 set(INPUT_DRIVER_SOURCES
   ${PLATFORM_INPUT_DRIVER_SOURCES}
+  ${INPUT_DRIVER_HIDAPI_SOURCES}
   ${INPUT_DRIVER_DBUS_SOURCES})
 
 set(GUI_SOURCES

cmake/Modules/FindHidAPI.cmake

@@ -0,0 +1,30 @@
+find_package(PkgConfig QUIET)
+PKG_CHECK_MODULES(PC_HIDAPI QUIET hidapi-libusb)
+
+find_path(HIDAPI_INCLUDE_DIR NAMES hidapi.h
+	HINTS
+	${PC_HIDAPI_INCLUDEDIR}
+	${PC_HIDAPI_INCLUDE_DIRS})
+
+find_library(HIDAPI_LIBRARY NAMES hidapi-libusb
+	HINTS
+	${PC_HIDAPI_LIBDIR}
+	${PC_HIDAPI_LIBRARY_DIRS})
+
+if(HIDAPI_INCLUDE_DIR AND EXISTS "${HIDAPI_INCLUDE_DIR}/hidapi.h")
+  file(STRINGS "${HIDAPI_INCLUDE_DIR}/hidapi.h" hidapi_version_major
+      REGEX "^#define[\t ]+HID_API_VERSION_MAJOR[\t ]+[0-9]+")
+  file(STRINGS "${HIDAPI_INCLUDE_DIR}/hidapi.h" hidapi_version_minor
+      REGEX "^#define[\t ]+HID_API_VERSION_MINOR[\t ]+[0-9]+")
+  file(STRINGS "${HIDAPI_INCLUDE_DIR}/hidapi.h" hidapi_version_patch
+      REGEX "^#define[\t ]+HID_API_VERSION_PATCH[\t ]+[0-9]+")
+  string(REGEX REPLACE "[^0-9.]" "" HIDAPI_VERSION_STRING "${hidapi_version_major}.${hidapi_version_minor}.${hidapi_version_patch}")
+  unset(hidapi_version_major)
+  unset(hidapi_version_minor)
+  unset(hidapi_version_patch)
+endif()
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(HidAPI REQUIRED_VARS HIDAPI_LIBRARY HIDAPI_INCLUDE_DIR)
+
+mark_as_advanced(HIDAPI_INCLUDE_DIR HIDAPI_LIBRARY)