bauer: an Emacs+Nix IDE

This ORG-mode file generates an Emacs configuration. I am calling it an Emacs+Nix IDE. That is, the Emacs configuration is integrated with hardcoded Nix store paths. This provides a kind of functional Emacs configuration. The integration between Emacs & Nix comes with lots of useful side effects. The raw Org file can always be downloaded here. You can create pull requests & issues on the GitHub repo. You can access my website at https://matthewbauer.us.

Usage

Installing/upgrading

This is the script that I use to setup all of my new machines but it’s portable enough for anyone to use.

To install, just run this command from your shell:

curl https://matthewbauer.us/bauer/install | sh

Once it’s installed, you can open Emacs at any time with this command:

"$HOME/.nix-profile/bin/run"

If you don’t like it, it’s also very easy to uninstall. Just run:

nix-env -e bauer
nix-collect-garbage -d

Developing

After you’ve installed it, it’s easy to make changes. By default, the configuration lives in ~/.local/share/bauer. To make changes just follow this process,

cd ~/.local/share/bauer
nix-build
./result/run README.org

The last line will spawn an Emacs frame in the Git repo. Anything in that file can be change. Once you’ve made a change, just run M-x dev-restart to rebuild the configuration & restart Emacs. Make any changes you want to the README.org file or any of the files in the site-lisp folder. Make sure you commit your changes afterward by typing C-c p v, then cc. If you have already forked this repo on GitHub, you can add it as a remote by typing Mg followed by your GitHub username within Magit. To push to it, just type Pr then find your username in the list & press enter. Pull requests are always welcome through GitHub!

Without Nix

You can also use this configuration without Nix. This just gives you the Emacs configuration without any of the Nix integrations. All of the binaries will have to be provided externally. To get started, run the following:

mv ~/.emacs.d ~/.emacs.d.old
git clone https://github.com/matthewbauer/bauer \
          ~/.emacs.d

Note on macOS

Disabling AppNap

Recent versions of macOS have a “feature” called AppNap that causes unfocused apps to sleep in the background. This often results in things like compilation taking forever because it only does any work while focused. We almost never want Emacs to suspend on its own, so it’s important to disable this.

Luckily, it’s not very hard to do this. From the terminal, run:

defaults write org.gnu.Emacs NSAppSleepDisabled -bool YES
defaults write emacs NSAppSleepDisabled -bool YES

I’ve seen some of the org.gnu.Emacs form posted online. However, if you start Emacs from the command line, the second one is necessary since this is how Apple will identify the binary.

This is totally optional. If this doesn’t bother you, feel free to leave it, and it will probably slightly improve your energy usage, since it can suspend Emacs when unfocused.

Emacs init file

This is the main part of the IDE. It is written in Emacs Lisp & will be loaded every time Emacs is started.

Increase GC

Increasing GC is a common way to speed up Emacs. gc-cons-threshold sets at what point Emacs should invoke its garbage collector Some people set it to a really larger number permanently. This works well until the garbage is actually collected (then you have to wait a long time). I’ve decided to just set it temporarily to a large number so we only garbage collect once on startup. After that we reset it to the standard value. Read @bling’s post for more info on this.

;; -*- mode: emacs-lisp; coding: utf-8; -*-

(defvar file-name-handler-alist-backup
        file-name-handler-alist)
(setq gc-cons-threshold most-positive-fixnum
      file-name-handler-alist nil)
(add-hook 'after-init-hook
  (lambda ()
    (garbage-collect)
    (setq gc-cons-threshold
            (car (get 'gc-cons-threshold 'standard-value))
      file-name-handler-alist
        (append
          file-name-handler-alist-backup
          file-name-handler-alist))))

(setq read-process-output-max (* 1024 1024))

Benchmark

Disabled for now.

