Fixing multiline [if]/[else]/[then] in includes using IO redirection?

[epsilon537]

As you mentioned, [if]/[else]/[then] spread over multiple lines doesn't work in include files, because these words rely on query, and query doesn't work as expected when feeding the include file to evaluate line-by-line.
https://github.com/spyren/Mecrisp-Cube/blob/master/sdcard/man/FileSystem.md#interpreter-directives

However, if include were implemented using IO redirection instead, wouldn't that circumvent the issue with query?

[spyren]

Good idea:

Contents of file /home/id.fs

[IFNDEF] hallo
: hallo
  ." Velo!" cr
;
[ENDIF]

hallo

First without word hallo

create fil /FIL allot  ok.
create fn 50 allot  ok.
fn dup 20 accept /home/id.fs  ok.
str0term  ok.
fil fn <f_open  ok.
<file  ok.
  ok.
[IFNDEF] hallo  ok.
: hallo  ok.
  ." Velo!" cr  ok.
;  ok.
[ENDIF]  ok.
  ok.
hallo Velo!
 ok.

Second with existing word hallo

: hallo  ok.
  ." Velo!" cr  ok.
;  ok.
create fil /FIL allot  ok.
create fn 50 allot  ok.
fn dup 20 accept /home/id.fs  ok.
str0term  ok.
fil fn <f_open  ok.
<file  ok.
  ok.
[IFNDEF] hallo 
: hallo 
  ." Velo!" cr 
; 
[ENDIF]  ok.
  ok.
hallo Velo!
 ok.

It works! But there is a problem to get back to the original console and nesting is hard to achieve.

[epsilon537]

Great! I'll give a try soon. To be able to go back to the original console, I guess the old descriptor needs to be saved on a stack and restored when EOF is encountered?

[spyren]

Unfortunately, it's not that simple.
include ( i*x "name" -- j*x ) Interprets the content of the file "name"
The stack is not balanced!

However, I found a solution, at least for me. I changed the include word, it concatenates lines with \ at its end.

It looks a bit like a C macro ;-)

[IFNDEF] .( \
: .( ( "ccc<paren>" -- ) \ Parse and display ccc delimited by ) \
  [char] ) ['] ." $1E + call, parse string, \
  immediate 0-foldable ; \
[THEN]

BTW I implemented the bracket-conditionals in assembler.

See also:
https://github.com/spyren/Mecrisp-Cube/blob/master/sdcard/man/FileSystem.md#interpreter-directives

[epsilon537]

I've been playing around with input file redirection. I've come to the same conclusion as you. Input file redirection happens at character level (key/key?). That is not the right level for a line-oriented "include". Include based on "evaluate", i.e. the approach you were using is the right approach.

I ended up with an alternative implementation for "[ifdef]". Rather than have it call "query", it calls a new word, "refill". Refill checks a variable called "include-source-id". If it's 0, it invokes query. If it's non-zero it:

1. treats the value as a file descriptor.
2. reads a line from that file.
3. sets source ("setsource") to that line.

In other words, "refill" is a variant of "query' that also support input from file rather than just input from the console.

"Include" keeps the include-source-id variable up-to-date. When include isn't executing, include-source-id set to 0. When include is running, include-source-id is set to the file being included.

0 variable include-source-id

\ Load forth code from a file with the specified path.
\ include may be used recursively, i.e. the file being
\ included itself may contain one or more include calls.
\ ( "path" -- )
: include
include-source-id @ include-push
token FA_OPEN_EXISTING FA_READ or f_open ( fil )
dup include-source-id ! ( fil )
80 [: ( fil buf )
begin ( fil buf )
2dup 80 f_gets ( fil buf adr len )
dup 0> while ( fil buf adr len )
1- evaluate ( fil buf )
repeat
;] with-temp-allot ( fil buf adr len )
2drop drop ( fil )
f_close ( )
include-pop ( source-id )
include-source-id !
;

\ ( -- )
: refill
include-source-id @ ?dup if
80 [: ( fil buf )
80 f_gets ( adr len )
setsource ;] with-temp-allot
else
query
then
;

See:
https://github.com/epsilon537/boxlambda/blob/develop/sw/components/forth/forth/shell.fs
https://github.com/epsilon537/boxlambda/blob/develop/sw/components/forth/forth/conditional-comp.fs