-
Notifications
You must be signed in to change notification settings - Fork 2
/
utils.pas
420 lines (347 loc) · 11.7 KB
/
utils.pas
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
unit Utils;
interface
uses
Classes, SysUtils, ThdTimer;
type
TQueuePolicy = ( QPNone, QPWait );
{ The Byte Pump is a FIFO queue, which can be chained with another two queues, }
{ in a sink-source fashion: }
{ - when data is dequeued from a sink, it will pull more from its source }
{ - when data is enqueued to a source, it cause the sink to pull data }
{ when and how much of the push / pull is done, depends on queue control mode: }
{ - QPNone: propagate immediately }
{ - QPWait: sink is only filled when sink it gets emptied, after an }
{ optional delay }
{ when no sink or source is defined, it works like a regular, single FIFO queue }
TBytePump = class
private
{ temporary buffer for pumping data }
Pipe: Array of byte;
{ ring buffer }
Data : Array of byte;
{ cogs }
FCapacity: Integer;
FCount: Integer;
FLeft: Integer;
ReadPos: Integer;
WritePos: Integer;
FFillLevel: Integer;
FSource: TBytePump;
FSink: TBytePump;
FDelay: Integer;
FReady: Boolean;
Waiting: Boolean;
Timer: TThreadedTimer;
WakeUpTimer: TTHreadedTimer;
procedure SetFillLevel(l: integer);
procedure SetDelay(d: integer);
procedure SetQueuePolicy(qp: TQueuePolicy);
{ the actual moving of data, but without pumping }
function FEnqueue(var src: array of byte; len: Integer): Integer;
function FDequeue(var dst: array of byte; len: Integer): Integer;
{ pump from source }
procedure Pump;
procedure OnTimer(Sender: TObject);
procedure OnWakeUpTimer(Sender: TObject);
public
FQueuePolicy: TQueuePolicy;
OnReady: TNotifyEvent;
Name: String;
procedure Flush;
procedure Purge;
{ move data and trigger a chain of pump actions }
function Enqueue(var src: array of byte; len: Integer): Integer;
function Dequeue(var dst: array of byte; len: Integer): Integer;
procedure Source(src: TBytePump);
procedure Sink(snk: TBytePump);
procedure BreakSource;
procedure BreakSink;
procedure Unplumb;
property Capacity: Integer read FCapacity;
property Count: Integer read FCount;
property Left: Integer read FLeft;
property QueuePolicy: TQueuePolicy read FQueuePolicy write SetQueuePolicy;
property FillLevel: Integer read FFillLevel write SetFillLevel;
property Delay: Integer read FDelay write SetDelay;
property Ready: Boolean read FReady;
constructor Create(Capacity: Integer);
destructor Destroy; override;
end;
procedure LinkPumps(Source: TBytePump; Sink: TBytePump);
procedure UnlinkPumps(a: TBytePump; b: TBytePump);
implementation
procedure LinkPumps(Source: TBytePump; Sink: TBytePump);
begin
{ do not allow a closed loop - TODO: walk the whole pipage and detect loops }
if Sink = Source then exit;
Source.FSink := Sink;
Sink.FSource := Source;
end;
{ detach two pumps if they are connected, in whichever way }
procedure UnlinkPumps(a: TBytePump; b: TBytePump);
begin
if (a.FSource = b) and (b.FSink = a)
then begin
a.FSource := Nil;
b.FSink := Nil;
end;
if (a.FSink = b) and (b.FSource = a)
then begin
a.FSink := Nil;
b.FSource := Nil;
end;
end;
constructor TBytePump.Create(Capacity: Integer);
begin
FCapacity := 0;
if Capacity <= 0 then exit;
SetLength(Data, Capacity);
SetLength(Pipe, Capacity);
FCapacity := Capacity;
ReadPos := 0;
WritePos := 0;
FCount := 0;
FLeft := Capacity;
FFillLevel := Capacity;
FSource := Nil;
FSink := Nil;
Waiting := False;
FReady := True;
FQueuePolicy := QPNone;
Timer := TThreadedTimer.Create(nil);
Timer.Interval := 1;
WakeUpTimer := TThreadedTimer.Create(nil);
WakeUpTimer.Interval := 1;
FDelay := 0;
Timer.Enabled := False;
WakeUpTimer.Enabled := False;
Timer.OnTimer := OnTimer;
WakeUpTimer.OnTimer := OnWakeUpTimer;
end;
destructor TBytePump.Destroy;
begin
Timer.Enabled := False;
WakeUpTimer.Enabled := False;
Unplumb;
end;
procedure TBytePump.SetQueuePolicy(qp: TQueuePolicy);
begin
if FQueuePolicy = qp then exit;
if qp = QPNone then
begin
SetLength(Pipe, FCapacity);
end else
begin
SetLength(Pipe, FFillLevel);
end;
FQueuePolicy := qp;
end;
procedure TBytePump.SetFillLevel(l: Integer);
begin
if l < 0 then l := FCapacity;
if l <= FCapacity then FFillLevel := l
else FFillLevel := FCapacity;
SetLength(Pipe, FFillLevel);
end;
procedure TBytePump.OnTimer(Sender: TObject);
begin
Timer.Enabled := False;
FReady := True;
Pump;
if assigned(OnReady) then OnReady(Self);
end;
procedure TBytePump.OnWakeUpTimer(Sender: TObject);
begin
WakeUpTimer.Enabled := False;
if assigned(OnReady) then OnReady(Self);
end;
procedure TBytePump.SetDelay(d: Integer);
begin
if d > 0 then
begin
FDelay := d;
Timer.Interval := Delay;
WakeUpTimer.Interval := Delay;
end else FDelay := 0;
end;
{ flush this queue }
procedure TBytePump.Flush;
begin
ReadPos := 0;
WritePos := 0;
FCount := 0;
FLeft := FCapacity;
Waiting := False;
FReady := True;
end;
{ flush this queue and chain flush downwards }
procedure TBytePump.Purge;
begin
Flush;
if assigned(FSink) then FSink.Purge;
end;
procedure TBytePump.Source(src: TBytePump);
begin
FSource := src;
if assigned(FSource) then FSource.FSink := Self;
end;
procedure TBytePump.Sink(snk: TBytePump);
begin
FSink := snk;
if assigned(FSink) then FSink.FSource := Self;
end;
{ break linkage towards sink }
procedure TBytePump.BreakSink;
begin
if assigned(FSink) then
begin
FSink.FSource := Nil;
end;
FSink := Nil;
end;
{ break linkage towards source }
procedure TBytePump.BreakSource;
begin
if assigned(FSource) then
begin
FSource.FSink := Nil;
end;
FSource := Nil;
end;
{ breake linkage in both directions but fuse them together }
procedure TBytePump.Unplumb;
begin
if assigned(FSource) then
begin
if assigned(FSink) then FSource.FSink := FSink;
FSource := Nil;
end;
if assigned(FSink) then
begin
if assigned(FSource) then FSink.FSource := FSource;
FSink := Nil;
end;
end;
{ pull data from source if ready }
procedure TBytePump.Pump;
var
FillLeft,len: integer;
begin
if not assigned(FSource) or (FLeft < 1) then exit;
case FQueuePolicy of
{ Wait: only pull more data through the pipe if we're ready }
QPWait: begin
FillLeft := FFillLevel - FCount;
if FillLeft < 1 then FillLeft := 0;
if Ready and (FillLeft > 0) then begin
len := FSource.Dequeue(Pipe, FillLeft);
if len > 0 then Enqueue(Pipe, len);
end;
end;
{ None: always attempt to pull data from source }
QPNone: begin
len := FSource.Dequeue(Pipe, FLeft);
if len > 0 then Enqueue(Pipe, len);
end;
end;
end;
{ enqueue data }
function TBytePump.FEnqueue(var src: array of byte; len: Integer): Integer;
var
toEnd: Integer;
begin
Result := 0;
if len < 1 then exit;
if (FQueuePolicy = QPWait) and (not Ready) then exit;
{ no space left }
if FLeft <= 0 then exit;
{ some space left but not enough - only enqueue what we can }
if FLeft < len then len := FLeft;
{ only fill up to fill level, no more }
if FQueuePolicy = QPWait then
begin
if ((len + FCount) >= FFillLevel) then len := FFillLevel - FCount;
{ queue fill level reached }
if len <= 0 then
begin
if assigned(OnReady) then OnReady(Self);
exit;
end;
end;
toEnd := FCapacity - WritePos;
{ we can append to the end }
if len <= toEnd then
begin
Move(src[0], Data[WritePos], len);
end
{ we need to wrap around }
else begin
Move(src[0], Data[WritePos], toEnd);
Move(src[toEnd], Data[0], len - toEnd);
end;
Inc(WritePos, len);
WritePos := WritePos mod FCapacity;
Inc(FCount, len);
Dec(FLeft, len);
{ we reached our fill level - stop pumping notify }
if (FQueuePolicy = QPWait) and (FCount >= FFillLevel) then
begin
FReady := False;
WakeUpTimer.Enabled := True;
end;
if (len > 0) and Ready and assigned(OnReady) then OnReady(Self);
Result := len;
end;
{ public enqueue - enqueue and pump }
function TBytePump.Enqueue(var src: array of byte; len: Integer): Integer;
begin
Result := FEnqueue(src,len);
{ triger a data pump to sink }
if (Result > 0) and assigned(FSink) then FSink.Pump;
end;
{ dequeue some data }
function TBytePump.FDequeue(var dst: array of byte; len: Integer): Integer;
var
toEnd: Integer;
begin
Result := 0;
{ no data queued }
if FCount < 1 then exit;
{ some data queued but less than what we wanted - only dequeue what we can }
if len > FCount then len := FCount;
toEnd := FCapacity - ReadPos;
{ we can read to the end }
if len <= toEnd then
begin
Move(Data[ReadPos], dst[0], len);
end
{ we need to wrap around }
else begin
Move(Data[ReadPos], dst[0], toEnd);
Move(Data[0], dst[toEnd], len - toEnd);
end;
Inc(ReadPos, len);
ReadPos := ReadPos mod FCapacity;
Dec(FCount, len);
Inc(FLeft, len);
{ queue emptied - delay notification if delay specified }
if (FQueuePolicy = QPWait) and (FCount = 0) then
begin
if Delay > 0 then
begin
FReady := False;
Timer.Enabled := True
end else begin
FReady := True;
end;
end;
Result := len;
end;
{ public dequeue - dequeue and pump }
function TBytePump.Dequeue(var dst: array of byte; len: Integer): Integer;
begin
Result := FDequeue(dst, len);
{ pull from source }
if (Result > 0) and assigned(FSource) then Pump;
end;
end.