;; (eval-and-compile (require 'use-package))
;; (use-package benchmark-init
;;   :demand
;;   :config
;;   ;; To disable collection of benchmark data after init is done.
;;   (add-hook 'after-init-hook 'benchmark-init/deactivate))

Autoloads & Misc.

Setup some initial aliases for Emacs. These give us an easy way to use these functions without actually require’ing them. Ideally, Emacs should pick these up through the automatic autoloading method, but that sometimes conflicts with the compiling phases used later.

(eval-and-compile
  (autoload 'package-installed-p "package")
  (autoload 'use-package-autoload-keymap "use-package")
  (autoload 'pcomplete-arg "pcomplete")
  (autoload 'pcomplete--here "pcomplete")
  (autoload 'tramp-tramp-file-p "tramp")
  (autoload 'tramp-dissect-file-name "tramp")

  (defvar view-mode-map)
  (defvar iso-transl-ctl-x-8-map)
  (defvar dired-mode-map))

When we are within a terminal we want to be able to use the mouse, so xterm-mouse-mode is enabled here.

iTerm doesn’t seem to support xterm color reporting correctly, so we use the COLORFGBG method.

(unless (display-graphic-p)
  (xterm-mouse-mode 1)

  (when (string-equal (getenv "TERM_PROGRAM") "iTerm.app")
    (add-hook 'after-make-frame-functions
              #'(lambda
                 ;; Take advantage of iterm2's CSI u support (https://gitlab.com/gnachman/iterm2/-/issues/8382).
                 (xterm--init-modify-other-keys)

                 ;; Courtesy https://emacs.stackexchange.com/a/13957, modified per
                 ;; https://gitlab.com/gnachman/iterm2/-/issues/8382#note_365264207
                 (defun character-apply-modifiers (c &rest modifiers)
                   "Apply modifiers to the character C.
MODIFIERS must be a list of symbols amongst (meta control shift).
Return an event vector."
                   (if (memq 'control modifiers) (setq c (if (and (<= ?a c) (<= c ?z))
                                                             (logand c ?\x1f)
                                                           (logior (lsh 1 26) c))))
                   (if (memq 'meta modifiers) (setq c (logior (lsh 1 27) c)))
                   (if (memq 'shift modifiers) (setq c (logior (lsh 1 25) c)))
                   (vector c))
                 (when (and (boundp 'xterm-extra-capabilities) (boundp 'xterm-function-map))
                   (let ((c 32))
                     (while (<= c 126)
                       (mapc (lambda (x)
                               (define-key xterm-function-map (format (car x) c)
                                 (apply 'character-apply-modifiers c (cdr x))))
                             '(;; with ?.VT100.formatOtherKeys: 0
                               ("\e\[27;3;%d~" meta)
                               ("\e\[27;5;%d~" control)
                               ("\e\[27;6;%d~" control shift)
                               ("\e\[27;7;%d~" control meta)
                               ("\e\[27;8;%d~" control meta shift)
                               ;; with ?.VT100.formatOtherKeys: 1
                               ("\e\[%d;3u" meta)
                               ("\e\[%d;5u" control)
                               ("\e\[%d;6u" control shift)
                               ("\e\[%d;7u" control meta)
                               ("\e\[%d;8u" control meta shift)))
                       (setq c (1+ c)))))
                 ))

    ;; ;; xterm--report-background-handler init fails, but we can still
    ;; ;; use COLORFGBG
    ;; (defvar xterm-extra-capabilities)
    ;; (setq xterm-extra-capabilities '(modifyOtherKeys getSelection setSelection))
    (autoload 'rxvt-set-background-mode "term/rxvt")
    (add-hook 'window-setup-hook 'rxvt-set-background-mode)
    ))

Custom config

set-defaults provides an easy way to override the default custom files. This means that when you customize a variable it will appear as ‘standard’ even though it’s not what the package originally defined as the default. This is useful for an Emacs distribution to provide better defaults while still letting the user override them. Look through the lispdoc of the package for documentation on how this works. Eventually, this will be added to MELPA for use in other Emacs distributions.

(require 'set-defaults)

Better defaults

These are some better defaults for Emacs. They shouldn’t require any packages to be installed to work (those go in use-package). In addition, they should take almost no time to run (meaning they probably shouldn’t have custom init hooks). The format of arguments to set-defaults is identical to the one used by custom-set-variables.

Default Variable	Default Value
apropos-do-all	t
async-shell-command-buffer	‘new-buffer
auth-source-save-behavior	t
auto-revert-avoid-polling	t
auto-revert-check-vc-info	t
auto-revert-interval	2
auto-revert-verbose	nil
backward-delete-char-untabify-method	‘hungry
bidi-inhibit-bpa	t
bidi-paragraph-direction	‘left-to-right
bookmark-save-flag	1
checkdoc-spellcheck-documentation-flag	t
comint-input-ignoredups	t
comint-move-point-for-matching-input	‘end-of-line
comint-move-point-for-output	‘all
comint-process-echoes	t
comint-prompt-read-only	t
comint-scroll-to-bottom-on-input	‘this
compilation-always-kill	t
compilation-ask-about-save	nil
compilation-context-lines	t
compilation-scroll-output	‘first-error
compilation-skip-threshold	1
completions-cycle-threshold	t
completions-detailed	t
completions-format	‘vertical
completion-ignore-case	t
case-fold-search	t
cursor-in-non-selected-windows	nil
custom-search-field	nil
delete-by-moving-to-trash	t
delete-old-versions	t
dired-dwim-target	t
dired-hide-details-hide-symlink-targets	nil
dired-omit-verbose	nil
dired-recursive-copies	‘top
dired-recursive-deletes	‘top
ediff-window-setup-function	‘ediff-setup-windows-plain
eldoc-idle-delay	0.4
enable-recursive-minibuffers	t
eshell-cmpl-autolist	t
eshell-cmpl-cycle-completions	nil
eshell-cmpl-ignore-case	t
eshell-default-target-is-dot	t
eshell-destroy-buffer-when-process-dies	t
eshell-hist-ignoredups	‘erase
eshell-list-files-after-cd	t
eshell-review-quick-commands	t
eval-expression-print-level	nil
flymake-no-changes-timeout	nil
flymake-start-syntax-check-on-newline	nil
flyspell-highlight-properties	nil
flyspell-issue-welcome-flag	nil
fill-column	80
frame-inhibit-implied-resize	t
history-delete-duplicates	t
ibuffer-default-display-maybe-show-predicates	t
ibuffer-expert	t
ibuffer-show-empty-filter-groups	nil
ibuffer-shrink-to-minimum-size	t
ibuffer-use-other-window	t
imenu-auto-rescan	t
indent-tabs-mode	nil
indicate-buffer-boundaries	‘left
indicate-empty-lines	t
isearch-allow-scroll	‘unlimited
isearch-lazy-count	t
isearch-yank-on-move	‘shift
ispell-quietly	t
ispell-silently-savep	t
jit-lock-chunk-size	4096
jit-lock-defer-time	0.05
jit-lock-stealth-time	1.25
kill-do-not-save-duplicates	t
kill-whole-line	t
load-prefer-newer	t
mac-command-modifier	‘meta
mac-option-modifier	‘super
mac-right-option-modifier	nil
next-error-recenter	t
ns-function-modifier	‘hyper
ns-pop-up-frames	nil
nsm-save-host-names	t
nxml-sexp-element-flag	t
nxml-slash-auto-complete-flag	t
project-compilation-buffer-name-function	‘project-prefixed-buffer-name
read-buffer-completion-ignore-case	t
read-extended-command-predicate	‘command-completion-default-include-p
resize-mini-windows	t
ruby-insert-encoding-magic-comment	nil
save-abbrevs	‘silently
save-interprogram-paste-before-kill	t
scroll-conservatively	101
scroll-preserve-screen-position	‘always
sentence-end-double-space	nil
set-mark-command-repeat-pop	t
shell-completion-execonly	nil
shell-input-autoexpand	nil
switch-to-buffer-in-dedicated-window	‘pop
switch-to-buffer-obey-display-actions	t
tab-always-indent	‘complete
term-input-autoexpand	t
term-input-ignoredups	t
tls-checktrust	t
undo-limit	80000000
undo-outer-limit	120000000
undo-strong-limit	12000000
uniquify-buffer-name-style	‘post-forward-angle-brackets
use-package-always-defer	t
version-control	t
view-inhibit-help-message	t
view-read-only	t
whitespace-line-column	120
window-combination-resize	t
woman-imenu	t
x-stretch-cursor	t
xref-show-definitions-function	‘xref-show-definitions-completing-read

(apply 'set-defaults
       (mapcar (lambda (x) (list (intern (car x))
                                 (if (stringp (cadr x))
                                     (car (read-from-string (cadr x)))
                                   (cadr x)))) defaults))

Misc. defaults that don’t fit above. TODO: move these above.

(when (file-exists-p user-emacs-directory)
  (make-directory (expand-file-name "auto-save/" user-emacs-directory) t)
  (make-directory (expand-file-name "backup/" user-emacs-directory) t)
  (make-directory (expand-file-name "undo-tree/" user-emacs-directory) t))

(set-defaults
 '(auto-save-file-name-transforms `((".*"
                                     ,(expand-file-name "auto-save/"
                                                        user-emacs-directory) t)))
 '(backup-directory-alist `((".*" .
                             ,(expand-file-name "backup/"
                                                user-emacs-directory))))
 '(context-menu-functions
   '(context-menu-ffap
     context-menu-undo
     context-menu-region
     context-menu-middle-separator
     context-menu-local
     context-menu-minor
     occur-context-menu
     Man-context-menu
     dictionary-context-menu
     context-menu-buffers))
 '(comint-password-prompt-regexp (concat
                                  "\\(^ *\\|"
                                  (regexp-opt
                                   '("Enter" "enter" "Enter same" "enter same" "Enter the" "enter the"
                                     "Enter Auth" "Old" "old" "New" "new" "'s" "login"
                                     "Kerberos" "CVS" "UNIX" " SMB" "LDAP" "PEM" "SUDO"
                                     "[sudo]" "Repeat" "Bad" "Retype")
                                   t)
                                  ;; Allow for user name to precede password equivalent (Bug#31075).
                                  " +.*\\)"
                                  "\\(?:" (regexp-opt password-word-equivalents) "\\|Response\\)"
                                  "\\(?:\\(?:, try\\)? *again\\| (empty for no passphrase)\\| (again)\\)?"
                                  ;; "[[:alpha:]]" used to be "for", which fails to match non-English.
                                  "\\(?: [[:alpha:]]+ .+\\)?[[:blank:]]*[:：៖][[:blank:]]*\\'"))
 '(compilation-error-regexp-alist
   '(absoft ada aix ant bash borland python-tracebacks-and-caml cmake cmake-info comma msft edg-1 edg-2
     epc ftnchek gradle-kotlin gradle-android iar ibm irix java javac jikes-file maven jikes-line
     clang-include gcc-include ruby-Test::Unit gmake gnu lcc makepp mips-1 mips-2 omake oracle perl
     php rxp shellcheck sparc-pascal-file sparc-pascal-line sparc-pascal-example sun sun-ada watcom
     4bsd gcov-file gcov-header gcov-nomark gcov-called-line gcov-never-called perl--Pod::Checker perl--Test
     perl--Test2 perl--Test::Harness weblint guile-file guile-line typescript-tsc-plain typescript-tsc-pretty
     ("^\\(?1:\\(?:[^\11\12 0-9]\\|[0-9]+[^\0120-9]\\)\\(?:[^\12 :]\\| [^\12/-]\\|:[^\12 ]\\)*?\\):(\\(?2:[0-9]+\\),\\(?3:[0-9]+\\))-(\\(?4:[0-9]+\\),\\(?5:[0-9]+\\))" 1 (2 . 4) (3 . 5))
     ("^  \\([^:\n\t]+\\):\\([0-9]+\\):\\([0-9]+\\): $" 1 2 3 0)))
 '(completion-styles '(basic partial-completion emacs22 substring flex))
 '(custom-file (expand-file-name "settings.el" user-emacs-directory))
 '(dired-listing-switches "-alhv --group-directories-first")
 '(dired-omit-files "^\\.\\|^#.*#$")
 '(dirtrack-list '("^[^:]*:\\(?:�\\[[0-9]+m\\)*\\([^\\$# �]+\\)" 1))
 '(eshell-prompt-function
   (lambda ()
     (concat (when (tramp-tramp-file-p default-directory)
               (concat
                (tramp-file-name-user
                 (tramp-dissect-file-name default-directory))
                "@"
                (tramp-file-name-host
                 (tramp-dissect-file-name default-directory))
                " "))
             (let ((dir (eshell/pwd)))
               (if (string= dir (getenv "HOME")) "~"
                 (let ((dirname (file-name-nondirectory dir)))
                   (if (string= dirname "") "/" dirname))))
             (if (= (user-uid) 0) " # " " $ "))))
 '(eshell-visual-commands
   '("vi" "screen" "top" "less" "more" "lynx" "ncftp" "pine" "tin"
     "trn" "elm" "ssh" "mutt" "tmux" "htop"
     "alsamixer" "watch" "elinks" "links" "nethack" "vim"
     "cmus" "nmtui" "nmtui-connect" "nmtui-edit" "ncdu"
     "telnet" "rlogin"))
 '(eshell-visual-subcommands '(("vagrant" "ssh")))
 '(find-ls-option '("-print0 | xargs -P4 -0 ls -ldN" . "-ldN"))
 '(find-ls-subdir-switches "-ldN")
 '(frame-title-format
   '(:eval
     (if (buffer-file-name)
         (abbreviate-file-name (buffer-file-name))
       "%b")))
 '(ibuffer-formats
   '((mark modified read-only " " (name 16 -1) " "
           (size 6 -1 :right) " " (mode 16 16) " " filename)
     (mark " " (name 16 -1) " " filename)))
 '(ibuffer-never-show-predicates '("\\*magit-\\(diff\\|process\\):"))
 '(ispell-extra-args '("--sug-mode=ultra"))
 '(mouse-wheel-scroll-amount '(1 ((shift) . 5) ((control))))
 '(minibuffer-prompt-properties
   '(read-only t
     cursor-intangible t
     point-entered minibuffer-avoid-prompt
     face minibuffer-prompt))
 '(package-archives
   '(("melpa" . "https://melpa.org/packages/")
     ("org" . "http://orgmode.org/elpa/")
     ("gnu" . "https://elpa.gnu.org/packages/")))
 '(savehist-additional-variables '(search-ring
                                   regexp-search-ring
                                   kill-ring
                                   comint-input-ring
                                   kmacro-ring
                                   sr-history-registry
                                   file-name-history
                                   tablist-name-filter))
 '(tramp-default-proxies-alist
   '(((regexp-quote (system-name)) nil nil)
     (nil "\\`root\\'" "/ssh:%h:")
     (".*" "\\`root\\'" "/ssh:%h:")))
 '(uniquify-ignore-buffers-re "^\\*")
 '(vc-git-diff-switches '("-w" "-U3"))
 '(vc-ignore-dir-regexp
   "\\(\\(\\`\\(?:[\\/][\\/][^\\/]+[\\/]\\|/\\(?:net\\|afs\\|\\.\\.\\.\\)/\\)\\'\\)\\|\\(\\`/[^/|:][^/|]*:\\)\\)\\|\\(\\`/[^/|:][^/|]*:\\)")
 '(whitespace-action '(cleanup))
 '(whitespace-style '(face trailing lines space-before-tab empty))
 '(whitespace-global-modes '(not erc-mode ses-mode))
 '(compilation-save-buffers-predicate
   (lambda ()
     (let ((proj (project-current)))
       (and proj
            (memq (current-buffer) (project-buffers proj)))))))

