Version locale

data/commun/functions/boucle.mcfunction

@@ -0,0 +1,9 @@
+
+
+
+# Fait en sorte que les joueurs aient leur grade quand il faut
+function commun:grades/protection/verification
+
+# Détecte un joueur qui se connecte ou se déconnecte
+function commun:connexion/nouveau_joueur/detection
+function commun:connexion/ancien_joueur/detection

data/commun/functions/connexion/ancien_joueur/detection.mcfunction

@@ -0,0 +1,19 @@
+#========================================
+# Mode de déclenchement :
+    # Tick
+
+# Déclencheurs :
+    # commun:boucle
+
+# Fonction du fichier :
+    # Détermine si un ancien joueur vient de se reconnecter et agit en conséquence.
+
+# Tags utilisés :
+    # ----
+#========================================
+
+
+
+execute as @a if score @s commun_LeaveGame matches 1.. run function commun:connexion/ancien_joueur/trigger
+
+scoreboard players set @a[scores={commun_LeaveGame=1..}] commun_LeaveGame 0

data/commun/functions/connexion/ancien_joueur/trigger.mcfunction

@@ -0,0 +1,26 @@
+#========================================
+# Mode de déclenchement :
+    # Event
+
+# Déclencheurs :
+    # commun:connexion/ancien_joueur/verification
+
+# Fonction du fichier :
+    # Execute ce qu'il faut à la connexion de l'ancien joueur
+
+# Tags utilisés :
+    # ----
+#========================================
+
+
+
+tellraw @a [{"text":"[","color":"gray"},{"text":"+","color":"green"},{"text":"] ","color":"gray"},{"selector":"@s"}]
+
+team leave @s
+
+tellraw @s [{"text":"Bonjour ","color":"blue"},{"selector":"@s","color":"gold"},{"text":" !","color":"blue"}]
+tellraw @s [{"text":"N'hésite pas à nous rejoindre sur ","color":"blue"},{"text":"le Discord","underlined":true,"color":"gold","clickEvent":{"action":"open_url","value":"https://discord.gg/vqRNfaC"}},{"text":" si ce n'est pas déjà fait !","color":"blue"}]
+
+function commun:grades/attribution
+
+execute as @a at @s run playsound minecraft:block.lava.pop master @s ~ ~ ~ 1 1.5

data/commun/functions/connexion/nouveau_joueur/detection.mcfunction

@@ -0,0 +1,21 @@
+#========================================
+# Mode de déclenchement :
+    # Tick
+
+# Déclencheurs :
+    # commun:boucle
+
+# Fonction du fichier :
+    # Détermine si un joueur se connecte pour la première fois sur le serveur.
+
+# Tags utilisés :
+    # ----
+#========================================
+
+
+
+# Détecte si un joueur est nouveau (= pas d'UUID) et l'initialise
+execute as @a unless score @s commun_UUID matches 1.. run function commun:connexion/nouveau_joueur/trigger
+
+# Détecte si un joueur à passé plus de 30 minutes (= 36000 ticks) sur le serveur
+execute as @a if score @s commun_TempsJeu matches 36000 run function commun:connexion/nouveau_joueur/plus_nouveau

data/commun/functions/connexion/nouveau_joueur/plus_nouveau.mcfunction

@@ -0,0 +1,24 @@
+#========================================
+# Mode de déclenchement :
+    # Event
+
+# Déclencheurs :
+    # commun:connexion/nouveau_joueur/detection
+
+# Fonction du fichier :
+    # Passe le nouveau joueur en tant que joueur normal.
+
+# Tags utilisés :
+    # ----
+#========================================
+
+
+
+# Attribution du nouveau grade
+scoreboard players set @s commun_Grade 1
+team join oJoueur
+
+# Message d'information
+tellraw @s {"text":"Vous avez joué 30 minutes, merci !"}
+
+# Mettre un bruit ou un advancement ?

data/commun/functions/connexion/nouveau_joueur/trigger.mcfunction

