Setup local dev environment

.envrc

@@ -0,0 +1,8 @@
+if has nix; then
+  watch_file flake.nix
+  watch_file flake.lock
+  watch_file dev/nix/devShell.nix
+  use flake
+fi
+
+source_env_if_exists .envrc.local

.gitignore

@@ -13,6 +13,7 @@ third_party/*
 
 # Local environment
 .env
+.direnv/
 
 # Project-scoped MCP
 .mcp.json

dev/nix/devShell.nix

@@ -0,0 +1,135 @@
+{
+  mkShell,
+  lib,
+  stdenv,
+  alsa-lib,
+  at-spi2-atk,
+  at-spi2-core,
+  atk,
+  cairo,
+  cargo,
+  clippy,
+  cups,
+  dbus,
+  expat,
+  ffmpeg,
+  git,
+  glib,
+  just,
+  libass,
+  libdrm,
+  libgbm,
+  libGL,
+  libplacebo,
+  libXScrnSaver,
+  libx11,
+  libxcb,
+  libxcomposite,
+  libxdamage,
+  libxext,
+  libxfixes,
+  libxkbcommon,
+  libXpresent,
+  libxrandr,
+  meson,
+  ninja,
+  nspr,
+  nss,
+  pango,
+  pkg-config,
+  python3,
+  rustPlatform,
+  rustc,
+  rustfmt,
+  systemd,
+  vulkan-loader,
+  wayland,
+  wayland-protocols,
+  wayland-scanner,
+}:
+
+let
+  mpvBuildInputs = [
+    ffmpeg
+    libass
+    libdrm
+    libgbm
+    libGL
+    libplacebo
+    libXScrnSaver
+    libx11
+    libxext
+    libxkbcommon
+    libXpresent
+    libxrandr
+    vulkan-loader
+    wayland
+    wayland-protocols
+    wayland-scanner
+  ];
+
+  cefRuntimeLibraries = [
+    alsa-lib
+    at-spi2-atk
+    at-spi2-core
+    atk
+    cairo
+    cups
+    dbus
+    expat
+    glib
+    libgbm
+    libx11
+    libxcomposite
+    libxdamage
+    libxext
+    libxfixes
+    libxrandr
+    nspr
+    nss
+    pango
+    systemd
+  ];
+
+  appLinkLibraries = [
+    libxcb
+    libxkbcommon
+  ];
+
+  runtimeLibraryPath = lib.makeLibraryPath (
+    cefRuntimeLibraries
+    ++ mpvBuildInputs
+    ++ appLinkLibraries
+  );
+in
+mkShell {
+  name = "jellyfin-desktop";
+
+  packages = [
+    cargo
+    clippy
+    git
+    just
+    meson
+    ninja
+    pkg-config
+    python3
+    rustPlatform.bindgenHook
+    rustc
+    rustfmt
+  ]
+  ++ lib.optionals stdenv.hostPlatform.isLinux (
+    mpvBuildInputs
+    ++ cefRuntimeLibraries
+    ++ appLinkLibraries
+  );
+
+  # Expose the runtime libary path so that `just run` can find the required libaries to run the app.
+  shellHook = lib.optionalString stdenv.hostPlatform.isLinux ''
+    export LD_LIBRARY_PATH="${runtimeLibraryPath}''${LD_LIBRARY_PATH:+:$LD_LIBRARY_PATH}"
+
+    if [ -z "''${XDG_RUNTIME_DIR:-}" ] || [ ! -w "''${XDG_RUNTIME_DIR:-}" ]; then
+      export XDG_RUNTIME_DIR="/tmp"
+    fi
+  '';
+}

flake.nix

@@ -0,0 +1,32 @@
+{
+  description = "Jellyfin Desktop development environment";
+
+  inputs = {
+    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
+    flake-compat = {
+      url = "github:edolstra/flake-compat";
+      flake = false;
+    };
+  };
+
+  outputs =
+    { nixpkgs, ... }:
+    let
+      systems = [
+        "x86_64-linux"
+        "aarch64-linux"
+      ];
+      forAllSystems = nixpkgs.lib.genAttrs systems;
+    in
+    {
+      devShells = forAllSystems (
+        system:
+        let
+          pkgs = nixpkgs.legacyPackages.${system};
+        in
+        {
+          default = pkgs.callPackage ./dev/nix/devShell.nix { };
+        }
+      );
+    };
+}

shell.nix

@@ -0,0 +1,12 @@
+(import
+  (
+    let
+      lock = builtins.fromJSON (builtins.readFile ./flake.lock);
+      flake-compat = lock.nodes.flake-compat;
+    in
+    fetchTarball {
+      url = "https://github.com/edolstra/flake-compat/archive/${flake-compat.locked.rev}.tar.gz";
+      sha256 = flake-compat.locked.narHash;
+    }
+  )
+  { src = ./.; }).shellNix