gem5, m5ops: init at 24.1.0.1

pkgs/by-name/ge/gem5/include-algorithm.patch

@@ -0,0 +1,12 @@
+diff --git a/src/base/random.hh b/src/base/random.hh
+index 0b287f95052..b3550a0f3df 100644
+--- a/src/base/random.hh
++++ b/src/base/random.hh
+@@ -45,6 +45,7 @@
+ #ifndef __BASE_RANDOM_HH__
+ #define __BASE_RANDOM_HH__
+
++#include <algorithm>
+ #include <random>
+ #include <string>
+ #include <type_traits>

pkgs/by-name/ge/gem5/m5ops.nix

@@ -0,0 +1,53 @@
+{
+  fetchFromGitHub,
+  glibc,
+  isa ? "x86",
+  lib,
+  scons,
+  stdenv,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "m5ops-${isa}";
+  version = "24.1.0.1";
+
+  src = fetchFromGitHub {
+    owner = "gem5";
+    repo = "gem5";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-Q7+LuCGUINvsuF7GyiEC7/veADTVi1FpkUXajl2TDkA=";
+  };
+
+  nativeBuildInputs = [ scons ];
+
+  buildInputs = [ glibc.static ];
+
+  sourceRoot = "source/util/m5";
+
+  buildFlags = [ "build/${isa}/out/m5" ];
+
+  # Needed so the build script doesn't hide all Nix environment variables.
+  postPatch = ''
+    substituteInPlace SConstruct \
+      --replace-fail "Environment()" "Environment(ENV=os.environ)"
+  '';
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/{bin,lib}
+    cp build/${isa}/out/m5 $out/bin/
+    cp build/${isa}/out/libm5.a $out/lib/
+    cp -r ../../include $out/include
+
+    runHook postInstall
+  '';
+
+  meta = {
+    description = "Special instructions for gem5";
+    homepage = "https://www.gem5.org/";
+    license = lib.licenses.bsd3;
+    platforms = lib.platforms.linux;
+    maintainers = [ lib.maintainers.mtoohey ];
+  };
+})

pkgs/by-name/ge/gem5/package.nix

@@ -0,0 +1,76 @@
+{
+  boost,
+  capstone,
+  fetchFromGitHub,
+  gperftools,
+  hdf5-cpp,
+  isa ? "X86",
+  lib,
+  libpng,
+  m4,
+  protobuf_21,
+  python3,
+  scons,
+  stdenv,
+  variant ? "opt",
+  zlib,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "gem5-${isa}-${variant}";
+  version = "24.1.0.1";
+
+  src = fetchFromGitHub {
+    owner = "gem5";
+    repo = "gem5";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-Q7+LuCGUINvsuF7GyiEC7/veADTVi1FpkUXajl2TDkA=";
+  };
+
+  # Needed to make the current release compile, see:
+  # https://github.com/gem5/gem5/pull/1897 (the PR was rejected, but there is no
+  # release with the fix).
+  patches = [ ./include-algorithm.patch ];
+
+  nativeBuildInputs = [
+    m4
+    python3
+    scons
+  ];
+
+  buildInputs = [
+    boost
+    capstone
+    gperftools # provides tcmalloc
+    hdf5-cpp
+    libpng
+    protobuf_21
+    zlib
+  ];
+
+  buildFlags = [ "build/${isa}/gem5.${variant}" ];
+
+  enableParallelBuilding = true;
+
+  preBuild = ''
+    patchShebangs .
+  '';
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/bin
+    cp build/${isa}/gem5.${variant} $out/bin/
+
+    runHook postInstall
+  '';
+
+  meta = {
+    description = "A modular platform for computer-system architecture research";
+    homepage = "https://www.gem5.org/";
+    license = lib.licenses.bsd3;
+    platforms = lib.platforms.linux;
+    mainProgram = "gem5.${variant}";
+    maintainers = [ lib.maintainers.mtoohey ];
+  };
+})

pkgs/top-level/all-packages.nix

@@ -18352,6 +18352,8 @@ with pkgs;
     erlang = erlang_25;
   };
 
+  m5ops = callPackage ../by-name/ge/gem5/m5ops.nix { };
+
   rustdesk-flutter = callPackage ../by-name/ru/rustdesk-flutter/package.nix {
     flutter = flutter324;
   };