[from_ssa] Add test cases

Add `brili` test cases, since I want to test that no undefined varaibles
are used during execution after `from_ssa`.

examples/test/from_ssa/argwrite.bril

@@ -0,0 +1,9 @@
+# ARGS: 3
+@main(a: int) {
+  cond: bool = const true;
+  br cond .here .there;
+.here:
+  a: int = const 5;
+.there:
+  print a;
+}

examples/test/from_ssa/argwrite.out

@@ -0,0 +1 @@
+5

examples/test/from_ssa/if-const.bril

@@ -0,0 +1,14 @@
+@main() {
+    cond: bool = const true;
+    br cond .true .false;
+.true:
+    a: int = const 0;
+    jmp .zexit;
+.false:
+    b: int = const 1;
+    jmp .zexit;
+# zexit to trigger a bug in to_ssa.py that depends on
+# the order that basic blocks get renamed.
+.zexit:
+    print a;
+}

examples/test/from_ssa/if-const.out

@@ -0,0 +1 @@
+0

examples/test/from_ssa/if-ssa.bril

@@ -0,0 +1,17 @@
+# ARGS: true
+@main(cond: bool) {
+.entry:
+    a.1: int = const 47;
+    br cond .left .right;
+.left:
+    a.2: int = add a.1 a.1;
+    jmp .zexit;
+.right:
+    a.3: int = mul a.1 a.1;
+    jmp .zexit;
+# zexit to trigger a bug in to_ssa.py that depends on
+# the order that basic blocks get renamed.
+.zexit:
+    a.4: int = phi .left a.2 .right a.3;
+    print a.4;
+}

examples/test/from_ssa/if-ssa.out

@@ -0,0 +1 @@
+94

examples/test/from_ssa/if.bril

@@ -0,0 +1,14 @@
+# ARGS: false
+@main(cond: bool) {
+.entry:
+    a: int = const 47;
+    br cond .left .right;
+.left:
+    a: int = add a a;
+    jmp .exit;
+.right:
+    a: int = mul a a;
+    jmp .exit;
+.exit:
+    print a;
+}

examples/test/from_ssa/if.out

@@ -0,0 +1 @@
+2209

examples/test/from_ssa/loop-branch.bril

@@ -0,0 +1,24 @@
+@func(): int {
+    n: int = const 5;
+    ret n;
+}
+
+@loop(infinite: bool, print: bool) {
+.entry:
+.loop.header:
+    br infinite .loop.body .loop.end;
+.loop.body:
+    br print .loop.print .loop.next;
+.loop.print:
+    v: int = call @func;
+    print v;
+.loop.next:
+    jmp .loop.header;
+.loop.end:
+}
+
+@main() {
+  infinite: bool = const false;
+  print: bool = const true;
+  call @loop infinite print;
+}

examples/test/from_ssa/loop.bril

@@ -0,0 +1,14 @@
+@main {
+.entry:
+    i: int = const 1;
+    jmp .loop;
+.loop:
+    max: int = const 10;
+    cond: bool = lt i max;
+    br cond .body .exit;
+.body:
+    i: int = add i i;
+    jmp .loop;
+.exit:
+    print i;
+}

examples/test/from_ssa/loop.out

@@ -0,0 +1 @@
+16

examples/test/from_ssa/selfloop.bril

@@ -0,0 +1,14 @@
+@main {
+.entry:
+  one: int = const 1;
+  zero: int = const 0;
+  x: int = const 5;
+.loop:
+  x: int = sub x one;
+  done: bool = eq x zero;
+.br:
+  br done .exit .loop;
+.exit:
+  print x;
+  ret;
+}

examples/test/from_ssa/selfloop.out

@@ -0,0 +1 @@
+0

examples/test/from_ssa/turnt.toml

@@ -0,0 +1 @@
+command = "bril2json < {filename} | python ../../to_ssa.py | python ../../from_ssa.py | brili {args}"

examples/test/from_ssa/while.bril

@@ -0,0 +1,13 @@
+# ARGS: 5
+@main(a: int) {
+.while.cond:
+  zero: int = const 0;
+  is_term: bool = eq a zero;
+  br is_term .while.finish .while.body;
+.while.body:
+  one: int = const 1;
+  a: int = sub a one;
+  jmp .while.cond;
+.while.finish:
+  print a;
+}

examples/test/from_ssa/while.out

@@ -0,0 +1 @@
+0