@@ -0,0 +1,42 @@
+#========================================
+# Mode de déclenchement :
+    # Event
+
+# Déclencheurs :
+    # commun:connexion/nouveau_joueur/detection
+
+# Fonction du fichier :
+    # Execute ce qu'il faut lors de la connexion d'un nouveau joueur.
+
+# Tags utilisés :
+    # ----
+#========================================
+
+
+
+# Set de l'UUID
+
+function commun:outils/uuid/attribution
+
+
+
+# Attribution du grade
+
+scoreboard players set @s commun_Grade 0
+team join pNouveau
+
+
+
+# Messages de bienvenue et d'information
+
+tellraw @a [{"text":"[","color":"gray"},{"text":"+","color":"green"},{"text":"] ","color":"gray"},{"selector":"@s"}]
+
+team leave @s
+
+tellraw @a [{"text":"C'est la première connexion de ","color":"green"},{"selector":"@s","color":"gold"},{"text":" sur Aycraft ! Bienvenue à toi !","color":"green"}]
+tellraw @s [{"text":"Tu peux naviguer sur le serveur facilement via un menu qui se trouve dans ton inventaire ! Presse "},{"keybind":"key.inventory"},{"text":" pour y accéder !"}]
+tellraw @s [{"text":"N'hésite pas à nous rejoindre sur ","color":"blue"},{"text":"le Discord","underlined":true,"color":"gold","clickEvent":{"action":"open_url","value":"https://discord.gg/vqRNfaC"}},{"text":" si ce n'est pas déjà fait !","color":"blue"}]
+
+team join pNouveau
+
+execute as @a at @s run playsound minecraft:ui.toast.challenge_complete master @s ~ ~ ~ 0.5 1.2

data/commun/functions/global_serveur/gamerules.mcfunction

@@ -0,0 +1,40 @@
+#========================================
+# Mode de déclenchement :
+    # Load
+
+# Déclencheurs :
+    # commun:initialisation
+
+# Fonction du fichier :
+    # Initialise les gamerules et le worldspawn aux bonnes valeurs
+
+# Tags utilisés :
+    # ----
+#========================================
+
+
+
+gamerule announceAdvancements false
+gamerule commandBlockOutput false
+gamerule disableElytraMovementCheck false
+gamerule doDaylightCycle false
+gamerule doEntityDrops true
+gamerule doFireTick false
+gamerule doLimitedCrafting true
+gamerule doMobLoot true
+gamerule doMobSpawning false
+gamerule doTileDrops true
+gamerule doWeatherCycle false
+gamerule keepInventory false
+gamerule logAdminCommands false
+gamerule maxCommandChainLength 1000000
+gamerule mobGriefing false
+gamerule naturalRegeneration true
+gamerule randomTickSpeed 3
+gamerule reducedDebugInfo false
+gamerule sendCommandFeedback true
+gamerule showDeathMessages false
+gamerule spawnRadius 0
+gamerule spectatorsGenerateChunks false
+
+setworldspawn 0 100 0

data/commun/functions/grades/attribution.mcfunction

@@ -0,0 +1,52 @@
+#========================================
+# Mode de déclenchement :
+    # Event
+
+# Déclencheurs :
+    # commun:grades/refresh
+	# commun:grades/protection/correction
+	# commun:connexion/ancien_joueur/trigger
+
+# Fonction du fichier :
+    # Attribution des grades aux joueurs.
+	# Plus le score commun_Grade est haut, plus le joueur est haut dans la hiérarchie.
+
+# Tags utilisés :
+    # ----
+#========================================
+
+
+
+# Staff
+
+team join aFondateur @s[scores={commun_Grade=15}]
+team join bAdministrateur @s[scores={commun_Grade=14}]
+team join cIngenieurChef @s[scores={commun_Grade=13}]
+team join dArchitecteChef @s[scores={commun_Grade=12}]
+team join eModerateur @s[scores={commun_Grade=11}]
+team join fIngenieur @s[scores={commun_Grade=10}]
+team join gArchitecte @s[scores={commun_Grade=9}]
+team join hAssistant @s[scores={commun_Grade=8}]
+team join iIngenieurTest @s[scores={commun_Grade=7}]
+team join jArchitecteTest @s[scores={commun_Grade=6}]
+
+
+
+# Membres à grades spéciaux
+
+team join kYoutubeur @s[scores={commun_Grade=5}]
+team join lAmi @s[scores={commun_Grade=4}]
+
+
+
+# Membres à grades payants
+
+team join mVIP+ @s[scores={commun_Grade=3}]
+team join nVIP @s[scores={commun_Grade=2}]
+
+
+
+# Grade de base
+
+team join oJoueur @s[scores={commun_Grade=1}]
+team join pNouveau @s[scores={commun_Grade=0}]

data/commun/functions/grades/creation.mcfunction

