build.gradle

plugins {
    id 'java'
    id 'idea'
    id 'net.minecraftforge.gradle' version '[6.0,6.2)'
    id 'org.spongepowered.mixin' version '0.7.+'
    id 'org.parchmentmc.librarian.forgegradle' version '1.+'
}

version = "${mcversion}-v${modversion}"

base {
    archivesName = modid
    targetCompatibility = JavaVersion.VERSION_17
    sourceCompatibility = JavaVersion.VERSION_17
}

minecraft {
    mappings channel: "${mappingsch}", version: "${mappings_version}-${mcversion}"
    accessTransformer = file('src/main/resources/META-INF/accesstransformer.cfg')
    copyIdeResources = true
    runs {
        configureEach {
            workingDirectory file('run')
            arg "-mixin.config=${modid}.${mixin_file_suffix}"
            property 'forge.logging.markers', 'REGISTRIES'
            property 'forge.logging.console.level', 'debug'
            property 'terminal.jline', 'true'
            mods {
                "${modid}" {
                    source sourceSets.main
                }
            }
        }

        client {
            taskName "runClient"
        }
    }
}

repositories {
    mavenCentral()
    maven { url "https://repo.spongepowered.org/maven" }
    maven { url "https://maven.fabricmc.net/" }
    maven { url "https://maven.tterrag.com/" }
    maven { url "https://maven.blamejared.com" }
    maven {
        url 'https://www.cursemaven.com'
        content {
            includeGroup 'curse.maven'
        }
    }
}

dependencies {
    minecraft "net.minecraftforge:forge:${mcversion}-${fgversion}"

    // MIXINS
    annotationProcessor "net.fabricmc:sponge-mixin:0.12.5+mixin.0.8.5"
    compileOnly(annotationProcessor("io.github.llamalad7:mixinextras-common:0.3.5"))
    implementation(jarJar("io.github.llamalad7:mixinextras-forge:0.3.5")) {
        jarJar.ranged(it, "[0.3.5,)")
    }

    // DEPENDENCIES
    implementation fg.deobf("org.embeddedt:embeddium-${mcversion}:${embeddiumversion}")
    implementation fg.deobf("curse.maven:jei-238222:${jeiversion}")
    runtimeOnly fg.deobf("curse.maven:textrues-embeddium-options-910506:${embeddiumoptionsversion}")
    runtimeOnly fg.deobf("curse.maven:oculus-581495:${oculusversion}")

    // MOD SUPPORT
    implementation fg.deobf("com.simibubi.create:create-${mcversion}:${createversion}:slim") { transitive = false }
    implementation fg.deobf("com.jozufozu.flywheel:flywheel-forge-${mcversion}:${flywheelversion}")
    implementation fg.deobf("com.tterrag.registrate:Registrate:${registrateversion}")

    // UTILITY
    runtimeOnly fg.deobf("curse.maven:worldedit-225608:${worldeditversion}")
}

mixin {
    add sourceSets.main, "${modid}.${mixin_refmap_suffix}"
    config("${modid}.${mixin_file_suffix}")
}

jar {
    archiveClassifier = 'ignore'
    manifest {
        attributes([
                "Specification-Title": modid,
                "Specification-Vendor": modauthor,
                "Specification-Version": modversion,
                "Implementation-Title": modname,
                "Implementation-Version": modversion,
                "Implementation-Vendor" : modauthor,
                "Implementation-Timestamp": new Date().format("yyyy-MM-dd'T'HH:mm:ssZ"),
                "MixinConfigs": "${modid}.${mixin_file_suffix}"
        ])
    }
}

jarJar.enable()

tasks.jarJar.finalizedBy('reobfJarJar')
tasks.jarJar.archiveClassifier = ''

// Process target resources with mod info
tasks.processResources.outputs.upToDateWhen { false }
processResources {
    filesMatching(['META-INF/mods.toml', 'pack.mcmeta']) {
        expand(rootProject.properties)
    }
}

jar.finalizedBy('reobfJar')
tasks.withType(JavaCompile).configureEach {
    it.options.encoding = 'UTF-8'
}