A simple example with lots of comments

[btsimonh]

I was frustrated by not easily finding Berry examples, and then found the discussion thread and hence to this repo.

So below is my first Berry script, which illustrates some of the simplest functions in use

Maybe enable the wiki on this repo, and encourage people to contribute there - easier than forking and PRing.

I found this example useful in understanding some of the basics.

###Things to highlight:

Repeatedly running code in the berry console is cumulative - especially and obviously adding tas rules :).
At least when developing, best to remove then add.... else you end up restarting a lot.

It's not obvious that the function added with add_cmd should end with a tas response to be sent (e.g. tasmota.resp_cmnd_done() ).
Else I got a cryptic error BRY: ERROR, bad json: OFF

# A simple Berry example.
# Operates an automatic pet feeder (an old CAT feeder)
# the purpose here is to respond to a commmand 'feed n'
# if n > 0, then a motor is started, and a counter set to n
# every time switch1 transitions to ON, a counter is decremented.
# when the counter reaches zero, the motor is turned off.
# in my case, I've used a spare hbridge to provide the motor drive, so setup relay1, relay2 as the hbridge controls.
# I've set switch1 as the switch operated by the feeder deliveing one portion of food.
# note the setting of swicth options from berry.
# note the REMOVAL of rules and cmnd before adding.

import json
import string
#import mqtt
#import persist

# define relays for motor hbridge
var forward = 0
var backward = 1

# a variable to count how many portions we have fed this time
var portion_counter = 0

def feed(val)
  if val
    # turn motor forwards if val != 0
    tasmota.set_power(forward,true)
    tasmota.set_power(backward,false)
    portion_counter = val
    print("feed", val)
  else
    # turn off motor
    tasmota.set_power(forward,false)
    tasmota.set_power(backward,false)
  end
end

# this is called by using 'feed' in tas.
# note that it needs to respond... else you get a cryptic 'BRY: ERROR, bad json: OFF'
def feed_cmnd(cmd, idx, payload)
  print("cmnd from tas:",cmd, idx, payload)
  feed(int(payload))
  tasmota.resp_cmnd_done()
end

# example of direct mqtt - we will just use a cmnd
# hence not tested.
#def feed_message(topic, idx, payload_s, payload_b)
#	var feed_msg = json.load(payload_s)
#  
# 	if feed_msg['state'] == "start"
#    feed(4)
#  else
#  end
#end
#def subscribes()
#  mqtt.subscribe("cmnd/feed/control",water_message)
#end
#tasmota.remove_rule("MQTT#Connected=1")
#tasmota.add_rule("MQTT#Connected=1", subscribes)


# this will be called from a rule in tas
def buttonTriggered()
  portion_counter = portion_counter - 1
  print("Switch activated")

  if portion_counter <= 0
    feed(0)
  end
end

# set switch 1 to report state, not toggle
tasmota.cmd("SwitchMode1 1");
# disconnect switches from relays
tasmota.cmd("SetOption114 1");

# note:
# if using the tas berry console, best to remove the rules first.
# because the old ones remain, and berry gets called multiple times.
# call our function every time the switch report on
tasmota.remove_rule("Switch1#State=1")
tasmota.add_rule("Switch1#State=1", buttonTriggered)

# our feed command - use like "feed 4" to feed a 4 portion meal.
tasmota.remove_cmd('feed')
tasmota.add_cmd('feed', / cmd, idx, payload -> feed_cmnd(cmd, idx, payload))

[btsimonh]

And to add some very simple UI.

Note the use of global.xxx to check if the driver already was present, and remove it. This allows the driver to be replaced, and so this code can be pasted many times into the berry console without a restart.

# simple UI for calling tas commands.
# note that when pasting into the berry console, you do not need to restart 
# between runs.. because I found a way to remove the driver...

import webserver # import webserver class

class MyButtonMethods

  #- create a method for adding a button to the main menu -#
  def web_add_main_button()
    webserver.content_send("<p></p><button onclick='la(\"&m_feed=1\");'>Feed 1</button>")
    webserver.content_send("<p></p><button onclick='la(\"&m_feed=4\");'>Feed 4</button>")
  end

  #- As we can add only one sensor method we will have to combine them besides all other sensor readings in one method -#
  def web_sensor()
    # if it was our UI button pressed
    if webserver.has_arg("m_feed")
      print("ui button pressed")
      # and now read the value of the arg
      var val = webserver.arg("m_feed");
      var cmd = "feed "+val;
      tasmota.cmd(cmd);
    end
  end
end

# if this is second run, remove the existing driver.
# when using global.xxx it does not throw syntax error if xxx does not exist.
if global.d1
  print("removing existing driver")
  tasmota.remove_driver(global.d1)
else
  # do nothing - normal first run
  print("first run, no driver to remove")
end
  
# note that here we are creating or replacing the global d1 variable
d1 = MyButtonMethods()
tasmota.add_driver(d1)
print("driver added")

[dkebler]

thanks for sharing. I've asked to have the discussion turned on for this repo. With discussion folks can do a post like this that then can be linked from the readme. Until then using issues works. I have going on several hundred SLOC in berry of which I haven't shared a line which is making you look like a hero and me a jerk. As I commented in that other issue I have a dev environment which may help with your dev cycle (coding pain). arendst/Tasmota#17490 (comment)

[Jason2866]

Discussions opened

[btsimonh]

@dkebler - ref the coding environment, note the code above can be run again and again without a reboot :). That was the first thing I HAD to solve when pasting stuff into the berry console, and finding myself continually forgetting to reboot.
Is you node based coding env available as a repo?

[btsimonh]

@dkebler "me a jerk" - haha, absolutely not. None of us are being paid here, and I dip in and out every 2 years or so, throw in a load of shit, and then dissappear completely (then it takes me 6 hours to get my build env going again!!!). Blame me for several (I feel nice) additions, including new BLE and 'new' Tuya!... but they are not great if people don't get a good understanding.
(I did notice someone had build a very complex BLE implementation in Berry on top of my BLE driver! - I actually felt proud of my months and months of toil at that point!...)
p.s. I do always read mails from github, so if anyone needs me, just @btsimonh and I'll be back... (which they did NOT do when disabling the 'new' Tuya, claiming 'not maintained'. Nobody told me there was any issue... bahh.)

Looking forward to discussion!