Type search custom request

CHANGES.md

@@ -15,6 +15,9 @@
 
 - Add a code-action for syntactic and semantic movement shortcuts based on Merlin's Jump command (#1364)
 
+- Add custom
+  [`ocamllsp/polaritysearch`](/ocaml-lsp-server/docs/ocamllsp/polaritySearch-spec.md) request (#1369)
+
 ## Fixes
 
 - Kill unnecessary ocamlformat processes with sigterm rather than sigint or

ocaml-lsp-server/docs/ocamllsp/polaritySearch-spec.md

@@ -0,0 +1,37 @@
+# Polarity Search Request
+
+## Description
+
+This custom request allows clients to perform a polarity-based search at a specific position within a text document based on finding functions or types that match a specific query pattern.
+
+## Server capability
+
+- property name: `handlePolaritySearch`
+- property type: `boolean`
+
+## Request
+
+```js
+export interface PolaritySearchParams extends TexDocumentPositionParams
+{
+    query: string;
+}
+```
+- method: `ocamllsp/polaritySearch`
+- params:
+    - `TextDocumentPositionParams`: This is an existing interface that includes:
+            - `TextDocumentIdentifier`: Specifies the document uri for which the request is sent.
+            - `Position`: Specifies the cursor position.
+        More details can be found in the [TextDocumentPositionParams - LSP Specification](https://microsoft.github.io/language-server-protocol/specifications/lsp/3.17/specification/#textDocumentPositionParams).
+    - `query`: The search pattern.
+
+## Response
+
+```js
+result: PolaritySearch | null
+export interface PolaritySearch {
+    type t = Query_protocol.Compl.entry list
+}
+```
+- `t`: A list of completion entries that match the query.
+- A response with null result is returned if no entries are found.

ocaml-lsp-server/src/custom_requests/custom_request.ml

@@ -6,3 +6,4 @@ module Typed_holes = Req_typed_holes
 module Type_enclosing = Req_type_enclosing
 module Wrapping_ast_node = Req_wrapping_ast_node
 module Get_documentation = Req_get_documentation
+module PolaritySearch = Req_polarity_search

ocaml-lsp-server/src/custom_requests/custom_request.mli

@@ -8,3 +8,4 @@ module Typed_holes = Req_typed_holes
 module Type_enclosing = Req_type_enclosing
 module Wrapping_ast_node = Req_wrapping_ast_node
 module Get_documentation = Req_get_documentation
+module PolaritySearch = Req_polarity_search

ocaml-lsp-server/src/custom_requests/req_polarity_search.ml

@@ -0,0 +1,124 @@
+open Import
+module TextDocumentPositionParams = Lsp.Types.TextDocumentPositionParams
+
+let meth = "ocamllsp/polaritySearch"
+let capability = "handlePolaritySearch", `Bool true
+
+let completion_kind kind : CompletionItemKind.t =
+  match kind with
+  | `Value -> Value
+  | `Variant -> EnumMember
+  | `Label -> Field
+  | `Module -> Module
+  | `Modtype -> Interface
+  | `MethodCall -> Method
+  | `Keyword -> Keyword
+  | `Constructor -> Constructor
+  | `Type -> TypeParameter
+;;
+
+let kind_of_completion_kind (kind : CompletionItemKind.t) =
+  match kind with
+  | Value -> `Value
+  | EnumMember -> `Variant
+  | Field -> `Label
+  | Module -> `Module
+  | Interface -> `Modtype
+  | Method -> `MethodCall
+  | Keyword -> `Keyword
+  | Constructor -> `Constructor
+  | TypeParameter -> `Type
+  | _ -> failwith "Unknown kind"
+;;
+
+module PolaritySearchParams = struct
+  type t =
+    { text_document : TextDocumentIdentifier.t
+    ; position : Position.t
+    ; query : string
+    }
+
+  let t_of_yojson json =
+    let open Yojson.Safe.Util in
+    let textDocumentPosition = Lsp.Types.TextDocumentPositionParams.t_of_yojson json in
+    let query = json |> member "query" |> to_string in
+    { position = textDocumentPosition.position
+    ; text_document = textDocumentPosition.textDocument
+    ; query
+    }
+  ;;
+
+  let yojson_of_t { text_document; position; query } =
+    `Assoc
+      (("textDocument", TextDocumentIdentifier.yojson_of_t text_document)
+       :: ("position", Position.yojson_of_t position)
+       :: [ "query", `String query ])
+  ;;
+end
+
+module PolaritySearch = struct
+  type t = Query_protocol.Compl.entry list
+
+  let entry_of_yojson json =
+    let open Yojson.Safe.Util in
+    let name = json |> member "name" |> to_string in
+    let kind =
+      json |> member "kind" |> CompletionItemKind.t_of_yojson |> kind_of_completion_kind
+    in
+    let desc = json |> member "desc" |> to_string in
+    let info = json |> member "info" |> to_string in
+    let deprecated = json |> member "deprecated" |> to_bool in
+    { Query_protocol.Compl.name; kind; desc; info; deprecated }
+  ;;
+
+  let yojson_of_entry { Query_protocol.Compl.name; kind; desc; info; deprecated } =
+    `Assoc
+      [ "name", `String name
+      ; "kind", CompletionItemKind.yojson_of_t (completion_kind kind)
+      ; "desc", `String desc
+      ; "info", `String info
+      ; "deprecated", `Bool deprecated
+      ]
+  ;;
+
+  let t_of_yojson json =
+    let open Yojson.Safe.Util in
+    json |> to_list |> List.map ~f:entry_of_yojson
+  ;;
+
+  let yojson_of_t entries = `List (List.map ~f:yojson_of_entry entries)
+end
+
+type t = PolaritySearch.t
+
+let t_of_yojson json = PolaritySearch.t_of_yojson json
+
+module Request_params = struct
+  type t = PolaritySearchParams.t
+
+  let yojson_of_t t = PolaritySearchParams.yojson_of_t t
+  let create text_document position query : t = { text_document; position; query }
+end
+
+let dispatch merlin position query =
+  Document.Merlin.with_pipeline_exn merlin (fun pipeline ->
+    let position = Position.logical position in
+    let query = Query_protocol.Polarity_search (query, position) in
+    let completions = Query_commands.dispatch pipeline query in
+    match completions.context with
+    | `Unknown -> PolaritySearch.yojson_of_t completions.entries
+    | _ -> failwith "Wrong context")
+;;
+
+let on_request ~params state =
+  Fiber.of_thunk (fun () ->
+    let params = (Option.value ~default:(`Assoc []) params :> Yojson.Safe.t) in
+    let PolaritySearchParams.{ text_document; position; query } =
+      PolaritySearchParams.t_of_yojson params
+    in
+    let uri = text_document.uri in
+    let doc = Document_store.get state.State.store uri in
+    match Document.kind doc with
+    | `Other -> Fiber.return `Null
+    | `Merlin merlin -> dispatch merlin position query)
+;;

ocaml-lsp-server/src/custom_requests/req_polarity_search.mli

@@ -0,0 +1,15 @@
+open Import
+
+module Request_params : sig
+  type t
+
+  val yojson_of_t : t -> Json.t
+  val create : TextDocumentIdentifier.t -> Position.t -> string -> t
+end
+
+type t
+
+val t_of_yojson : Json.t -> t
+val meth : string
+val capability : string * [> `Bool of bool ]
+val on_request : params:Jsonrpc.Structured.t option -> State.t -> Json.t Fiber.t

ocaml-lsp-server/src/ocaml_lsp_server.ml

@@ -539,6 +539,7 @@ let on_request
        ; Req_type_enclosing.meth, Req_type_enclosing.on_request
        ; Req_get_documentation.meth, Req_get_documentation.on_request
        ; Req_wrapping_ast_node.meth, Req_wrapping_ast_node.on_request
+       ; Req_polarity_search.meth, Req_polarity_search.on_request
        ; ( Semantic_highlighting.Debug.meth_request_full
          , Semantic_highlighting.Debug.on_request_full )
        ; ( Req_hover_extended.meth

ocaml-lsp-server/test/e2e-new/dune

@@ -62,6 +62,7 @@
     test
     type_enclosing
     documentation
+    polarity_search
     with_pp
     with_ppx
     workspace_change_config))))