Add Nix Overlay

flake.nix

@@ -1,28 +1,46 @@
 {
   description = "A JS devtool orchestrator";
   inputs = {
-    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
+    nixpkgs.url = "github:nixos/nixpkgs";
     flake-utils.url = "github:numtide/flake-utils";
   };
 
-  outputs = { self, nixpkgs, flake-utils }:
-  flake-utils.lib.eachDefaultSystem (system:
-  let
-    manifest = (pkgs.lib.importTOML ./crates/depot/Cargo.toml).package;
-    pkgs = import nixpkgs { inherit system; };
-    depot-js = pkgs.rustPlatform.buildRustPackage rec {
-      pname = manifest.name;
-      version = manifest.version;
-      cargoLock.lockFile = ./Cargo.lock;
-      src = pkgs.lib.cleanSource ./.;    
-      nativeBuildInputs = [ pkgs.git ];
-      # NOTE: depot's tests have a lot of external dependencies: node, biome, ...
-      # We'll ignore them for now and figure it out later ;)
-      doCheck = false;
-    };
-  in {
-    packages = {
-      default = depot-js;
-    };
-  });
+  outputs =
+    {
+      self,
+      nixpkgs,
+      flake-utils,
+    }:
+    let
+      depotOverlay = final: prev: {
+        depot = final.callPackage ./nix/package.nix {
+          cleanSource = prev.lib.cleanSource;
+        };
+
+        mkDepotPackage = final.callPackage ./nix/mk-depot-package.nix {
+          depot = final.depot;
+        };
+      };
+    in
+    {
+      overlays.default = depotOverlay;
+    }
+    // flake-utils.lib.eachDefaultSystem (
+      system:
+      let
+        pkgs = import nixpkgs {
+          inherit system;
+          overlays = [ depotOverlay ];
+        };
+      in
+      {
+        packages = {
+          default = pkgs.depot;
+        };
+
+        devShells.default = pkgs.mkShell {
+          inputsFrom = [ pkgs.depot ];
+        };
+      }
+    );
 }

nix/mk-depot-package.nix

@@ -0,0 +1,61 @@
+{
+  lib,
+  stdenv,
+  cacert,
+  nodejs_22,
+  pnpm_9,
+  depot,
+}:
+
+{
+  pname,
+  version,
+  src,
+  pnpmHash, # The checksum for pnpm-lock.yaml
+  distDir ? "dist", # Where the build output lands (relative to root)
+  extraNativeBuildInputs ? [ ],
+  ...
+}@args:
+
+stdenv.mkDerivation (
+  finalAttrs:
+  (builtins.removeAttrs args [
+    "pnpmHash"
+    "distDir"
+    "extraNativeBuildInputs"
+  ])
+  // {
+    nativeBuildInputs = [
+      cacert
+      pnpm_9
+      nodejs_22
+      depot
+    ]
+    ++ extraNativeBuildInputs;
+
+    pnpmDeps = pnpm_9.fetchDeps {
+      inherit (finalAttrs) pname version src;
+      fetcherVersion = 2;
+      hash = pnpmHash;
+    };
+
+    buildPhase = ''
+      set -euo pipefail
+
+      # 1. Setup PNPM Store
+      export NPM_CONFIG_OFFLINE=true
+      export PNPM_WRITABLE_STORE=$(mktemp -d)
+      cp -LR ${finalAttrs.pnpmDeps}/* $PNPM_WRITABLE_STORE/ || true
+      chmod -R +w $PNPM_WRITABLE_STORE
+      export npm_config_store_dir=$PNPM_WRITABLE_STORE
+
+      # 2. Run Depot Build
+      depot b --release
+    '';
+
+    installPhase = ''
+      mkdir -p $out
+      cp -r ${distDir}/* $out/ 
+    '';
+  }
+)

nix/package.nix

@@ -0,0 +1,18 @@
+{
+  lib,
+  rustPlatform,
+  git,
+  cleanSource,
+}:
+
+let
+  manifest = (lib.importTOML ../crates/depot/Cargo.toml).package;
+in
+rustPlatform.buildRustPackage {
+  pname = manifest.name;
+  version = manifest.version;
+  cargoLock.lockFile = ../Cargo.lock;
+  src = cleanSource ../.;
+  nativeBuildInputs = [ git ];
+  doCheck = false;
+}