Merge branch 'release-1.3.0'

Author: kopischke

autoload/stay.vim

@@ -34,10 +34,33 @@ endfunction
 " Check if {fname} is in a 'backupskip' location:
 " @signature:  stay#istemp({fname:String})
 " @returns:    Boolean
-function! stay#istemp(path) abort
-  let l:candidates = stay#shim#globpath(&backupskip, '**/'.fnamemodify(a:path, ':t'), 1, 1)
-  return index(l:candidates, a:path) isnot -1
-endfunction
+if exists('glob2regpat') " fastest option, Vim 7.4 with patch 668 only
+  function! stay#istemp(path) abort
+    for l:tempdir in split(&backupskip, '\m[^\\]\%(\\\\\)*,')
+      if a:path =~# glob2regpat(l:tempdir)
+        return 1
+      endif
+    endfor
+    return 0
+  endfunction
+elseif has('wildignore') " ~ slower by x 1.75
+  function! stay#istemp(path) abort
+    let l:wildignore = &wildignore
+    try
+      let &wildignore = &backupskip
+      return empty(expand(a:path))
+    finally
+      let &wildignore = l:wildignore
+    endtry
+  endfunction
+else
+  " assume Vim builds without |+wildignore| are performance constrained,
+  " which makes using |globpath()| filtering on 'backupskip' a non-option
+  " (it's about a 100 times slower than the 'wildignore' / |expand()| hack)
+  function! stay#istemp(path) abort
+    return -1
+  endfunction
+endif
 
 " Check if one of {bufnr}'s 'filetype' parts is on the {ftypes} List:
 " @signature:  stay#isftype({bufnr:Number}, {ftypes:List<String>})

autoload/stay/view.vim

@@ -19,11 +19,14 @@ function! stay#view#make(winnr) abort
     endif
     unlet! b:stay_atpos
     call s:doautocmd('User', 'BufStaySavePre')
+    let l:dopost = 1
     mkview
-    call s:doautocmd('User', 'BufStaySavePost')
-    call s:win.back()
     return 1
   finally
+    if get(l:, 'dopost', 0) is 1
+      call s:doautocmd('User', 'BufStaySavePost')
+    endif
+    call s:win.back()
     let &lazyredraw = l:lazyredraw
   endtry
 endfunction
@@ -37,20 +40,30 @@ function! stay#view#load(winnr) abort
   endif
 
   call s:doautocmd('User', 'BufStayLoadPre')
-  try   " significantly slows down buffer loads without noautocmd
-    noautocmd silent loadview
+  " the `doautoall SessionLoadPost` in view session files significantly
+  " slows down buffer load, hence we suppress it...
+  let l:eventignore = &eventignore
+  set eventignore+=SessionLoadPost
+  try
+    silent loadview
+    " ... then fire it in a more targeted way
+    if exists('b:stay_loaded_view')
+      let &eventignore = l:eventignore
+      call s:doautocmd('SessionLoadPost')
+    endif
+    " respect position set by other scripts / plug-ins
+    if exists('b:stay_atpos')
+      call cursor(b:stay_atpos[0], b:stay_atpos[1])
+      silent! normal! zOzz
+    endif
+    return 1
   catch " silently return on errors
     return 0
+  finally
+    let &eventignore = l:eventignore
+    call s:doautocmd('User', 'BufStayLoadPost')
+    call s:win.back()
   endtry
-  call s:doautocmd('User', 'BufStayLoadPost')
-  call s:doautocmd('SessionLoadPost')
-
-  if exists('b:stay_atpos')
-    call cursor(b:stay_atpos[0], b:stay_atpos[1])
-    silent! normal! zOzz
-  endif
-  call s:win.back()
-  return 1
 endfunction
 
 " Private helper functions: {{{

doc/vim-stay.txt

@@ -1,4 +1,4 @@
-*vim-stay.txt*        For Vim version 7.0 or better          version 1.2.0
+*vim-stay.txt*        For Vim version 7.0 or better          version 1.3.0
 
 
 		VIM REFERENCE for the Stay plug-in
@@ -9,9 +9,10 @@ Never lose your place in a buffer again	    	*vim-stay*
 1. Introduction				|vim-stay-introduction|
 2. Configuration			|vim-stay-configuration|
 3. Commands				|vim-stay-commands|