Site paths

Now, pull in generated paths from site-paths.el. Nix will generate this file automatically for us & different Emacs variables will be set to their Nix store derivation paths. Everything should work fine if you don’t have this available, though. If you are in Emacs & already have the IDE installed you can inspect this file by typing C-h C-l site-paths. It will look similar to a settings.el file where each line corresponds to a customizable variable. Unlike settings.el, each entry is path in the Nix store & we verify it exists before setting it.

(load "site-paths" t)

Set environment

set-envs is provided by set-defaults. We can use it like custom-set-variables, just it calls setenv instead of setq. All of these entries correspond to environment variables that we want to always be set in the Emacs process.

(set-envs
 '("VISUAL" "emacsclient -a emacs")
 '("EDITOR" "emacsclient -a emacs")
 '("NODE_NO_READLINE" "1")
 '("PAGER" "cat")
 '("PS1" "\\W > ")
 )

Fix broken Git on Windows.

(when (eq window-system 'w32)
  (setenv "GIT_ASKPASS" "git-gui--askpass"))

Load custom file

This file allows users to override the above defaults. This will mean you can use custom as you normally would in vanilla Emacs.

(when custom-file
  (load custom-file t))

Setup use-package

use-package is an Emacs package by John Weigley allowing users to easily configure other Emacs packages. It’s quite useful & it will be used extensively in this project.

Now to get use-package we will require package.el & initialize it if site-paths is not setup (meaning we’re outside the Nix expression). Because site-paths should be available (unless you don’t have Nix), we can skip this step. All of this is marked ‘eval-and-compile’ to make sure the compiler picks it up on build phase.

So, there are basically two modes for using this configuration. One when packages are installed externally (through Nix) & another where they are installed internally. This is captured in the variable ‘needs-package-init’ which will be t when we want to use the builtin package.el & will be nil when we want to just assume everything is available.

(eval-and-compile
  (setq needs-package-init
        (and (not (locate-library "site-paths"))
                 (not (and
                    (boundp 'use-package-list--is-running)
                    use-package-list--is-running)))))

First handle using package.el. We will do all of the work of bootstrapping here including running package-initialize, ensuring use-package, & delight are installed.

(when needs-package-init
  (require 'package)
  (package-initialize)
  (unless (package-installed-p 'use-package)
    (package-refresh-contents)
    (package-install 'use-package))
  (unless (package-installed-p 'delight)
    (package-refresh-contents)
    (package-install 'delight)))

Actually require use-package,

(eval-and-compile
  (require 'delight)
  (require 'bind-key)
  (require 'use-package))

Now let’s handle the case where all of the packages are already provided. Basically, we’ll prevent use-package from running ‘ensure’ on anything.

(eval-and-compile
  (setq use-package-always-ensure needs-package-init)
  (when (not needs-package-init)
    (setq use-package-ensure-function 'ignore
          package-enable-at-startup nil
          package--init-file-ensured t)))

Key bindings

Using bind-key, setup some simple key bindings. None of these should overwrite Emacs’ default keybindings. Also, they should only require vanilla Emacs to work (non-vanilla Emacs key bindings should be put in their use-package declaration). These are meant to all be as close to vanilla Emacs as possible. I try to avoid extremely specific key binds here.

What is overwritten can be seen with M-x describe-personal-keybindings. The goal is to overwrite as little as possible. When it is necessary to overwrite Emacs keybinds, documentation on why should be provided.

First we include a library that provides some nice helper functions that will be used as key bindings.

(require 'bauer)
(require 'files)

Define some helper functions.

(defun web-search (start end)
  (interactive "r")
  (let ((q (buffer-substring-no-properties start end)))
    (browse-url (concat "http://www.google.com/search?btnI&q="
      (url-hexify-string q)))))

Override browse-url to handle man protocol better.

(require 'browse-url)
(defun my-browse-url (url &rest args)
  "Ask a WWW browser to load URL.
Prompt for a URL, defaulting to the URL at or before point.
Invokes a suitable browser function which does the actual job.
The variable `browse-url-browser-function' says which browser function to
use.  If the URL is a mailto: URL, consult `browse-url-mailto-function'
first, if that exists.

The additional ARGS are passed to the browser function.  See the doc
strings of the actual functions, starting with `browse-url-browser-function',
for information about the significance of ARGS (most of the functions
ignore it).
If ARGS are omitted, the default is to pass `browse-url-new-window-flag'
as ARGS."
  (interactive (browse-url-interactive-arg "URL: "))
  (unless (called-interactively-p 'interactive)
    (setq args (or args (list browse-url-new-window-flag))))
  (when (and url-handler-mode
             (not (file-name-absolute-p url))
             (not (string-match "\\`[a-z]+:" url)))
    (setq url (expand-file-name url)))
  (let ((process-environment (copy-sequence process-environment))
	(function (or (and (string-match "\\`mailto:" url)
			   browse-url-mailto-function)
                      (and (string-match "\\`man:" url)
                           browse-url-man-function)
		      browse-url-browser-function))
	;; Ensure that `default-directory' exists and is readable (b#6077).
	(default-directory (or (unhandled-file-name-directory default-directory)
			       (expand-file-name "~/"))))
    ;; When connected to various displays, be careful to use the display of
    ;; the currently selected frame, rather than the original start display,
    ;; which may not even exist any more.
    (if (stringp (frame-parameter nil 'display))
        (setenv "DISPLAY" (frame-parameter nil 'display)))
    (if (and (consp function)
	     (not (functionp function)))
	;; The `function' can be an alist; look down it for first match
	;; and apply the function (which might be a lambda).
	(catch 'done
	  (dolist (bf function)
	    (when (string-match (car bf) url)
	      (apply (cdr bf) url args)
	      (throw 'done t)))
	  (error "No browse-url-browser-function matching URL %s"
		 url))
      ;; Unbound symbols go down this leg, since void-function from
      ;; apply is clearer than wrong-type-argument from dolist.
      (apply function url args))))

(advice-add 'browse-url :override 'my-browse-url)

(defun my-escape-quotes (begin end)
  (interactive
   (if (region-active-p)
       (list (region-beginning) (region-end))
     (list (line-beginning-position) (line-end-position))))
  (save-excursion
      (save-restriction
        (narrow-to-region begin end)
        (goto-char (point-min))
        (while (search-forward "\"" nil t)
          (replace-match "\\\"" t t)))))

(defun my-unescape-quotes (begin end)
  (interactive
   (if (region-active-p)
       (list (region-beginning) (region-end))
     (list (line-beginning-position) (line-end-position))))
  (save-excursion
    (save-restriction
      (narrow-to-region begin end)
      (goto-char (point-min))
      (while (search-forward "\\\"" nil t)
        (replace-match "\"" t t)))))

(with-eval-after-load 'project
  (defun project-find-regexp-with-unique-buffer (orig-fun &rest args)
    "An advice function that gives project-find-regexp a unique buffer name"
    (require 'xref)
    (let ((xref-buffer-name (format "%s %s" xref-buffer-name (car args))))
      (apply orig-fun args)))

  (advice-add 'project-find-regexp :around #'project-find-regexp-with-unique-buffer))

Now we will call bind-keys. We give it keys to bind & what function to run when those keys are pressed. Note on syntax of bind-keys: if you are unfamiliar with how Emacs key binding works, you should read through this article. Some things done below include:

Make frame and window management a little bit easier. These are all used to

better navigations.

Scale text size for different context. Defaults to 12pt fonts.
Add evaluator keys, useful for executing lisp expressions.
Add some read-only mode keybindings.

Key combination	Action
<s-return>	toggle-frame-fullscreen
s-C-<left>	enlarge-window-horizontally
s-C-<right>	shrink-window-horizontally
s-C-<down>	shrink-window
s-C-<up>	enlarge-window
<S-s-up>	shrink-window
<S-s-down>	enlarge-window
<s-down>	windmove-down
<s-up>	windmove-up
<s-left>	windmove-left
<s-right>	windmove-right
C-x 5 3	iconify-frame
C-x 5 4	toggle-frame-fullscreen
<C-return>	other-window
<C-M-return>	other-window
s-o	other-window
ESC o	other-window
s-1	other-frame
C-c m b	eval-buffer
C-c m e	eval-last-sexp
C-c m i	eval-expression
C-c m d	eval-defun
C-c m n	eval-print-last-sexp
C-c m r	eval-region
C-c C-u	rename-uniquely
C-c C-o	browse-url-at-point
H-l	browse-url-at-point
H-c	compile
s-c	compile
s-r	revert-buffer
M-s d	find-grep-dired
M-s F	find-grep
M-s G	grep
C-x r q	save-buffers-kill-terminal
C-c C-<return>	delete-blank-lines
C-<f10>	menu-bar-mode
C-x M-g	browse-url-at-point
M-s f	find-name-dired
s-SPC	cycle-spacing
C-c w w	whitespace-mode
M-g l	goto-line
<C-M-backspace>	backward-kill-sexp
C-x v H	vc-region-history
C-c SPC	just-one-space
C-c f	flush-lines
C-c o	customize-option
C-c O	customize-group
C-c F	customize-face
C-c q	fill-region
C-c s	replace-string
C-c u	rename-uniquely
C-c z	clean-buffer-list
C-c =	count-matches
C-c ;	comment-or-uncomment-region
C-c [	align-regexp
s-/	comment-or-uncomment-region
M-s l	sort-lines
M-s m	multi-occur
M-s M	multi-occur-in-matching-buffers
C-c i i	imenu
s-v	scroll-down-command
s-M-e	end-of-defun
s-M-a	beginning-of-defun
s-?	xref-find-references
s-.	xref-find-definitions
s-,	xref-go-back
s->	xref-go-forward
s-%	query-replace
C-c \ u	my-unescape-quotes
C-c \ e	my-escape-quotes

(mapc (lambda (x) (bind-key (car x) (intern (cadr x)))) keybinds)

Some bauer-specific custom keybindings.

(bind-keys
  ([f12] . next-error)
  ([f11] . previous-error)
  ([shift f12] . previous-error)
  ([mouse-9] . next-buffer)
  ([mouse-8] . previous-buffer))

(bind-keys
 ("C-c I"   . bauer-find-config)
 :prefix-map bauer-git
 :prefix "s-g"
 ("l" . magit-clone)

 :prefix-map bauer-help
 :prefix "s-h"
 ("k" . describe-personal-keybindings)
 ("p" . ffap)
 ("m" . man)
 ("w" . woman))

Terminal mode key bindings follow. Scrolling in the term with the mouse should move text.

(unless window-system
  (global-set-key (kbd "<mouse-4>") 'scroll-down-line)
  (global-set-key (kbd "<mouse-5>") 'scroll-up-line))

macOS-specific bindings follow. Fullscreen handling should use the macOS feature, while by default it uses a custom Emacs stuff. In addition, drag and drop needs a special binding.

(when (eq window-system 'mac)
  (defun mac-fullscreen ()
    (interactive)
    (let ((fullscreen (frame-parameter nil 'fullscreen)))
      (if (memq fullscreen '(fullscreen fullboth))
          (let ((fullscreen-restore (frame-parameter nil 'fullscreen-restore)))
            (if (memq fullscreen-restore '(maximized fullheight fullwidth))
                (set-frame-parameter nil 'fullscreen fullscreen-restore)
              (set-frame-parameter nil 'fullscreen nil)))
        (modify-frame-parameters
         nil `((fullscreen . fullscreen) (fullscreen-restore . ,fullscreen))))))

  (bind-key "C-x 5 4" 'mac-fullscreen)

  (when (fboundp 'ns-drag-n-drop-as-text)
    (global-set-key [M-s-drag-n-drop]
                   'ns-drag-n-drop-as-text)))

Add special quotes and arrows to ctrl x 8 keymap.

(bind-keys
 :package iso-transl
 :map iso-transl-ctl-x-8-map
 ("' /"       . "′")
 ("\" /"      . "″")
 ("\" ("      . "“")
 ("\" )"      . "”")
 ("' ("       . "‘")
 ("' )"       . "’")
 ("4 < -"     . "←")
 ("4 - >"     . "→")
 ("4 b"       . "←")
 ("4 f"       . "→")
 ("4 p"       . "↑")
 ("4 n"       . "↓")
 ("<down>"    . "⇓")
 ("<S-down>"  . "↓")
 ("<left>"    . "⇐")
 ("<S-left>"  . "←")
 ("<right>"   . "⇒")
 ("<S-right>" . "→")
 ("<up>"      . "⇑")
 ("<S-up>"    . "↑")
 (","         . "…"))

Bind help map keys.

(bind-keys
  :map help-map
  ("C-r" . woman)
  ("j" . woman)
  ("C-j" . man)
  ("C-s" . web-search))

More keys that have custom functions. TODO: move these above

(bind-keys
 ("C-x ~" . (lambda () (interactive) (find-file "~")))
 ("C-x /" . (lambda () (interactive) (find-file "/")))
 ("C-x 4 C-x ~" . (lambda () (interactive) (find-file-other-window "~")))
 ("C-x 4 C-x /" . (lambda () (interactive) (find-file-other-window "/")))

 ("C-x M-p" . (lambda () (interactive)
                (save-excursion (other-window 1)
                                (quit-window))))

 ("C-M--" . (lambda () (interactive)
              (update-font-size -1 t)))
 ("C-M-=" . (lambda () (interactive)
              (update-font-size 1 t)))
 ("C-M-0" . (lambda () (interactive)
              (update-font-size 12 nil))))

Delete current buffer

;;;###autoload
(defun delete-file-and-buffer ()
  "Kill the current buffer and deletes the file it is visiting."
  (interactive)
  (let ((filename (buffer-file-name)))
    (when filename
      (if (vc-backend filename)
          (vc-delete-file filename)
        (progn
          (delete-file filename)
          (message "Deleted file %s" filename)
          (kill-buffer))))))

Setup installer

Installer provides installation & upgrading functionality. You can upgrade the IDE at any time by typing M-x upgrade from within Emacs. You may have to restart Emacs for the upgrade to take place. See installer.el for documentation.

(require 'installer nil t)

Packages

Each of these entries are use-package calls that will both install & load the package for us. The most important are listed first in “Essentials”. “Built-in” Emacs packages are also configured. Next comes the “Programming Language” modes. Finally, we list some miscellaneous modes.

This is an alphabetized listing of all Emacs packages needed by the IDE. To resort, go to one of the package group headings & type C-c ^ a.

Essentials

These are the best & most useful modes available to us in Emacs world.

Name		Name	Last commit message	Last commit date
Latest commit History 1,571 Commits
.github/workflows		.github/workflows
site-lisp		site-lisp
.dir-locals.el		.dir-locals.el
.gitattributes		.gitattributes
.gitignore		.gitignore
.travis.yml		.travis.yml
LICENSE		LICENSE
README.org		README.org
bootstrap.sh		bootstrap.sh
default.nix		default.nix
deploy.sh		deploy.sh
flake.lock		flake.lock
flake.nix		flake.nix
gist-unpack.sh		gist-unpack.sh
init.el		init.el
module.nix		module.nix
nixos.nix		nixos.nix
update.sh		update.sh

License

matthewbauer/bauer

Folders and files

Latest commit

History

Repository files navigation

bauer: an Emacs+Nix IDE

Usage

Installing/upgrading

Developing

Without Nix

Note on macOS

Disabling AppNap

Emacs init file

Increase GC

Benchmark

Autoloads & Misc.

Custom config

Better defaults

Site paths

Set environment

Load custom file

Setup use-package

Key bindings

Setup installer

Packages

Essentials

aggressive-indent

consult

envrc

dtrt-indent

Emacs shell

esh-help

em-dired

Gnus

GCMH

Magit

git-timemachine

MMM Mode

multiple-cursors

Org

smart-hungry-delete

sudo-edit

Theme

try

which-key

wgrep

embark

Built-ins

autorevert

bug-reference

comint

compile

conf-mode

delsel

dired

dired-column

dired-subtree

dired-x

display-line-numbers

eldoc

electric

elec-pair

eww

executable

ffap

files

flyspell

goto-addr

hl-line

ibuffer

imenu-list

mouse

paren

pp

prog-mode

persistent-mode

savehist-mode

saveplace-mode

Shell