@@ -0,0 +1,93 @@
+#========================================
+# Mode de déclenchement :
+    # Load
+
+# Déclencheurs :
+    # commun:initialisation
+
+# Fonction du fichier :
+    # Création de tous les grades
+
+# Tags utilisés :
+    # ----
+#========================================
+
+
+
+# Staff
+
+	# Fondateur
+team add aFondateur
+team modify aFondateur prefix [{"text":"Fondateur","bold":true,"color":"gold"},{"text":" » ","color":"gray"}]
+
+	# Administrateur
+team add bAdministrateur
+team modify bAdministrateur prefix [{"text":"Administrateur","color":"dark_red"},{"text":" » ","color":"gray"}]
+
+	# Ingénieur Chef
+team add cIngenieurChef
+team modify cIngenieurChef prefix [{"text":"Chef Ingénieur","bold":true,"color":"dark_green"},{"text":" » ","color":"gray"}]
+
+	# Architecte Chef
+team add dArchitecteChef
+team modify dArchitecteChef prefix [{"text":"Chef Architecte","bold":true,"color":"dark_blue"},{"text":" » ","color":"gray"}]
+
+	# Modérateur
+team add eModerateur
+team modify eModerateur prefix [{"text":"Modérateur","color":"yellow"},{"text":" » ","color":"gray"}]
+
+	# Ingénieur
+team add fIngenieur
+team modify fIngenieur prefix [{"text":"Ingénieur","color":"dark_green"},{"text":" » ","color":"gray"}]
+
+	# Architecte
+team add gArchitecte
+team modify gArchitecte prefix [{"text":"Architecte","color":"dark_blue"},{"text":" » ","color":"gray"}]
+
+	# Assistant
+team add hAssistant
+team modify hAssistant prefix [{"text":"Assistant","color":"dark_purple"},{"text":" » ","color":"gray"}]
+
+	# Ingénieur Test
+team add iIngenieurTest
+team modify iIngenieurTest prefix [{"text":"Ingénieur Test","italic":true,"color":"dark_green"},{"text":" » ","color":"gray"}]
+
+	# Architecte Test
+team add jArchitecteTest
+team modify jArchitecteTest prefix [{"text":"Architecte Test","italic":true,"color":"dark_blue"},{"text":" » ","color":"gray"}]
+
+
+
+# Membres à grades spéciaux
+
+	# Youtubeur
+team add kYoutubeur
+team modify kYoutubeur prefix [{"text":"Youtubeur","color":"red"},{"text":" » ","color":"gray"}]
+
+	# Ami
+team add lAmi
+team modify lAmi prefix [{"text":"Ami","color":"light_purple"},{"text":" » ","color":"gray"}]
+
+
+
+# Membres à grades payants (€ ou Ay Coins)
+
+	# VIP+ (10€)
+team add mVIP+
+team modify mVIP+ prefix [{"text":"VIP","color":"dark_aqua"},{"text":"+","color":"gold"},{"text":" » ","color":"gray"}]
+
+	# VIP (5€)
+team add nVIP
+team modify nVIP prefix [{"text":"VIP","color":"dark_aqua"},{"text":" » ","color":"gray"}]
+
+
+
+# Grades de base
+
+	# Joueur
+team add oJoueur
+team modify oJoueur prefix [{"text":"Joueur » ","color":"gray"}]
+
+	# Nouveau
+team add pNouveau
+team modify pNouveau prefix [{"text":"Nouveau","color":"dark_gray"},{"text":" » ","color":"gray"}]

data/commun/functions/grades/protection/correction.mcfunction

@@ -0,0 +1,47 @@
+#========================================
+# Mode de déclenchement :
+    # Event
+
+# Déclencheurs :
+    # commun:grades/protection/verification
+
+# Fonction du fichier :
+    # Remet aux joueurs le score commun_Grade qu'ils devraient avoir
+	# Remet aux joueurs le grade qu'ils devraient avoir si besoin
+
+# Tags utilisés :
+    # commun_ABesoinGrade
+	# commun_EstJoueurRandom
+#========================================
+
+
+
+# Remise du score a sa valeur normale
+
+	# Staff
+scoreboard players set @s[name=aygame] commun_Grade 15
+scoreboard players set @s[name=Fabaure] commun_Grade 14
+scoreboard players set @s[name=Haugtolas] commun_Grade 14
+scoreboard players set @s[name=mathaym25] commun_Grade 13
+scoreboard players set @s[name=Catsuri33] commun_Grade 11
+scoreboard players set @s[name=_Fire_Ghost_] commun_Grade 11
+scoreboard players set @s[name=matiousse12] commun_Grade 11
+scoreboard players set @s[name=Multicort] commun_Grade 11
+scoreboard players set @s[name=Vianpyro] commun_Grade 10
+scoreboard players set @s[name=vinzvador] commun_Grade 9
+scoreboard players set @s[name=marlax_] commun_Grade 9
+scoreboard players set @s[name=zaled] commun_Grade 8
+scoreboard players set @s[name=KaZs] commun_Grade 6
+
+	# Youtubeur -> VIP
+# pas fait
+
+	# Autres membres
+scoreboard players set @s[tag=commun_EstJoueurRandom,scores={commun_TempsJeu=36000..}] commun_Grade 1
+scoreboard players set @s[tag=commun_EstJoueurRandom,scores={commun_TempsJeu=..35999}] commun_Grade 0
+
+
+
+# Join de la team si le joueur a le tag commun_ABesoinGrade
+
+execute if entity @s[tag=commun_ABesoinGrade] run function commun:grades/attribution