nextflow.config

process {
    publishDir = {"./results/$sid/$task.process"}
    scratch = true
    errorStrategy = { task.attempt <= 3 ? 'retry' : 'ignore' }
    maxRetries = 3
    maxErrors = -1
    stageInMode = 'copy'
    stageOutMode = 'rsync'
    tag = { "$sid" }
    afterScript = 'sleep 1'
}

params {
    //*BIDS options**//
        clean_bids=false

    //**Global options**//
        b0_thr_extract_b0=10
        dwi_shell_tolerance=20

    //**SH fitting**//
        sh_fitting=false
        sh_fitting_order=6
        sh_fitting_basis="descoteaux07"


    //**Preliminary DWI brain extraction**//
        dilate_b0_mask_prelim_brain_extraction=5
        bet_prelim_f=0.16

    //**Denoise dwi (dwidenoise in Mrtrix3)**//
        run_dwi_denoising=true
        extent=7

    //**GIBBS CORRECTION (mrdegibbs in Mrtrix3)**//
        run_gibbs_correction=false

    //**Topup**//
        run_topup=true
        config_topup="b02b0.cnf"
        encoding_direction="y"
        readout=0.062
        prefix_topup="topup_results"

    //**Eddy**//
        run_eddy=true
        eddy_cmd="eddy_cpu"
        bet_topup_before_eddy_f=0.16
        use_slice_drop_correction=true

    //**Final DWI BET**//
        bet_dwi_final_f=0.16

    //**Denoise T1**//
        run_t1_denoising=false

    //**Resample T1**//
        run_resample_t1=true
        t1_resolution=1
        t1_interpolation="lin"

    //**Normalize DWI**//
        fa_mask_threshold=0.4

    //**Resample DWI**//
        run_resample_dwi=true
        dwi_resolution=1
        dwi_interpolation="lin"

    //**Extract DTI shells using this value as maximum**//
        max_dti_shell_value=1200

    //**Extract fODF shells using this value as minimum**//
        min_fodf_shell_value=700

    //**Segment tissues**//
        number_of_tissues=3

    //**Compute fiber response function (frf)**//
        fa=0.7
        min_fa=0.5
        min_nvox=300
        roi_radius=20
        set_frf=true
        manual_frf="15,4,4"

    //**Mean fiber response function (frf)**//
        mean_frf=false

    //**Compute fODF metrics**//
        sh_order=8
        basis="descoteaux07"
        fodf_metrics_a_factor=2.0
        relative_threshold=0.1
        max_fa_in_ventricle=0.1
        min_md_in_ventricle=0.003

    //**PFT seeding mask**//
        pft_seeding_mask_type="wm"
        pft_fa_seeding_mask_threshold=0.1

    //**PFT tracking**//
        run_pft_tracking=true
        pft_compress_streamlines=true
        pft_algo="prob"
        pft_seeding="npv"
        pft_nbr_seeds=10
        pft_step=0.5
        pft_theta=20
        pft_sfthres=0.1
        pft_sfthres_init=0.5
        pft_min_len=20
        pft_max_len=200
        pft_particles=15
        pft_back=2
        pft_front=1
        pft_compress_value=0.2
        pft_random_seed=0

    //**Local seeding mask**//
        local_seeding_mask_type="wm"
        local_fa_seeding_mask_threshold=0.1

    //**Local tracking mask**//
        local_tracking_mask_type="wm"
        local_fa_tracking_mask_threshold=0.1

    //**Local tracking**//
        run_local_tracking=false
        local_compress_streamlines=true
        local_algo="prob"
        local_seeding="npv"
        local_nbr_seeds=10
        local_step=0.5
        local_theta=20
        local_sfthres=0.1
        local_sfthres_init=0.5
        local_min_len=20
        local_max_len=200
        local_compress_value=0.2
        local_random_seed=0
        local_tracking_gpu=false
        local_batch_size_gpu=10000

    //**Number of processes per tasks**//
        processes_brain_extraction_t1=4
        processes_denoise_dwi=4
        processes_denoise_t1=4
        processes_eddy=4
        processes_fodf=4
        processes_registration=4
        processes_local_tracking=4

    //**Tractoflow-ABS**//
        run_tractoflow_abs = false

    //**Template T1 path**//
        template_t1="/human-data/mni_152_sym_09c/t1"

    //**Output directory**//
        output_dir=false

    //**Process control**//
        processes = false

    Mean_FRF_Publish_Dir = "./results/Mean_FRF"
    Readme_Publish_Dir = "./results/Readme"
    Read_BIDS_Publish_Dir = "./results/Read_BIDS"
}

if(params.output_dir) {
    process.publishDir = {"$params.output_dir/$sid/$task.process"}
    params.Mean_FRF_Publish_Dir = "${params.output_dir}/Mean_FRF"
    params.Readme_Publish_Dir = "${params.output_dir}/Readme"
    params.Read_BIDS_Publish_Dir = "${params.output_dir}/Read_BIDS"
    workDir =  "${params.output_dir}/work"
}

if(params.processes) {
    if(params.processes > Runtime.runtime.availableProcessors()) {
        throw new RuntimeException("Number of processes higher than available CPUs.")
    }
    else if(params.processes < 1) {
        throw new RuntimeException("When set, number of processes must be >= 1 " +
                                   "and smaller or equal to the number of CPUs.")
    }
    else {
        executor.$local.cpus = params.processes
    }
}

singularity.autoMounts = true
singularity.runOptions = "--no-home"

profiles {

    use_gpu {
        singularity.runOptions='--nv'
        docker.runOptions='--gpus all'
        params.eddy_cmd="eddy_cuda10.2"
        params.local_algo="prob"
        params.local_tracking_gpu=true
    }

    fully_reproducible {
        params.processes_brain_extraction_t1=1
        params.processes_denoise_dwi=4
        params.processes_denoise_t1=4
        params.processes_eddy=1
        params.processes_fodf=4
        params.processes_registration=1
        params.processes_local_tracking=1
    }

    skip_preprocessing {
        params.run_resample_t1 = false
        params.run_resample_dwi = false
        params.run_topup = false
        params.run_eddy = false
        params.run_dwi_denoising = false
        process {
            withLabel: 'big_mem' { maxForks = 10 }
        }
    }

    macos {
            process.scratch="/tmp"
    }

    cbrain {
      process{
        if(params.output_dir) {
          publishDir = [path: {"$params.output_dir/$sid/$task.process"}, mode: 'copy']
        }
        else{
          publishDir = [path: {"./results/$sid/$task.process"}, mode: 'copy']
        }

        withName: 'README' {
          publishDir = [path: {"$params.Readme_Publish_Dir"}, mode: 'copy']
        }
        withName: 'Read_BIDS' {
          publishDir = [path: {"$params.Read_BIDS_Publish_Dir"}, mode: 'copy']
        }
      }
    }

    ABS {
        params.run_tractoflow_abs=true
        params.run_local_tracking=true
        params.run_pft_tracking=false
    }

    bundling {
        //**Local tracking**//
        params.run_local_tracking=true
        params.local_nbr_seeds=5
        params.local_tracking_mask_type="fa"
        params.local_seeding_mask_type="fa"
        params.local_fa_seeding_mask_threshold=0.15
        params.local_fa_tracking_mask_threshold=0.15

        //**PFT tracking**//
        params.pft_nbr_seeds=10
    }

    connectomics {
        //**PFT tracking**//
        params.pft_nbr_seeds=30
        params.pft_seeding_mask_type="interface"
    }
}