-4. Position specifications		|vim-stay-integration|
-5. Troubleshooting			|vim-stay-troubleshooting|
-6. Credits and license			|vim-stay-credits-license|
+4. Variables				|vim-stay-variables|
+5. Position specifications		|vim-stay-integration|
+6. Troubleshooting			|vim-stay-troubleshooting|
+7. Credits and license			|vim-stay-credits-license|
 
 {not available when |'compatible'| is set, or when Vim is compiled without
 |+autocmd| or without |+mksession|}
@@ -73,7 +74,15 @@ you need to add file types to it, make sure the plug-in has loaded, then do
 		|g:volatile_ftypes|) to the plug-in defaults.
 
 ==============================================================================
-4. Integration					*vim-stay-integration*
+4. Variables					*vim-stay-variables*
+
+
+b:stay_loaded_view
+		Full path to the view session file last loaded for the current
+		buffer by vim-stay.
+
+==============================================================================
+5. Integration					*vim-stay-integration*
 
 
 INTEGRATION WITH 3RD PARTY PLUG-INS:
@@ -139,7 +148,7 @@ The advantage over hard-wiring support for vim-stay in your plug-in is that
 - the integration code will only be active if your user actually uses vim-stay.
 
 ==============================================================================
-5. Troubleshooting				*vim-stay-troubleshooting*
+6. Troubleshooting				*vim-stay-troubleshooting*
 
 
 MY CURSOR POSITION IS NOT PERSISTED
@@ -178,12 +187,15 @@ recommended setting under |vim-stay-viewoptions|.
 VIM-STAY TRIES TO PERSIST STATE FOR TEMPORARY FILES
 
 - If the files are in a standard system temporary location, you should check
-  if it listed in 'backupskip' - vim-stray will ignore files in the hierarchy
+  if it listed in 'backupskip' - vim-stay will ignore files in the hierarchy
   of directories listed there.
 - Files in a temporary or cache directory not listed in 'backupskip' are not
   recognized as volatile, unless their 'buftype' is set to a non-file type.
   You can alleviate the issue by setting |b:stay_ignore| in affected buffers.
 
+Note: for performance reasons, 'backupskip' checking is skipped if Vim is
+compiled without |+wildignore| and |glob2regpat()| is not available.
+
 
 VIM-STAY TRIES TO PERSIST STATE FOR OTHER VOLATILE FILES
 
@@ -211,7 +223,7 @@ Please do not forget to list the steps to reproduce the issue as well as your
 Vim version and platform.
 
 ==============================================================================
-6. Credits and License			*vim-stay-credits-license*
+7. Credits and License			*vim-stay-credits-license*
 
 vim-stay is maintained by Martin Kopischke
 

plugin/stay.vim

@@ -1,7 +1,7 @@
 " A LESS SIMPLISTIC TAKE ON RESTORE_VIEW.VIM
 " Maintainer: Martin Kopischke <[email protected]>
 " License:    MIT (see LICENSE.md)
-" Version:    1.2.0
+" Version:    1.3.0
 if &compatible || !has('autocmd') || !has('mksession') || v:version < 700
   finish
 endif
@@ -49,12 +49,21 @@ function! s:setup(defaults) abort
   " - 'stay' autocommand group (also used by integrations)
   augroup stay
     autocmd!
+
+    " |v:this_session| is not set for view sessions, so we roll our own (ignored
+    " when 'viewdir' is empty or set to the current directory hierarchy, as that
+    " would catch every filed sourced from there, not just view session files)
+    autocmd SourcePre ?*
+          \ if &viewdir !~? '\v^$|^\.' && stridx(expand('<afile>'), &viewdir) is 0 |
+          \   let b:stay_loaded_view = expand('<afile>') |
+          \ endif
+
     " default buffer handling
-    autocmd BufLeave,BufWinLeave ?*
+    autocmd BufLeave,BufWinLeave ?* nested
           \ if stay#ispersistent(str2nr(expand('<abuf>')), g:volatile_ftypes) |
           \   call stay#view#make(bufwinnr(str2nr(expand('<abuf>')))) |
           \ endif
-    autocmd BufWinEnter ?*
+    autocmd BufWinEnter ?* nested
           \ if stay#ispersistent(str2nr(expand('<abuf>')), g:volatile_ftypes) |
           \   call stay#view#load(bufwinnr(str2nr(expand('<abuf>')))) |
           \ endif