SHA256.jl

const k = [0x428a2f98, 0x71374491, 0xb5c0fbcf, 0xe9b5dba5, 0x3956c25b, 0x59f111f1, 0x923f82a4, 0xab1c5ed5,
           0xd807aa98, 0x12835b01, 0x243185be, 0x550c7dc3, 0x72be5d74, 0x80deb1fe, 0x9bdc06a7, 0xc19bf174,
           0xe49b69c1, 0xefbe4786, 0x0fc19dc6, 0x240ca1cc, 0x2de92c6f, 0x4a7484aa, 0x5cb0a9dc, 0x76f988da,
           0x983e5152, 0xa831c66d, 0xb00327c8, 0xbf597fc7, 0xc6e00bf3, 0xd5a79147, 0x06ca6351, 0x14292967,
           0x27b70a85, 0x2e1b2138, 0x4d2c6dfc, 0x53380d13, 0x650a7354, 0x766a0abb, 0x81c2c92e, 0x92722c85,
           0xa2bfe8a1, 0xa81a664b, 0xc24b8b70, 0xc76c51a3, 0xd192e819, 0xd6990624, 0xf40e3585, 0x106aa070,
           0x19a4c116, 0x1e376c08, 0x2748774c, 0x34b0bcb5, 0x391c0cb3, 0x4ed8aa4a, 0x5b9cca4f, 0x682e6ff3,
           0x748f82ee, 0x78a5636f, 0x84c87814, 0x8cc70208, 0x90befffa, 0xa4506ceb, 0xbef9a3f7, 0xc67178f2]

function sha256(message::Vector{<:Unsigned})
    bits = vcat(digits!.(BitVector.(undef, Int.(8sizeof.(message))), message, base=2)...)
    L = length(bits)
    push!(bits, true)
    append!(bits, falses(-rem(length(bits) + 64, 512, RoundUp)))
    append!(bits, reverse!(digits!(BitVector(undef, 64), L, base=2)))
    message32 = reinterpret(UInt32, bits.chunks)

    # Initialize hash values:
    hash = eltype(message32)[0x6a09e667,
                             0xbb67ae85,
                             0x3c6ef372,
                             0xa54ff53a,
                             0x510e527f,
                             0x9b05688c,
                             0x1f83d9ab,
                             0x5be0cd19]

    # Create message schedule array:
    w = similar(hash, 64)

    for block in Iterators.partition(eachindex(message32), 16)
        w[1:16] = message32[block]
        for i = 17:64
            s0 = bitrotate(w[i-15],  -7) ⊻ bitrotate(w[i-15], -18) ⊻ (w[i-15] >>  3)
            s1 = bitrotate(w[i- 2], -17) ⊻ bitrotate(w[i- 2], -19) ⊻ (w[i- 2] >> 10)
            w[i] = w[i-16] + s0 + w[i-7] + s1
        end

        # Initialize working variables to current hash value:
        a, b, c, d, e, f, g, h = hash

        for i = 1:64
            S1 = bitrotate(e, -6) ⊻ bitrotate(e, -11) ⊻ bitrotate(e, -25)
            ch = (e & f) ⊻ (~e & g)
            @inbounds temp1 = h + S1 + ch + k[i] + w[i]
            S0 = bitrotate(a, -2) ⊻ bitrotate(a, -13) ⊻ bitrotate(a, -22)
            maj = (a & b) ⊻ (a & c) ⊻ (b & c)
            temp2 = S0 + maj

            h = g
            g = f
            f = e
            e = d + temp1
            d = c
            c = b
            b = a
            a = temp1 + temp2
        end

        hash .+= a, b, c, d, e, f, g, h
    end

    return hash
end
sha256(message::String) = sha256(Vector{UInt8}(message))