wstETH/ETH oracle using exchange rate only

src/adapters/WstEthOracle.sol

@@ -0,0 +1,33 @@
+// SPDX-License-Identifier: GPL-2.0-or-later
+pragma solidity 0.8.21;
+
+import {IStEth} from "../interfaces/IStEth.sol";
+import {AggregatorV3Interface} from "../interfaces/AggregatorV3Interface.sol";
+
+/// @title WstEthOracle
+/// @author Morpho Labs
+/// @custom:contact [email protected]
+/// @notice wstETH/ETH exchange rate price feed.
+/// @dev This contract should only be used as price feed for `ChainlinkOracle`.
+contract WstEthOracle is AggregatorV3Interface {
+    uint8 public constant decimals = uint8(18);
+    string public constant description = "wstETH/ETH exchange rate price";
+    uint256 public constant version = 1;
+
+    IStEth public immutable ST_ETH;
+
+    constructor(address stEth) {
+        require(stEth != address(0), "WstEthOracle: ZERO_ADDRESS");
+        ST_ETH = IStEth(stEth);
+    }
+
+    function getRoundData(uint80) external view returns (uint80, int256, uint256, uint256, uint80) {
+        return latestRoundData();
+    }
+
+    function latestRoundData() public view returns (uint80, int256, uint256, uint256, uint80) {
+        uint256 ethByShares = ST_ETH.getPooledEthByShares(10 ** decimals);
+        require(ethByShares < type(uint256).max, "WstEthOracle: OVERFLOW");
+        return (0, int256(ethByShares), 0, 0, 0);
+    }
+}

src/interfaces/IStEth.sol

@@ -0,0 +1,6 @@
+// SPDX-License-Identifier: GPL-2.0-or-later
+pragma solidity >=0.5.0;
+
+interface IStEth {
+    function getPooledEthByShares(uint256) external view returns (uint256);
+}

test/WstEthOracle.sol

@@ -0,0 +1,76 @@
+// SPDX-License-Identifier: GPL-2.0-or-later
+pragma solidity ^0.8.0;
+
+import "../lib/forge-std/src/Test.sol";
+import "../src/adapters/WstEthOracle.sol";
+
+contract ChainlinkOracleTest is Test {
+    IStEth internal constant ST_ETH = IStEth(0xae7ab96520DE3A18E5e111B5EaAb095312D7fE84);
+
+    WstEthOracle internal oracle;
+
+    function setUp() public {
+        vm.createSelectFork(vm.envString("ETH_RPC_URL"));
+        oracle = new WstEthOracle(address(ST_ETH));
+    }
+
+    function testLastRoundDataUintMax() public {
+        vm.mockCall(
+            address(ST_ETH),
+            abi.encodeWithSelector(ST_ETH.getPooledEthByShares.selector, 10 ** 18),
+            abi.encode(type(uint256).max)
+        );
+        vm.expectRevert("WstEthOracle: OVERFLOW");
+        oracle.latestRoundData();
+    }
+
+    function testGetRoundDataUintMax() public {
+        vm.mockCall(
+            address(ST_ETH),
+            abi.encodeWithSelector(ST_ETH.getPooledEthByShares.selector, 10 ** 18),
+            abi.encode(type(uint256).max)
+        );
+        vm.expectRevert("WstEthOracle: OVERFLOW");
+        oracle.getRoundData(1);
+    }
+
+    function testDecimals() public {
+        assertEq(oracle.decimals(), uint8(18));
+    }
+
+    function testDeployZeroAddress() public {
+        vm.expectRevert("WstEthOracle: ZERO_ADDRESS");
+        new WstEthOracle(address(0));
+    }
+
+    function testConfig() public {
+        assertEq(oracle.description(), "wstETH/ETH exchange rate price");
+        assertEq(oracle.version(), 1);
+    }
+
+    function testLastRoundData() public {
+        (uint80 roundId, int256 answer, uint256 startedAt, uint256 updatedAt, uint80 answeredInRound) =
+            oracle.latestRoundData();
+        assertEq(roundId, 0);
+        assertEq(uint256(answer), ST_ETH.getPooledEthByShares(10 ** 18));
+        assertEq(startedAt, 0);
+        assertEq(updatedAt, 0);
+        assertEq(answeredInRound, 0);
+    }
+
+    function testGetLastRoundData() public {
+        (uint80 roundId, int256 answer, uint256 startedAt, uint256 updatedAt, uint80 answeredInRound) =
+            oracle.getRoundData(1);
+        assertEq(roundId, 0);
+        assertEq(uint256(answer), ST_ETH.getPooledEthByShares(10 ** 18));
+        assertEq(startedAt, 0);
+        assertEq(updatedAt, 0);
+        assertEq(answeredInRound, 0);
+    }
+
+    function testLastRoundDataBounds() public {
+        (, int256 answer,,,) = oracle.latestRoundData();
+        assertGe(uint256(answer), 1154690031824824994); // Exchange rate queried at block 19070943
+        assertLe(uint256(answer), 1.5e18); // Max bounds of the exchange rate. Should work for a long enough time.
+    }
+}