Missing nixos flake attribute on self

[FelipeMarcelino]

Updated my nix flake regarding the inputs I were using, and then seems that flake or flake parts is have not the same structure regarding the code I am usingt to configure my nixos/home/darwin machines. Getting the following error:

direnv: loading ~/Development/nix-dotfiles/.envrc
warning: Git tree '/home/felipemarcelino/Development/nix-dotfiles' is dirty
error:
       … while calling the 'derivationStrict' builtin

         at /builtin/derivation.nix:9:12: (source not available)

       … while evaluating derivation 'activate'
         whose name attribute is located at /nix/store/zgzjib5vbxl9l2ridhjfvs1ll6lil8s6-source/pkgs/stdenv/generic/make-derivation.nix:375:7

       … while evaluating attribute 'buildCommand' of derivation 'activate'

         at /nix/store/zgzjib5vbxl9l2ridhjfvs1ll6lil8s6-source/pkgs/build-support/trivial-builders/default.nix:59:16:

           58|         enableParallelBuilding = true;
           59|         inherit buildCommand name;
             |                ^
           60|         passAsFile = [ "buildCommand" ]

       (stack trace truncated; use '--show-trace' to show the full trace)

       error: attribute 'nixos-flake' missing

       at /nix/store/wdc6wwj3slxq45jir14i60rysly4s94d-source/flake.nix:59:20:

           58|         darwinConfigurations = {
           59|           felipe = self.nixos-flake.lib.mkMacosSystem {
             |                    ^
           60|             nixpkgs.hostPlatform = "aarch64-darwin";

On thef following file:

{
 description = "My NixOS/Darwin/Flakes/Home Manager configuration for everything!";

 inputs = {
   nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
   nix-darwin.url = "github:lnl7/nix-darwin/master";
   nix-darwin.inputs.nixpkgs.follows = "nixpkgs";
   home-manager.url = "github:nix-community/home-manager";
   home-manager.inputs.nixpkgs.follows = "nixpkgs";
   flake-parts.url = "github:hercules-ci/flake-parts";
   nixos-flake.url = "github:srid/nixos-flake";
   nixvim.url = "github:nix-community/nixvim";
   nixvim.inputs.nixpkgs.follows = "nixpkgs";
   disko.url = "github:nix-community/disko";
   disko.inputs.nixpkgs.follows = "nixpkgs";
   sops-nix.url = "github:Mic92/sops-nix";
   sops-nix.inputs.nixpkgs.follows = "nixpkgs";
   nix-genymotion.url = "github:fillon/nix-genymotion";
   nix-genymotion.inputs.nixpkgs.follows = "nixpkgs";
 };

 outputs = inputs @ {self, ...}:
   inputs.flake-parts.lib.mkFlake {inherit inputs;} {
     systems = ["x86_64-linux" "aarch64-darwin" "x86_64-darwin"];
     imports = [
       inputs.nixos-flake.flakeModule
     ];
     flake = let
       myUserName = "felipemarcelino";
       nubankUserName = "felipe.marcelino";
     in {
       nixosConfigurations = {
         solid = self.nixos-flake.lib.mkLinuxSystem {
           nixpkgs.hostPlatform = "x86_64-linux";
           imports = [
             self.nixosModules.common
             self.nixosModules.linux
             self.nixosModules.home-manager
             self.nixosModules.nixvimNixos
             self.nixosModules.diskoNixos
             self.nixosModules.nix-genymotion

             #self.nixosModules.sops
             {
               home-manager.users.${myUserName} = {
                 imports = [
                   self.homeModules.common
                   self.homeModules.linux
                   self.homeModules.nixvimHome
                   self.homeModules.sopsHome
                 ];
                 home.stateVersion = "23.11";
               };
             }
           ];
         };
       };
       darwinConfigurations = {
         felipe = self.nixos-flake.lib.mkMacosSystem {
           nixpkgs.hostPlatform = "aarch64-darwin";
           imports = [
             self.nixosModules.common
             self.nixosModules.darwin
             self.nixosModules.nixvimDarwin
             self.darwinModules_.home-manager
             {
               home-manager.users.${nubankUserName} = {
                 imports = [
                   self.homeModules.common
                   self.homeModules.darwin
                   self.homeModules.nixvimHome
                   self.homeModules.sopsHome
                 ];
                 home.stateVersion = "23.11";
               };
             }
           ];
         };
       };
       nixosModules = {
         linux = import ./linux/solid/system/configuration.nix;
         nixvimNixos = inputs.nixvim.nixosModules.nixvim;
         nixvimDarwin = inputs.nixvim.nixDarwinModules.nixvim;
         diskoNixos = inputs.disko.nixosModules.disko;
         darwin = import ./macos/nubank/system/configuration.nix;
         common = import ./common/system/configuration.nix;
         sops = inputs.sops-nix.nixosModules.sops;
         nix-genymotion = {pkgs, ...}: {
           environment.systemPackages = with pkgs; [
             inputs.nix-genymotion.packages.x86_64-linux.default
           ];
         };
       };
       homeModules = {
         common = import ./common/home/default.nix;
         linux = import ./linux/solid/home/default.nix;
         nixvimHome = inputs.nixvim.homeManagerModules.nixvim;
         darwin = import ./macos/nubank/home/default.nix;
         sopsHome = inputs.sops-nix.homeManagerModules.sops;
         nix-genymotion = inputs.nix-genymotion.packages.x86_64-linux.default;
       };
     };
   };
}

[srid]

This project got renamed (#77). It is now self.nixos-unified (rather than self.nixos-flake).

You can see this in the example,

nixos-unified/examples/macos/flake.nix

Line 26 in e60e648

self.nixos-unified.lib.mkMacosSystem