build.gradle

//
// Copyright 2020  SenX S.A.S.
//
// Use of this software is governed by the Business Source License
// included in the file licenses/BSL.txt.
//
// As of the Change Date specified in that file, in accordance with
// the Business Source License, use of this software will be governed
// by the Apache License, Version 2.0, included in the file
// licenses/APL.txt.
//

plugins {
  id 'com.github.johnrengelman.shadow' version '7.0.0'
  id 'net.nemerosa.versioning' version '2.14.0'
  id 'io.codearte.nexus-staging' version '0.22.0'
  id 'java'
  id 'java-library'
  id 'idea'
  id 'eclipse'
  id 'maven-publish'
  id 'signing'
  id 'antlr'
}

project.group = 'io.warp10'
project.description = 'FLoWS WarpScript Extension'

// If the current tag is set, then it's a new release. Don't add build number
project.version = versioning.info.lastTag + ((versioning.info.tag != null) ? '' : '-' + versioning.info.build)
//
// Repositories for the project dependencies
//

repositories {
    mavenCentral()
}

configurations {
  provided
}

//
// Dependencies of the project
//
dependencies {
  compileOnly 'io.warp10:warpscript:2.8.1'

  //
  // Insert your dependencies here
  //
  antlr 'org.antlr:antlr4:4.8'

  testCompileOnly 'io.warp10:warpscript:2.8.1'
  testImplementation 'junit:junit:4.12'
}

test {
  useJUnit()
}

sourceSets {
  main {
    compileClasspath = compileClasspath + configurations.provided
  }
}

eclipse.classpath.plusConfigurations += [configurations.provided]  // Eclipse users only

// for IntelliJ users
idea {
  module {
    scopes.PROVIDED.plus += [configurations.provided]
  }
}

java {
    withJavadocJar()
    withSourcesJar()
}

jar {
  manifest {
        attributes('WarpFleet-Description': project.description)
        attributes('WarpFleet-Group': project.group)
        attributes('WarpFleet-Artifact': project.name)
        attributes('WarpFleet-Version': project.version)
  }

  from('src/main/warpscript') {
    //
    // Only consider macros which are in our namespace
    //
    include project.group + '/' + project.name + '/*.mc2'
    include project.group + '/' + project.name + '/**/*.mc2'
  }

  from('.') {
      include 'README.md'
      include project.group + '-' + project.name + '.conf'
  }
}

shadowJar {
  classifier = ''

  manifest {
        attributes('WarpFleet-Description': project.description)
        attributes('WarpFleet-Group': project.group)
        attributes('WarpFleet-Artifact': project.name)
        attributes('WarpFleet-Version': project.version)
  }

  from('src/main/warpscript') {
    //
    // Only consider macros which are in our namespace
    //
    include project.group + '/' + project.name + '/*.mc2'
    include project.group + '/' + project.name + '/**/*.mc2'
  }

  from('.') {
      include 'README.md'
      include project.group + '-' + project.name + '.conf'
  }

  dependencies {
    exclude(dependency('org.slf4j::'))
  }
}

shadowJar.dependsOn(test)

//
// Maven related config
//
publishing {
  publications {
    maven(MavenPublication) {
      groupId project.group
      artifactId project.name
      version = project.version
      from components.java

      pom {
        name = project.name
        description = project.description
        url = 'https://github.com/senx/' + project.name

        scm {
          connection = 'scm:git:git://github.com/senx/' + project.name
          developerConnection = 'scm:git:ssh://github.com/senx/' + project.name
          url = 'https://github.com/senx/' + project.name
        }

        licenses {
          license {
            name = 'The Apache License, Version 2.0'
            url = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
          }
        }

        developers {
          developer {
            id = 'senx'
            name = 'SenX'
            email = 'contact@senx.io'
          }
        }
      }
    }
  
    uberJar(MavenPublication) {
      groupId project.group
      artifactId project.name
      artifact(shadowJar)
      artifact(tasks['javadocJar'])
      artifact(tasks['sourcesJar'])
      version = project.version + '-uberjar'

      pom {
        name = project.name
        description = project.description
        url = 'https://github.com/senx/' + project.name

        scm {
          connection = 'scm:git:git://github.com/senx/' + project.name
          developerConnection = 'scm:git:ssh://github.com/senx/' + project.name
          url = 'https://github.com/senx/' + project.name
        }

        licenses {
          license {
            name = 'The Apache License, Version 2.0'
            url = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
          }
        }

        developers {
          developer {
            id = 'senx'
            name = 'SenX'
            email = 'contact@senx.io'
          }
        }
      }
    }
  }

  repositories {
    if (project.hasProperty('ossrhUsername')) {
      maven {
        url 'https://oss.sonatype.org/service/local/staging/deploy/maven2/'
        credentials {
          username ossrhUsername
          password ossrhPassword
        }
      }
    }
    if (project.hasProperty('nexusUsername')) {
      maven {
        name 'nexus'
        allowInsecureProtocol true
        url "$nexusHost/repository/maven-releases/"
        credentials {
          username nexusUsername
          password nexusPassword
        }
      }
    }
  }
}

artifacts {
    archives shadowJar, javadocJar, sourcesJar
}

if (project.hasProperty('ossrhUsername')) {
  nexusStaging {
    packageGroup = 'io.warp10'
    username ossrhUsername
    password ossrhPassword
  }
}

//
// Artifact Signing
//
if (project.hasProperty('signing.gnupg.keyName')) {
  signing {
        useGpgCmd()
        sign publishing.publications
  }
}

generateGrammarSource {
  arguments += [ '-package', 'io.warp10.ext.flows.antlr' ]
  doLast {
    copy {
      from 'build/generated-src/antlr/main/'
      include '*.*'
      into 'build/generated-src/antlr/main/io/warp10/ext/flows/antlr'
    }
    project.delete fileTree('build/generated-src/antlr/main').include('*.*')
  }
}