WIP

cf. https://docs.gradle.org/current/userguide/sharing_build_logic_between_subprojects.html

buildSrc/build.gradle.kts

@@ -0,0 +1,6 @@
+plugins {
+    `kotlin-dsl`
+}
+repositories {
+    mavenCentral()
+}

buildSrc/src/main/java/lightzone.java-conventions.gradle.kts

@@ -0,0 +1,92 @@
+import org.gradle.api.tasks.Exec
+import org.gradle.api.tasks.compile.JavaCompile
+import org.gradle.kotlin.dsl.*
+
+plugins {
+    application
+    java
+}
+
+group = "com.lightcrafts"
+version = rootProject.file("lightcrafts/version.txt").readText().trim().substringBefore('~')
+
+repositories {
+    maven(url = "https://maven.geotoolkit.org/")
+    mavenCentral()
+}
+
+val jetbrainsAnnotation = "org.jetbrains:annotations:24.0.1"
+val lombok = "org.projectlombok:lombok:1.18.30"
+dependencies {
+    annotationProcessor(jetbrainsAnnotation)
+    annotationProcessor(lombok)
+    compileOnly(jetbrainsAnnotation)
+    compileOnly(lombok)
+    implementation(files("${project.rootDir}/lightcrafts/lib/jai-lightzone-1.1.3.0.jar"))
+    testCompileOnly(jetbrainsAnnotation)
+    testImplementation(kotlin("test"))
+    testImplementation("io.kotest:kotest-runner-junit5:5.8.0")
+    testImplementation("org.assertj:assertj-core:3.11.1")
+    testImplementation(platform("org.junit:junit-bom:5.10.1"))
+    testImplementation("org.junit.jupiter:junit-jupiter-api")
+    testImplementation("org.junit.jupiter:junit-jupiter-engine")
+    testImplementation("org.junit.jupiter:junit-jupiter-params")
+}
+
+application {
+    applicationName = "LightZone"
+    applicationDefaultJvmArgs += listOf(
+        "--add-exports=java.desktop/sun.awt.image=ALL-UNNAMED",
+        "-Xmx512m",
+    )
+}
+
+val os = System.getProperty("os.name").lowercase()
+val MAKE = with(os) {
+    when {
+        startsWith("sun") -> "gmake"
+        endsWith("bsd") -> "gmake"
+        else -> "make"
+    }
+}
+tasks {
+    withType<JavaCompile> {
+        options.encoding = "UTF-8"
+        options.compilerArgs = listOf("-h", file("javah").absolutePath)
+    }
+    test {
+        useJUnitPlatform()
+        testLogging {
+            events("passed", "skipped", "failed")
+        }
+        workingDir = file("products")
+    }
+    run.get().workingDir = file("products")
+    register<Exec> ("products") {
+        commandLine(MAKE, "-C", "products", "-j")
+    }
+    register<Exec> ("cleanProducts") {
+        commandLine(MAKE, "-C", "products", "-j", "-s", "clean")
+    }
+    named("build") {
+        dependsOn("products")
+    }
+    named("clean") {
+        dependsOn("cleanProducts")
+    }
+    if (file("jnisrc").exists()) {
+        register<Exec> ("jni") {
+            dependsOn("classes")
+            commandLine(MAKE, "-C", "jnisrc")
+        }
+        register<Exec> ("cleanJni") {
+            commandLine(MAKE, "-C", "jnisrc", "-j", "-s", "distclean")
+        }
+        named("build") {
+            dependsOn("jni")
+        }
+        named("clean") {
+            dependsOn("cleanJni")
+        }
+    }
+}

lightcrafts/build.gradle.kts

@@ -1,5 +1,18 @@
 import java.io.FileOutputStream
 
+plugins {
+    kotlin("jvm")
+    id("lightzone.java-conventions")
+}
+dependencies {
+    implementation("com.formdev:flatlaf:3.1.1")
+    implementation("com.formdev:flatlaf-intellij-themes:3.1.1")
+    implementation("com.github.jiconfont:jiconfont-swing:1.0.1")
+    implementation("com.github.jiconfont:jiconfont-font_awesome:4.7.0.0")
+    implementation("com.github.jiconfont:jiconfont-google_material_design_icons:2.2.0.2")
+    implementation("com.github.openjson:openjson:1.0.13")
+    implementation("org.ejml:ejml-simple:0.40")
+}
 application {
     mainClass.set("com.lightcrafts.app.Application")
 }
@@ -11,15 +24,6 @@ sourceSets {
         }
     }
 }
-dependencies {
-    implementation("com.formdev:flatlaf:3.1.1")
-    implementation("com.formdev:flatlaf-intellij-themes:3.1.1")
-    implementation("com.github.jiconfont:jiconfont-swing:1.0.1")
-    implementation("com.github.jiconfont:jiconfont-font_awesome:4.7.0.0")
-    implementation("com.github.jiconfont:jiconfont-google_material_design_icons:2.2.0.2")
-    implementation("com.github.openjson:openjson:1.0.13")
-    implementation("org.ejml:ejml-simple:0.40")
-}
 val os = System.getProperty("os.name").lowercase()
 val MAKE = with(os) {
     when {
@@ -50,10 +54,10 @@ tasks {
         }
         File("$dir/Version").writeText(version.toString())
     }
-    getByName("build") {
+    named("build") {
         dependsOn("coprocesses", "revision")
     }
-    getByName("clean") {
+    named("clean") {
         dependsOn("cleanCoprocesses")
     }
 }

linux/build.gradle.kts

@@ -1,3 +1,7 @@
+plugins {
+    kotlin("jvm")
+    id("lightzone.java-conventions")
+}
 dependencies {
     implementation(project(":lightcrafts"))
     implementation("javax.help:javahelp:2.0.05")

macosx/build.gradle.kts

@@ -1,4 +1,6 @@
 plugins {
+    kotlin("jvm")
+    id("lightzone.java-conventions")
     id("org.beryx.runtime")
 }
 dependencies {

settings.gradle.kts

@@ -1,14 +1,16 @@
 import org.gradle.internal.os.OperatingSystem
 
 plugins {
-    id("org.gradle.toolchains.foojay-resolver-convention") version "0.5.0"
+    kotlin("jvm") version "1.9.22" apply false
+    id("org.beryx.runtime") version "1.13.1" apply false
 }
 
-include(":lightcrafts")
 val os = OperatingSystem.current()!!
 val osName = when {
     os.isWindows -> "windows"
     os.isMacOsX -> "macosx"
     else -> "linux"
 }
-include(osName)
+
+rootProject.name = "lightzone"
+include("lightcrafts", osName)

windows/build.gradle.kts

@@ -1,4 +1,6 @@
 plugins {
+    kotlin("jvm")
+    id("lightzone.java-conventions")
     id("org.beryx.runtime")
 }
 dependencies {