Adds support for parsing vectors at comptime

src/Sema/LowerZon.zig

@@ -88,6 +88,7 @@ fn lowerExpr(self: *LowerZon, node: Zoir.Node.Index, res_ty: Type) CompileError!
         .@"struct" => return self.lowerStructOrTuple(node, res_ty),
         .@"union" => return self.lowerUnion(node, res_ty),
         .pointer => return self.lowerPointer(node, res_ty),
+        .vector => return self.lowerVector(node, res_ty),
 
         .type,
         .noreturn,
@@ -98,7 +99,6 @@ fn lowerExpr(self: *LowerZon, node: Zoir.Node.Index, res_ty: Type) CompileError!
         .@"opaque",
         .frame,
         .@"anyframe",
-        .vector,
         .void,
         => return self.fail(
             node,
@@ -669,3 +669,34 @@ fn lowerUnion(self: *LowerZon, node: Zoir.Node.Index, res_ty: Type) !InternPool.
         .val = val,
     });
 }
+
+fn lowerVector(self: *LowerZon, node: Zoir.Node.Index, res_ty: Type) !InternPool.Index {
+    const ip = &self.sema.pt.zcu.intern_pool;
+
+    const vector_info = ip.indexToKey(res_ty.toIntern()).vector_type;
+
+    const elem_nodes: Zoir.Node.Index.Range = switch (node.get(self.file.zoir.?)) {
+        .array_literal => |nodes| nodes,
+        .empty_literal => .{ .start = node, .len = 0 },
+        else => return self.fail(node, "expected type '{}'", .{res_ty.fmt(self.sema.pt)}),
+    };
+
+    const elems = try self.sema.arena.alloc(InternPool.Index, vector_info.len);
+
+    if (elem_nodes.len != vector_info.len) {
+        return self.fail(
+            node,
+            "expected {} vector elements; found {}",
+            .{ vector_info.len, elem_nodes.len },
+        );
+    }
+
+    for (elems, 0..) |*elem, i| {
+        elem.* = try self.lowerExpr(elem_nodes.at(@intCast(i)), .fromInterned(vector_info.child));
+    }
+
+    return self.sema.pt.intern(.{ .aggregate = .{
+        .ty = res_ty.toIntern(),
+        .storage = .{ .elems = elems },
+    } });
+}

test/behavior/zon.zig

@@ -407,3 +407,38 @@ test "inf and nan" {
         try expect(std.math.isNegativeInf(actual[2]));
     }
 }
+
+test "vector" {
+    {
+        const actual: @Vector(0, bool) = @import("zon/vec0.zon");
+        const expected: @Vector(0, bool) = .{};
+        try expectEqual(expected, actual);
+    }
+    {
+        const actual: @Vector(3, bool) = @import("zon/vec3_bool.zon");
+        const expected: @Vector(3, bool) = .{ false, false, true };
+        try expectEqual(expected, actual);
+    }
+
+    {
+        const actual: @Vector(0, f32) = @import("zon/vec0.zon");
+        const expected: @Vector(0, f32) = .{};
+        try expectEqual(expected, actual);
+    }
+    {
+        const actual: @Vector(3, f32) = @import("zon/vec3_float.zon");
+        const expected: @Vector(3, f32) = .{ 1.5, 2.5, 3.5 };
+        try expectEqual(expected, actual);
+    }
+
+    {
+        const actual: @Vector(0, u8) = @import("zon/vec0.zon");
+        const expected: @Vector(0, u8) = .{};
+        try expectEqual(expected, actual);
+    }
+    {
+        const actual: @Vector(3, u8) = @import("zon/vec3_int.zon");
+        const expected: @Vector(3, u8) = .{ 2, 4, 6 };
+        try expectEqual(expected, actual);
+    }
+}

test/behavior/zon/vec3_bool.zon

@@ -0,0 +1 @@
+.{ false, false, true }

test/behavior/zon/vec3_float.zon

@@ -0,0 +1 @@
+.{ 1.5, 2.5, 3.5 }

test/behavior/zon/vec3_int.zon

@@ -0,0 +1 @@
+.{ 2, 4, 6 }

test/cases/compile_errors/@import_zon_vec_too_few.zig

@@ -0,0 +1,10 @@
+export fn entry() void {
+    const f: @Vector(3, f32) = @import("zon/tuple.zon");
+    _ = f;
+}
+
+// error
+// imports=zon/tuple.zon
+//
+// zon/tuple.zon:1:2: error: expected 3 vector elements; found 2
+// tmp.zig:2:40: note: imported here

test/cases/compile_errors/@import_zon_vec_too_many.zig

@@ -0,0 +1,10 @@
+export fn entry() void {
+    const f: @Vector(1, f32) = @import("zon/tuple.zon");
+    _ = f;
+}
+
+// error
+// imports=zon/tuple.zon
+//
+// zon/tuple.zon:1:2: error: expected 1 vector elements; found 2
+// tmp.zig:2:40: note: imported here

test/cases/compile_errors/@import_zon_vec_wrong_type.zig

@@ -0,0 +1,10 @@
+export fn entry() void {
+    const f: @Vector(2, bool) = @import("zon/tuple.zon");
+    _ = f;
+}
+
+// error
+// imports=zon/tuple.zon
+//
+// zon/tuple.zon:1:4: error: expected type 'bool'
+// tmp.zig:2:41: note: imported here