Thanos Query expand args

[dminca]

Hi, how can I expand this

kube-thanos/jsonnet/kube-thanos/kube-thanos-query.libsonnet

Line 125 in 6fedb04

args:

to add more args? I'm not that experienced with jsonnet currently 😅

[dminca]

I think I got it working

local commonConfig = {
  config+:: {
    local cfg = self,
    namespace: 'thanos',
    version: 'v0.31.0',
    image: 'harbor.proxy/quay.io/thanos/thanos:' + cfg.version,
    imagePullPolicy: 'IfNotPresent',
    logFormat: 'json',
    objectStorageConfig: {
      name: 'thanos-objectstorage',
      key: 'thanos.yaml',
    },
    hashringConfigMapName: 'hashring-config',
    volumeClaimTemplate: {
      spec: {
        accessModes: ['ReadWriteOnce'],
        resources: {
          requests: {
            storage: '10Gi',
          },
        },
      },
    },
  },
};

local q = t.query(commonConfig.config {
  replicas: 1,
  replicaLabels: ['prometheus_replica', 'rule_replica'],
  serviceMonitor: true,
  stores: [s.storeEndpoint] + i.storeEndpoints,
});

local qa = q {
  deployment+: {
    spec+: {
      template+: {
        spec+: {
          containers: [
            if container.name == 'thanos-query' then
              container {
                args+: [
                  '--foo',
                  '--bar'
                ]
              }
            else container
            for container in super.containers
          ]
        }
      }
    }
  }
};