feat cmake: add download_userver()

.github/workflows/ci.yml

@@ -44,9 +44,9 @@ jobs:
 
           - name: Install packages
             run: |
-                (cd third_party && git clone -b develop --single-branch --depth 1 https://github.com/userver-framework/userver.git)
+                make cmake-debug || :
                 sudo apt update
-                sudo apt install --allow-downgrades -y $(cat third_party/userver/scripts/docs/en/deps/${{matrix.os}}.md | tr '\n' ' ')
+                sudo apt install --allow-downgrades -y $(cat build_debug/_deps/userver-src/scripts/docs/en/deps/${{matrix.os}}.md | tr '\n' ' ')
                 python3 -m pip install -r requirements.txt
 
           - name: Setup ccache

CMakeLists.txt

@@ -1,21 +1,13 @@
 cmake_minimum_required(VERSION 3.12)
 project(service_template CXX)
 
+list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
+include(DownloadUserver)
 
-# Adding userver dependency
 find_package(userver COMPONENTS core postgresql QUIET)
-if(NOT userver_FOUND)  # Fallback to subdirectory usage
-    # Compatibility mode: some systems don't support these features
-    set(USERVER_FEATURE_CRYPTOPP_BLAKE2 OFF CACHE BOOL "" FORCE)
-    set(USERVER_FEATURE_GRPC_CHANNELZ OFF CACHE BOOL "" FORCE)
-    set(USERVER_FEATURE_REDIS_HI_MALLOC ON CACHE BOOL "" FORCE)
-
-    if (EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/third_party/userver)
-        message(STATUS "Using userver framework from third_party/userver")
-        add_subdirectory(third_party/userver)
-    else()
-        message(FATAL_ERROR "Either install the userver or provide a path to it")
-    endif()
+if(NOT userver_FOUND)
+    # download_userver() tries TRY_DIR first, fallbacks to downloading userver from github
+    download_userver(TRY_DIR third_party/userver)
 endif()
 
 userver_setup_environment()

cmake/DownloadUserver.cmake

@@ -0,0 +1,50 @@
+# Copied from get_cpm.cmake
+set(CPM_DOWNLOAD_VERSION 0.39.0)
+set(CPM_HASH_SUM "66639bcac9dd2907b2918de466783554c1334446b9874e90d38e3778d404c2ef")
+set(CPM_DOWNLOAD_LOCATION "${CMAKE_BINARY_DIR}/cmake/CPM_${CPM_DOWNLOAD_VERSION}.cmake")
+file(DOWNLOAD
+    https://github.com/cpm-cmake/CPM.cmake/releases/download/v${CPM_DOWNLOAD_VERSION}/CPM.cmake
+    ${CPM_DOWNLOAD_LOCATION} EXPECTED_HASH SHA256=${CPM_HASH_SUM}
+)
+include(${CPM_DOWNLOAD_LOCATION})
+
+
+function(download_userver)
+  set(OPTIONS)
+  set(ONE_VALUE_ARGS VERSION TRY_DIR)
+  set(MULTI_VALUE_ARGS FEATURES FEATURES_OFF)
+  cmake_parse_arguments(
+      ARG "${OPTIONS}" "${ONE_VALUE_ARGS}" "${MULTI_VALUE_ARGS}" ${ARGN}
+  )
+  if(NOT ARG_VERSION)
+    set(ARG_VERSION develop)
+  endif()
+
+  if(ARG_TRY_DIR AND EXISTS ${ARG_TRY_DIR})
+    foreach(FEATURE ${ARG_FEATURES})
+      set(USERVER_FEATURE_${FEATURE} ON CACHE BOOL "" FORCE)
+    endforeach()
+    foreach(FEATURE ${ARG_FEATURES_OFF})
+      set(USERVER_FEATURE_${FEATURE} OFF CACHE BOOL "" FORCE)
+    endforeach()
+
+    message(STATUS "Using userver from ${ARG_TRY_DIR}")
+    add_subdirectory(${ARG_TRY_DIR})
+    return()
+  endif()
+
+  set(CMAKE_OPTIONS "USERVER_IS_THE_ROOT_PROJECT OFF")
+  foreach(FEATURE ${ARG_FEATURES})
+    list(APPEND CMAKE_OPTIONS "USERVER_FEATURE_${FEATURE} ON")
+  endforeach()
+  foreach(FEATURE ${ARG_FEATURES_OFF})
+    list(APPEND CMAKE_OPTIONS "USERVER_FEATURE_${FEATURE} OFF")
+  endforeach()
+
+  CPMAddPackage(
+      NAME userver
+      GITHUB_REPOSITORY userver-framework/userver
+      GIT_TAG ${ARG_VERSION}
+      OPTIONS ${CMAKE_OPTIONS}
+  )
+endfunction()