MS Access VBA

[Docent24]

Hi.
I try to use your cTlsSocket class as an replacement of std Winsock.ocx to communicate with Asterisk hardware from MS Access project. Everything works fine, "buuut": if i receive an event in opened connection WHILE there are modal dialogs on the screen (MsgBox, InputBox, etc) - then communication after that is not working. I see connection in netstat stated as "established", but i do not receive any new events within connection. After reconnection (close/open the connection) - it works again.
I have seen this behaivor when i used cAsyncSocket class in the project, and using WinsockTls.ocx has not made any change here.

I know that project has not been meant to be used with VBA, but it is such a great project for VBA world and there are no good alternatives out there. Maybe, something can be done here.

P.S. Standard Winsock.ocx works fine, but have another issues and not supported and distributed by MS.

[wqweto]

I just recompiled WinsockTls.zip from current sources and bumped the OCX to latest version (1.0.4).

You can check out if the binary under 1.0.4 release fails the same.

[Docent24]

Thank you for the quick answer. I tried version 1.0.4, but no, no changes.
Other than that - it is very stable project, works like a charm in VBA. But, as you understand, that "modal dialog bug" ruined all the possibilities to use it in production. Hopes to replace Winsock.ocx was very high =)))

I hope, you will look into this one day.

Anyway, once again - huge thanks for your hard work! Keep it up! Cheers!

[wqweto]

Standard Winsock.ocx works fine

Btw, do you "receive an event in opened connection WHILE there are modal dialogs on the screen (MsgBox, InputBox, etc)" with Standard Winsock.ocx?

I don't have 32-bit office so I'm not asking for minimum reproduction project. I can only peek at a VB6 repro.

[wqweto]

Yes, I actually found a problem with Winsock replacement control: If you do not call GetData (or PeekData) in DataArrival event the underlying socket input buffer became full and it stops sending FD_READ notifications as the TCP connection became stalled so the Winsock control connection looks stalled too.

I've fixed this issue in 1.0.5 release so that the reproduction code below works ok now

'--- Form1
Option Explicit

Private Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" (Destination As Any, Source As Any, ByVal Length As Long)
Private Declare Function DeleteFile Lib "kernel32" Alias "DeleteFileW" (ByVal lpFileName As Long) As Long

Private Sub Form_Click()
    ctxWinsock1.Connect "dl.unicontsoft.com", 80
End Sub

Private Sub ctxWinsock1_Connect()
    Debug.Print "Connected to " & ctxWinsock1.RemoteHostIP, Timer
    ctxWinsock1.SendData "GET /upload/pix/ss_vbyoga_flex_container.gif HTTP/1.0" & vbCrLf & _
                         "Host: dl.unicontsoft.com" & vbCrLf & vbCrLf
End Sub

Private Sub ctxWinsock1_DataArrival(ByVal bytesTotal As Long)
    Debug.Print bytesTotal;
End Sub

Private Sub ctxWinsock1_CloseEvent()
    Dim baBuffer()      As Byte
    Dim lPos            As Long
    Dim sFile           As String
    
    ctxWinsock1.GetData baBuffer
    Debug.Print vbCrLf & "Download completed " & UBound(baBuffer) + 1, Timer
    lPos = InStrB(1, baBuffer, StrConv(vbCrLf & vbCrLf, vbFromUnicode)) + 3
    If lPos > 3 Then
        Call CopyMemory(baBuffer(0), baBuffer(lPos), UBound(baBuffer) - lPos + 1)
        ReDim Preserve baBuffer(0 To UBound(baBuffer) - lPos) As Byte
    End If
    sFile = Environ$("TEMP") & "\aaa.gif"
    Call DeleteFile(StrPtr(sFile))
    WriteBinaryFile sFile, baBuffer
    Shell "cmd /c " & sFile
End Sub

Public Sub WriteBinaryFile(sFile As String, baBuffer() As Byte)
    Dim nFile           As Integer
    
    nFile = FreeFile
    Open sFile For Binary Access Write Shared As nFile
    If UBound(baBuffer) >= 0 Then
        Put nFile, , baBuffer
    End If
    Close nFile
End Sub

The sample is contrived so no data is fetched in ctxWinsock1_DataArrival up until ctxWinsock1_CloseEvent when all of the recv buffer is retrieved and saved to a file.

Thanks for the bug report!

[Docent24]

Oh, it works now! Now "that's what I call a replacement" for WinsockControl for VBA too!

Many thanks, Vladimir! And thumbs up for the speedy fix!